XL 2016 VBA pour dupliquer un fichier en X fois

Sub CopieFichiers()
  Dim tbliste()
  Dim i As Integer, j As Integer
  Dim chemin As String, fSource As String, fCible As String
 
  chemin = ThisWorkbook.Path & "\"
  tbliste = Range("tb_listeFichiers").Value2
 
  For i = 1 To UBound(tbliste)
    For j = 1 To tbliste(i, 2)
      fSource = chemin & tbliste(i, 1) & ".xlsx"
      fCible = chemin & tbliste(i, 1) & j & ".xlsx"
      FileCopy fSource, fCible
    Next j
  Next i
 
End Sub

Sub Copier()
Dim chemin$, fso As Object, f As Object, pos%, nf$, i As Variant, n%
chemin = ThisWorkbook.Path & "\"
Set fso = CreateObject("Scripting.FileSystemObject")
On Error Resume Next
'---supprime les fichiers indexés---
For Each f In fso.GetFolder(chemin).Files
    If f.Name Like "*#.*" Then
        Workbooks(f.Name).Close False 'si le fichier est ouvert on le ferme
        Kill chemin & f.Name
    End If
Next f
'---copie les fichiers restants---
For Each f In fso.GetFolder(chemin).Files
    If f.Name <> ThisWorkbook.Name Then
        pos = InStrRev(f.Name, ".")
        nf = Left(f.Name, pos - 1)
        i = Application.VLookup(nf, Columns("A:B"), 2, 0) 'RECHERCHEV
        If IsNumeric(i) Then
            For n = 1 To i
                fso.CopyFile chemin & f.Name, chemin & nf & n & Mid(f.Name, pos)
            Next n
        End If
    End If
Next f
End Sub

Sub Copier_fichiers()
Dim chemin$, fichier, pos%, nf$, i As Variant, n%
chemin = ThisWorkbook.Path & "\"
fichier = Dir(chemin) '1er fichier du dossier
On Error Resume Next
'---supprime les fichiers indexés---
While fichier <> ""
    If fichier Like "*#.*" Then
        Workbooks(fichier).Close False 'si le fichier est ouvert on le ferme
        Kill chemin & fichier
    End If
    fichier = Dir
Wend
'---copie les fichiers restants---
fichier = Dir(chemin)
While fichier <> ""
    If fichier <> ThisWorkbook.Name Then
        pos = InStrRev(fichier, ".")
        nf = Left(fichier, pos - 1)
        i = Application.VLookup(nf, Columns("A:B"), 2, 0) 'RECHERCHEV
        If IsNumeric(i) Then
            For n = 1 To i
                FileCopy chemin & fichier, chemin & nf & n & Mid(fichier, pos)
            Next n
        End If
    End If
    fichier = Dir
Wend
End Sub

i = Application.VLookup(nf, Columns("A:B"), 2, 0) 'RECHERCHEV

i = Application.VLookup(fichier, Columns("A:B"), 2, 0) 'RECHERCHEV