Valeur Non reconnue "00:15" - RECHERCHEV

[drx22]

Bonjour à tous,

Je viens à vous car mes compétences m'empêchent de continuer d'autant que c'est une "incohérence" qui m'a poussé à poster.

J'élabore un fichier pour la crèche de mon fils dans lequel seront automatiquement recensées les heures supplémentaires en fonction des heures contractuelles pré-remplies.
Seules les heures d'arrivées/départ journalières seront incrémentées quotidiennement puis tout le reste se calculera seul.

Voici mon problème,
Comme vous pourrez le constater j'ai fait appel à la fonction RECHERCHEV (en référence à l'onglet EquivHre-Hs, qui me permet en fonction du résultat automatique apparaissant dans la colonne i, de faire apparaître l'équivalence en HS dans la colonne J.
Le principe de facturation est le suivant / Pour tout 1/4 d'heure validé, 1 heure supp est facturée. Or, tout fonctionne sauf la facturation du premier 1/4 (0:15) qui reste à zéro.
Je m'arrache les cheveux pour savoir pour quelle raison cette valeur n'est pas reconnue dans la Table_matrice.
L'horaire d'arrivée 7:45 (pour un horaire contractuel de 8:00) provoque un "dépassement" de 15 minutes (Ligne 5) mais le résultat reste à 0, or quand je teste les lignes inférieures (6,7 et 8) cela fonctionne..

1) Cette valeur 0:15 buguerait elle d'origine dans le logiciel ?

2) Les calculs de la colonne i sous la forme =C5-MIN(C5;F5) seraient-ils à l'origine de mon problème ?

Par avance merci de votre contribution

Cédric

 

[david84]

Re : Valeur Non reconnue "00:15" - RECHERCHEV

Bonsoir,
je n'ai pas trop cherché à comprendre mais à tester en J5 et à tirer vers le bas :

=SI(A5="";"";RECHERCHEV(I5;'Equiv.Hre-HS'!A$2:B$146;2))

A+

 

[drx22]

Re: Re : Valeur Non reconnue "00:15" - RECHERCHEV

Salut David,

Je viens de faire le test, le résultat reste inchangé hélas pour J5 en revanche concernant L5, la formule fonctionne parfaitement (même avec 0:15) !!

Je pense que les soucis viennent des formules des calculs d'écart horaire MIN et MAX !?!

 

[Tibo]

Re : Valeur Non reconnue "00:15" - RECHERCHEV

Bonjour drx, salut David,

La gestion des heures réserve parfois de petites surprises.

Si tu passes des cellules au format Standard, tu vas apercevoir des différences au-delà de la 15ème décimale.

En J5, je te propose ceci :

=SOMMEPROD(ARRONDI('Equiv.Hre-HS'!$A$2:$A$146;8)=ARRONDI(Mars!I5;8))*'Equiv.Hre-HS'!$B$2:$B$146

à recopier vers le bas

A adapter pour la colonne L

@+

 

[JCGL]

Re : Valeur Non reconnue "00:15" - RECHERCHEV

Bonjour à tous,

Peut-être en renseignant l'argument valeur proche à VRAIet mettant bien les $ (comme proposé par David):

=SI(A5="";"";RECHERCHEV(I5;'Equiv.Hre-HS'!A$2:B$146;2;VRAI))

Mais la liste doit être triée :

Si l'argument valeur_proche est VRAI, les valeurs de la première colonne de l'argument table_matrice doivent être placées en ordre croissant : ..., -2, -1, 0, 1, 2, ..., A-Z, FAUX, VRAI. Sinon, la fonction RECHERCHEV peut donner une valeur incorrecte. Si l'argument valeur_proche est FAUX, les éléments de la table ne doivent pas nécessairement être classés

A+ à tous

 

[hoerwind]

Re : Valeur Non reconnue "00:15" - RECHERCHEV

Bonjour, salut david, Tibo et JCGL,

Comme expliqué par notre ami Tibo, le processeur reçoit une valeur en format décimal, la transforme en format binaire pour établir le calcul et transforme à nouveau le résultat en format décimal avant de le renvoyer.
Ce double changement de système peut provoquer une petite erreur au-delà de la quinzième décimale.
Pour s'en rendre compte il suffit de saisir dans une cellule : =I5="15:00"

Pour y remédier on peut arrondir le résultat : =ARRONDI(C5-MIN(C5;F5);6)
J5 renverra 1:00

D'autre part le tableau de comparaison en 'Equiv.Hre-HS'! n'est pas nécessaire pour obtenir le résultat en J5
On peut ajouter 45:00 à I5 et en extraire l'heure : =(HEURE(I5+3/96))/24

Je préfère cette méthode plutôt que de faire l'impasse sur le quatrième argument de la fonction RECHERCHEV

 

[drx22]

Tout d'abord, merci a tous de vos interventions !

Après avoir essayé les méthodes proposées il s'avère que le grand gagnant est Hoerwind. En effet les décimales posaient problème or avec sa méthode "Pour y remédier on peut arrondir le résultat : =ARRONDI(C5-MIN(C5;F5);6)", cela fonctionne parfaitement. La correspondance est bien présente en J5 a savoir 1,00 pour 0:15 en I5.

J'en déduis que le format de calcul d'écart d'heure "MIN" est le coupable mais cela n'explique pas pourquoi le même calcul "MAX" en L5 fonctionne sans "l'arrondi".

Quoiqu'il en soit mon problème est enfin résolu et grace a vous.
Je vous en remercie bien humblement une nouvelle fois.

A+

Ced

 

[hoerwind]

Re : Valeur Non reconnue "00:15" - RECHERCHEV

Re,

Ce n'est pas la fonction qui est coupable, mais le processeur !

J'avais bien dit : Ce double changement de système peut provoquer une petite erreur
Peut = c'est possible, mais pas nécessairement.
Dans d'autres cas de figure il se pourrait que MIN ne renvoie pas cette erreur, tandis MAX bien.