XL 2021 Trier des numéros par ordre croissant lignes et colonnes

[alan5]

Bonjour à tous,
mes compétences concernant Excel sont très limitées en VBA.
Je fais donc appel à vos talents.
Tableau comportant les tirages du jeu Crescendo.
1. Plan horizontal. Comment trier les dix numéros sur chaque ligne par ordre croissant,
de la gauche vers la droite.
2. Plan vertical. Éventuellement, tri ensuite des lignes (numéros) sur le plan vertical par
ordre croissant du plus petit au plus grand.

 

[riton00]

Bonsoir,

Un essai!

Slts

 

[sylvanu]

Bonjour Alan, Riton,
Un essai en PJ. Le bouton gris permet de retrouver les valeurs d'origine pour test.
Pas bien compris le "plan vertical". Dans ce cas toutes les combinaisons horizontales seront perdue ?

 

[Phil69970]

Bonjour à tous

@alan5
Je te propose ce fichier

Merci de ton retour

 

[mapomme]

Bonjour @alan5🙂, à tous😉,

Une macro pour trier chaque ligne (tri par bulle) et une macro pour trier par colonne tel que je l'ai compris et qui conserve l'ordre au sein de chaque ligne.

nota : Le tri par colonne n'est judicieux qu'après avoir trié chaque ligne! C'est pourquoi le choix est donné dans la macro de tri par colonne.

Les codes dans Module1:

Sub TriChaqueLigne()
Dim DerLig&, t, i&, j&, ech As Boolean, aux
   With Sheets("Feuil1")
      DerLig = .Cells(Rows.Count, "B").End(xlUp).Row
      t = .Range("b6:k" & DerLig).Value
      For i = 1 To UBound(t)
         Do
            ech = False
            For j = 1 To UBound(t, 2) - 1
               If t(i, j) > t(i, j + 1) Then ech = True: aux = t(i, j): t(i, j) = t(i, j + 1): t(i, j + 1) = aux
            Next j
         Loop While ech
      Next i
      .Range("b6:k" & DerLig) = t
   End With
End Sub

Sub TriDesLignesParColonnes()
Dim rep, DerLig&, plage As Range, j&
   rep = MsgBox("Voulez-vous d'abord trier chaque ligne ?", vbYesNo + vbQuestion + vbDefaultButton1)
   With Sheets("Feuil1")
      If rep = vbYes Then TriChaqueLigne
      DerLig = .Cells(Rows.Count, "b").End(xlUp).Row
      Set plage = .Range("b6:k" & DerLig)
      .Sort.SortFields.Clear
      For j = 1 To plage.Columns.Count
         .Sort.SortFields.Add2 Key:=plage.Columns(j), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
      Next j
      With .Sort
         .SetRange plage
         .Header = xlGuess
         .MatchCase = False
         .Orientation = xlTopToBottom
         .SortMethod = xlPinYin
         .Apply
      End With
   End With
End Sub

nb: j'ai repris la présentation de @sylvanu que je salue😉.