Microsoft 365 Valeur 1er cellule d'un tableau filtré

[bendv]

Bonjour à tous,
j'ai un tableau de données avec plusieurs segments, et j'aimerai trouver une solution pour que la premiere valeur de la cellule filtrée s'affiche en A1 (exemple)
Actuellement j'ai réussi à trouver cette formule mais je ne sais la faire fonctionner qu'avec des valeurs numérique (sous.total 2), si c'est une valeur texte ça ne fonctionne pas.
Auriez vous une idée ?

=INDIRECT("G"&EQUIV(1;SOUS.TOTAL(3;INDIRECT("G"&(LIGNE(Curriculum_utilisateur_Non_Termeiné[Identifiant parent du parcours de formation])-1)-2));0)+15)

 

[chris]

Bonjour

Une des solutions est d'ajouter dans une colonne masquable du tableau, titrée vis par exemple, structuré la formule :

=SOUS.TOTAL(103;[@Nom])

Nom étant le titre de la colonne concernée

puis

=INDEX(Tableau1[NOM];EQUIV(1;Tableau1[vis];0))

 

[Hecatonchire]

Bonjour,


Je n'ai peut être pas compris.

Ajoute une colonne (NbLigne) au tableau =Ligne()

=INDEX(Curriculum_utilisateur_Non_Termeiné[Nom];
SOUS.TOTAL(5;Curriculum_utilisateur_Non_Termeiné[NbLigne])-LIGNE(Curriculum_utilisateur_Non_Termeiné[[#En-têtes];[Nom]]))

 

[merinos-BernardEtang]

Bonjour a tous,

Ma reponse... reste a trouver une formule qui permette de se passer de la colonne qui indique les lignes...

 

[bendv]

Merci Je viens de tester mais ne fonctionne pas , ou j'adapte mal la formule.
Je joints le fichier pour mieux comprendre.
j'aimerai que pour le segment "identifiant du parcour de formation" l'intitulé s'indique en H2.
Merci d'"avance

 

[merinos-BernardEtang]

Tu as oublié de compter les lignes a partir de 1 .... donc il faut enlever la position de la table.


Entre temps j'ai essayé sans employer de colonne ligne... c'est possible aussi. Voir ma methode avec une fonction LAMBDA...

Mais probableme epas nécésaire,

BernardEtang

 

[chris]

Bonjour

Ma proposition illustrée sur ton fichier (je te conseille néanmoins de ne pas garder le nom automatique de type Tableau1 mais de donner un nom signifiant à ton tableau)

 

[Hecatonchire]

Je propose sans colonne supplémentaire

=LET(m;MAP(Curriculum_utilisateur_Non_Termeiné[Nom];LAMBDA(v;SOUS.TOTAL(3;v)*(LIGNE(v)-LIGNE(Curriculum_utilisateur_Non_Termeiné[[#En-têtes];[Nom]]))));
li;MIN(FILTRE(m;m>0));
INDEX(Curriculum_utilisateur_Non_Termeiné[Nom];li))

 

[TooFatBoy]

Bonjour,

Je plussoie les dires en particulier de chris et Hecatonchire .

j'ai un tableau de données avec plusieurs segments, et j'aimerai trouver une solution pour que la premiere valeur de la cellule filtrée s'affiche en A1 (exemple)

Proposition de formule pour la cellule A1 :

=INDEX(Tableau13[Identifiant d’élément];SOUS.TOTAL(5;Tableau13[NumLigTS]))