Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

[Icedarts]

Bonjour à tous,
Voila je souhaite dans une case mettre une formule qui me faase la moyenne des grandes valeurs d'une série.

Pour cela j'ai trouvé grace à la recherche sur le forum
Moyenne(grande.valeur(a1:a30;{1;2;3;4})) ça c'est bon ça marche!

Ce qui est déjà pas mal 😉

Pour la suite, NB et Si sont trop court pour effectuer une recherche sur le forum et je n'y arrive pas tout seul...

Dans la série a1:a30 il n'y aura pas toujours 30 nombres.
Et la série de grandes valeurs à extraire dépend de combien il y a de nombre c'est pourquoi je veux me servir de nb(a1:a30).
Voila ce que je dois avoir

Quand NB(A1:A30) est compris entre 1 et 5 dans la case il ne doit rien y avoir.

Quand NB(A1:A30) est compris entre 6 et 7 dans la case on doit avoir MOYENNE(GRANDE.VALEUR(A1:A15;{1;2;3;4}))

Quand NB(A1:A30) est compris entre 8 et 9 dans la case on doit avoir MOYENNE(GRANDE.VALEUR(A1:A15;{1;2;3;4;5}))

Quand NB(A1:A30) est compris entre 10 et 11 dans la case on doit avoir MOYENNE(GRANDE.VALEUR(A1:A15;{1;2;3;4;5;6}))

Quand NB(A1:A30) est compris entre 12 et 13 dans la case on doit avoir MOYENNE(GRANDE.VALEUR(A1:A15;{1;2;3;4;5;6;7}))

Quand NB(A1:A30) est compris entre 14 et 15 dans la case on doit avoir MOYENNE(GRANDE.VALEUR(A1:A15;{1;2;3;4;5;6;7;8}))

Quand NB(A1:A30) est compris entre 16 et 17 dans la case on doit avoir MOYENNE(GRANDE.VALEUR(A1:A15;{1;2;3;4;5;6;7;8;9}))

Quand NB(A1:A30) est supérieur ou égal à 18 dans la case on doit avoir MOYENNE(GRANDE.VALEUR(A1:A15;{1;2;3;4;5;6;7;8;9;10}))

C'est pourquoi je voulais me servir de la fonction "SI"
SI(NB((A1:A30)={1;2;3;4;5};"";NB((A1:A30)={6;7};MOYENNE(GRANDE.VALEUR(A1:A15;{1;2;3;4})))) et ainsi de suite.

Ce qu ne marche pas c'est NB(A1:A30)={1;2;3;4;5}...

Voila j'espère que vous avez compris 😉
Et surtout que vous avez une solution.
Merci d'avance.

 

[Icedarts]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

Effectivement ça marche impec!!!

 

[Icedarts]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

Ah non après plusieurs tests la formule matricielle ne tiens pas compte de la condition >=18 ou de 18 à .... on ne retire que les 10 plus grandes valeurs de la série!

 

[jmd2]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

re

toujours curieux :
à quoi sert cette moyenne ?

 

[Moulinois]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

Bonjour et bonne fête du travail,

Je devrais finir de cette manière dans ce cas?

Ouaip

Tibo> Wahou, c'est vachement sexy les formules matricielles vues comme ça. T'as un tutoriel à me conseiller pour commencer à comprendre comment ça fonctionne ?

 

[Icedarts]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

C'est pour les flechettes.
Il y a un championnat de France et a chaque journée de championnat on a des moyennes pour les jeux 501-301 et cricket.
Et à la fin de la saison il y a les phases finales du championnat de France pendant une semaine au parc des expos de La Rochelle.
Pendant ces phases finales il y a au total 7 niveaux.
Et c'est cette moyenne (que l'on appelle moyenne qualificative) qui détermine dans quel niveau on va se retrouver.
Voila chaque vainqueur de chaque niveau gagne un voyage de 10 jours à Las Vegas quasiment tous frais payés pour un tournois international au Mandala Bay il me semble.
D'ailleurs les joueurs sont rentrés ce week end et il y a une equipe qui a gagné la bas!!!

Voili voilou!

Je suis fortement interessé aussi par un tuto sur les formules vectorielles!!!

 

[jmd2]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

re à toi Flèchette de Glace

c'est donc une règle de tournoi de jeu qui impose de ne pas tenir compte des plus faibles scores.

formules matricielles :
Formation Excel VBA JB
fonctions diverses

mais faut parfois s'accrocher pour mettre de telles formules en application, comme pour ton exemple quand en plus on y intègre des conditions SI ou NB.SI.

 

[Icedarts]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

re à toi Flèchette de Glace

Tu as compris! 😉

La formule matricielle de Tibo fonctionne bien

=SI(NB($A$1:$A$30)<6;"";MOYENNE(GRANDE.VALEUR(A1:A30;
LIGNE(INDIRECT("1:"&ENT(NB($A$1:$A$30)/2+1))))))

Mais cela ne va plus dès que l'on dépasse les 18 valeurs car à partir de la il faut extraire les 10 plus grandes et pas une de plus 😉

A quoi servent les $ dans cette formule?

 

[Tibo]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

re,

Passage un peu tardif pour proposer une correction :

=SI(NB(A1:A30)<6;"";MOYENNE(GRANDE.VALEUR(A1:A30;
LIGNE(INDIRECT("1:"&ENT(MIN(18;NB(A1:A30))/2+1))))))

Toujours matricielle (CTRL + MAJ + ENTREE)

Les dollars n'étaient pas ici nécessaires.

@+

 

[Icedarts]

Re : Une formule comprenant "SI" "NB" "MOYENNE" et "GRANDE.VALEUR"

Merci Tibo cette fois c'est parfait!