XL 2016 VBA - Impossible d'envoyer l'image du QR Code en fichier

[Dudu2]

Bonjour,

Dans le fichier joint, 2 boutons:

Ok, c'est simple, ça marche pas de problème !

KO, ça ne marche pas,

bien que le code utilisé fonctionne parfaitement pour une image "vraie" !!!

L'image du QR Code en fichier est vide ou non valide, je ne sais pas ???

 

[patricktoulon]

non moi je suis un petit bricoleur qui fait semblant d'etre un grand
😉😆😅😂

pour rester sérieux
avantage methode request/object stream
pas de shape
pas de clipboard
pas de paste vide

c'est du direct request/fichier
c'est vieux comme le monde 😉

 

[soan]

Bonjour Dudu2, le fil,

Je ne sais pas si c'est aussi perfide que ça. 😱

non, bien sûr, ça n'est pas aussi perfide que ça ! 😄 les smileys 😁 😂 🤣 que j'ai mis dans mon post #6 étaient pour montrer que c'était "en mode humour". (dixit Staple1600)​

soan

 

[patricktoulon]

re
Bonjour j'ai retrouvé la méthode paste sans api et adapté

'----------------------------
'Génère un QR code en fichier
'----------------------------
Sub QRCodeToFile(Chaine As String, NomCompletFichier, Optional PicWidth As Integer = 120, Optional PicHeight As Integer = 120)
    Dim Ch As ChartObject, Pic As Picture
    Application.CutCopyMode = False    'on vide l'eventuelle image précédamment copiée(pour ne pas recoller la meme)
    DoEvents    'laisse quelques milliemes de seconde au clip pour se vider
    Set Pic = QRCodeToCell(Chaine, ActiveCell, PicWidth, PicHeight): Pic.CopyPicture
    Set Ch = ActiveSheet.ChartObjects.Add(0, 0, Pic.Width, Pic.Height)    'Create a Chart on the ActiveSheet
    With Ch.Chart
        Do While .Pictures.Count = 0: DoEvents: .Paste: Loop    ' on paste tant qu'il y a pas une image dans le chart
          .Export NomCompletFichier, FilterName:=Mid(NomCompletFichier, InStrRev(NomCompletFichier, ".") + 1)
    End With
    Pic.Delete: Ch.Delete    'Delete the image and the Chart
End Sub

 

[Dudu2]

pour montrer que c'était "en mode humour".

Ah mince, j'ai raté l'affaire 😵

 

[Dudu2]

@patricktoulon,
Ton dernier code en passant par le Chart est bien.
D'autant qu'on peut lui ajouter un ScreenUpdating = False pour ne pas avoir l'effet visuel fugace de l'image du QR Code à l'écran.

Edit: Fichier supprimé. Voir ci-dessous

 

[patricktoulon]

re
Bonjour @Dudu2
tu a les deux solutions maintenant
pour l'avenir tu le saura (copy image et export par chart)= grosse bouff de mémoire sur 2016 et +
donc gestion d'attente
😉
pour ma part je préfère un do/ loop plutôt qu'un wait ou sleep
le do loop s’ arrête quand il y a une picture dans le chart

et pour eviter une image de mauvais format au cas ou la requête n'aboutie pas

'----------------------------
'Génère un QR code en fichier
'Code de PatrickToulon
'
'Arguments:
'---------
'- Chaine   : Chaine à encoder en QR Code
'- NomCompletFichier: Nom complet du fichier image du QR Code
'- PicWidth : Largeur de l'image du QR Code
'- PicHeight: Hauteur de l'image du QR Code
'----------------------------
Sub QRCodeToFile(Chaine As String, _
                 NomCompletFichier, _
                 Optional PicWidth As Integer = 120, _
                 Optional PicHeight As Integer = 120)

    Dim Link As String
    Dim ReQ As Object
    Dim oStream As Object

    'https://developers.google.com/chart/infographics/docs/qr_codes
    Link = "http://chart.googleapis.com/chart?cht=qr&chs=" & PicWidth & "x" & PicHeight & "&chl=" & Chaine

    If Len(Dir(NomCompletFichier)) > 0 Then Kill NomCompletFichier
    '
    Set ReQ = CreateObject("Microsoft.XMLHTTP")
    ReQ.Open "get", Link, False
    ReQ.send
    If ReQ.Status <> 200 Then MsgBox "la requete n'a pas abouti": Exit Sub
    '
    Set oStream = CreateObject("ADODB.Stream")
    oStream.Open
    oStream.Type = 1
    oStream.Write ReQ.responsebody
    oStream.SaveToFile NomCompletFichier
    oStream.Close
End Sub

 

[Dudu2]

Bonjour @patricktoulon,
Oui, d'ailleurs j'ai ajouté hier une ressource (en cours de validation) avec uniquement ton code oStream pour la mise en fichier.

Ici, je remets les 2 solutions fichier avec calcul du temps elapse.

 

[patricktoulon]

le contrôle du status te permet de ne pas faire le fichier si la requête n'aboutie pas
ça t’évite de faire un fichier "format illisible"
je regarderai la ressource des qu'elle sera dispo

 

[Dudu2]

La mise directe en fichier chez moi dure environ 18 millièmes de seconde.
Le passage par un Copy / Paste image dure environ 70 millièmes de seconde (3+ fois plus).

 

[patricktoulon]

c'est normal
l’écriture direct passe par le com
l'autre passe le paste d'une copiesur chart puis export le tout piloté par vba

tout les chemins mènent à Rome; certains sont plus long que d'autres c'est tout
😉