tri et déplacement de colonnes entre onglets

[EloiseRo]

Bonjour,

Voici mon problème :
Je travail avec une plate-forme internet qui me permet d'exporter un tableau excel. Ce tableau n'étant pas assez lisible à mon gout, je voudrais le modifier pour ne garder que certaines colonnes (pas dans le même ordre, ni même format...).
J'ai donc créé un document où je collerais le tableau exporté en premier onglet puis en 2ème onglet j'ai le tableau tel que j'aimerais qu'il soit. En fait je voudrais copier automatiquement certaines colonnes de ma première feuille (sans l'entete) et les coller dans l'autre mais à une autre place.

A savoir : Les colonnes A, C, D, E, K de la feuille 1 (AMADEO) à transferer sans la première ligne de titre respectivement dans les colonnes D, C, A, B, F de la feuille 2 (veilleE).

Pensez-vous que cela soit possible simplement ?

J'ai déjà vu certains articles sur le même genre d'opération avec une macro mais, étant novice en macro, j'ai un peu de mal à transposer.
Pouvez-vous m'aider à réaliser cette manip svp ? Cela m'éviterais des copier coller de colonnes à chaque fois que j'exporte cette feuille !

Merci d'avance,
Eloïse

 

[ROGER2327]

Re : tri et déplacement de colonnes entre onglets

Bonjour EloiseRo, bienvenue...

Ce code devrait faire le boulot :

[COLOR="DarkSlateGray"][B]Sub sélectionne()
Dim i&, j&, oDat, dDat, Col
   With Sheets("AMADEO")
      oDat = .Cells(2, 1).Resize(.Cells(.Rows.Count, 1).End(xlUp).Row - 1, 11).Value
      'Tableau d'origine.
   End With
   ReDim dDat(1 To UBound(oDat, 1), 1 To 6) 'Tableau de destination.
   Col = Array(Array(1, 3, 4, 5, 11), Array(4, 3, 1, 2, 6)) 'correspondance des colonnes
   For i = 1 To UBound(oDat, 1) 'copie ligne par ligne
      For j = 0 To UBound(Col(0))
         dDat(i, Col(1)(j)) = oDat(i, Col(0)(j))
      Next j
   Next i
   Sheets("VeilleE").Cells(6, 1).Resize(UBound(dDat, 1), 6).Value = dDat
End Sub[/B][/COLOR]

Mais vos cellules fusionnées dans la colonne A de la feuille VeilleE flanquent la pagaille !​

ROGER2327
#3944

Dimanche 8 Tatane 137 (Susception du Croc à Merdre, SS)
3 Thermidor An CCXVIII
2010-W29-3T14:07:46Z

 

[EloiseRo]

Re : tri et déplacement de colonnes entre onglets

Merci pour votre réponse !

La macro fonctionne bien, j'ai défusionné les cellules de ma première colonne (c'est mieux effectivement) !

Par contre j'ai une colonne "lien" dans mon premier onglet qui, quand elle se retrouve dans le 2ème onglet ne copie pas le chemin avec : le lien hypertexte ne s'ouvre plus.
Y a t-il une solution ?

Merci,
Eloïse

 

[ROGER2327]

Re : tri et déplacement de colonnes entre onglets

Re...

Peut-être cette rustine :

[COLOR="DarkSlateGray"][B]Sub sélectionne()
Dim i&, j&, oDat, dDat, Col
   [COLOR="Red"]With Sheets("AMADEO")[/COLOR]
      oDat = .Cells(2, 1).Resize(.Cells(.Rows.Count, 1).End(xlUp).Row - 1, 11).Value
      'Tableau d'origine.
      ReDim dDat(1 To UBound(oDat, 1), 1 To 6) 'Tableau de destination.
      Col = Array(Array(1, 3, 4, 5, 11), Array(4, 3, 1, 2, 6)) 'correspondance des colonnes
      For i = 1 To UBound(oDat, 1) 'copie ligne par ligne
         For j = 0 To UBound(Col(0))
            dDat(i, Col(1)(j)) = oDat(i, Col(0)(j))
         Next j
         [COLOR="Red"]If .Cells(i + 1, 11).Hyperlinks.Count Then dDat(i, 6) = .Cells(i + 1, 11).Hyperlinks.Item(1).Address[/COLOR]
      Next i
   [COLOR="Red"]End With[/COLOR]
   Sheets("VeilleE").Cells(6, 1).Resize(UBound(dDat, 1), 6).Value = dDat
End Sub[/B][/COLOR]

Mais je ne suis pas spécialiste des hyperliens : il y a probablement mieux à faire.​

ROGER2327
#3948

Lundi 9 Tatane 137 (Saints Ecrase-Merdre, sectateurs, SQ)
4 Thermidor An CCXVIII
2010-W29-4T09:01:12Z