tri tableaux

[moniquedol]

bonjour a tous

j'ai un tableau a 2 colonnes E et F

Je souhaite obtenir la colonne E triée d'après le tri croissant de la colonne F

il y a des chiffres et des nombres dans le tableau

je suis sous Windows 7 avec excel 2007

merci d'avant pour vos idées monique

 

[Jack2]

Re : tri tableaux

Bonjour moniquedol,

Si j'ai bien compris, tu sélectionnes le tableau (colonnes E et F, même nombre de valeurs) puis dans l'onglet Accueil allez à droite dans Trier et Filtrer (AZ et petit entonnoir). Dans la boîte de dialogue choisir tir personnalisé, puis dans colonne choisir : colonne F, trier sur : valeur, Ordre : de A à Z.

Ca devrait marcher.

A+ Jack2

 

[moniquedol]

Re : tri tableaux

bonjour a tous

pour etre plus claire je vous joint un petit fichier http://cjoint.com/?3GqkThJaPoT


vu que j'ai plus de 200 tableaux et en ajoute toutes les semaines, je doit le faire par formules ,le plus simples possible pour les adapter

merci de votre aide monique

 

[job75]

Re : tri tableaux

Bonjour moniquedol, Jack2,

Allons allons Monique, avec plus de 200 tableaux vous n'allez pas trimbaler des formules.

Soit vous voulez faire un tri pour un tableau et vous faites ce qu'a dit Jack.

Soit vous voulez trier tous les tableaux et vous utilisez VBA (Alt+F11) :

Sub TriSurColonne1()
Dim deb As Range, pas%
Set deb = [E5] '1ère cellule, à adapter
pas = 3 'pas à adapter
Application.ScreenUpdating = False
While deb <> ""
  With Intersect(deb.CurrentRegion, Rows(deb.Row & ":" & Rows.Count))
    .Sort .Columns(1), xlAscending, Header:=xlYes
  End With
  Set deb = deb.Offset(, pas)
Wend
End Sub

Sub TriSurColonne2()
Dim deb As Range, pas%
Set deb = [E5] '1ère cellule, à adapter
pas = 3 'pas à adapter
Application.ScreenUpdating = False
While deb <> ""
  With Intersect(deb.CurrentRegion, Rows(deb.Row & ":" & Rows.Count))
    .Sort .Columns(2), xlAscending, Header:=xlYes
  End With
  Set deb = deb.Offset(, pas)
Wend
End Sub

Ces macros permettent de trier soit sur la colonne 1 soit sur la colonne 2.

Les titres des tableaux doivent être sur la même ligne et se suivre avec le même pas.

Fichier joint.

A+

 

[job75]

Re : tri tableaux

Re,

Si VBA vous intéresse, sachez qu'on peut utiliser ici une macro paramétrée :

Sub TriSurColonne1()
Tri 1
End Sub

Sub TriSurColonne2()
Tri 2
End Sub

Sub Tri(col As Byte)
Dim deb As Range, pas%
Set deb = [E5] '1ère cellule, à adapter
pas = 3 'pas à adapter
Application.ScreenUpdating = False
While deb <> ""
  With Intersect(deb.CurrentRegion, Rows(deb.Row & ":" & Rows.Count))
    .Sort .Columns(col), xlAscending, Header:=xlYes
  End With
  Set deb = deb.Offset(, pas)
Wend
End Sub

Fichier (2).

A+