VBA rechercheV avec Si

Diyann à dit:

Que cherches-tu avec ta rechercheV ? Tu cherches quoi dans quelle plage ?
Ca doit forcément être une macro ?

Cliquez pour agrandir...

Robert à dit:

Bonsoir Arpette Diyann, bonsoir le forum,

En pièce jointe un exemple avec la macro événementielle Change ci-dessous :

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim pl As Range 'déclare la variable pl (PLage)
Dim r As Range 'déclare la variable r (Recherche)
 
'si la modification a lieu ailleurs qu'en B21, sort de la procédure
If Target.Address <> "$B$21" Then Exit Sub
'si B21 est effacée, C21 est effacée également, sort de la procédure
If Target.Value = "" Then Target.Offset(0, 1).Value = "": Exit Sub
 
With Sheets("Fournisseurs") 'prend en compte l'onglet "Fournisseurs"
    Set pl = .Range("A2:A" & .Range("A65536").End(xlUp).Row) 'définit la plage de recherche
End With 'fin de la prise en compte de l'onglet "Fournisseurs"
 
Set r = pl.Find(Target.Value, , xlValues, xlWhole) 'définit la recherche
If Not r Is Nothing Then 'condition : si il existe au moins une occurrence de B21 dans la plage pl
    'place le résultat en C21 (tu adapteras à ton cas en modifiant les valeurs des offset (Ligne, Colonnes))
    Target.Offset(0, 1).Value = r.Offset(0, 1).Value
Else 'sinon
    MsgBox "Code non trouvé !" 'message
    Range("B21").Select 'place le curseur dans la cellule B21
End If
End Sub

Cliquez pour agrandir...

Pierrot93 à dit:

Bonsoir Arpette, Robert🙂

modifie le test ainsi, plage à adapter :

Code:

If Intersect(Target, Range("B1:B24")) Is Nothing Then Exit Sub

bonne soirée
@+

Cliquez pour agrandir...

Arpette à dit:

Bonsoir Pierrot, Robert, le forum, c'est nickel merci beaucoup.

@ bientôt

Cliquez pour agrandir...

Pierrot93 à dit:

Bonjour à tous,

Euh.... pas tout compris moi.... Ca bogue sur quelle ligne ? mets peut être un fichier en pièce jointe, plus facile pour t'aider....

bon après midi
@+

Cliquez pour agrandir...

Pierrot93 à dit:

Re,

modifie la procédure ainsi :

Code:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Not Application.Intersect(Target, Range("B1:B65000")) Is Nothing Then
        Application.EnableEvents = False
        Rows(Target.Row).Insert Shift:=xlDown
        Cancel = True
        Application.EnableEvents = True
    End If
End Sub

Cliquez pour agrandir...

Pierrot93 à dit:

Bonjour,

pour insérer 25 lignes, essaye ainsi :

Code:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Not Application.Intersect(Target, Range("B1:B65000")) Is Nothing Then
        Application.EnableEvents = False
        Rows(Target.Row & ":" & Target.Row + 24).Insert Shift:=xlDown
        Cancel = True
        Application.EnableEvents = True
    End If
End Sub

pour le reste, je pense qu'il faut modifier la procédure que t'avait donné Robert, pense pas qu'il faille utiliser l'événement "BeforeDoubleClick" pour cela...

bonne journée
@+

Cliquez pour agrandir...