tri automatique avec deux critères

[picronte]

Bonjour à tous,
j'ai un petit problème dans mon fichier qui a bien été élaboré par le fil.
Voilà j'aimerai que dans la feuil6 il me met les résultats de la base quand je sélectionne les deux critères en A1 et B1
merci
Ci-joint le fichier
Picronte

 

[CHALET53]

Re : tri automatique avec deux critères

Bonjour,

Une fois que tu as choisi p en A1 et d en B1, tu veux quelle information (intersection colonne où est p et ligne où est d ?) et où on loge cette information?
a+

 

[picronte]

Re : tri automatique avec deux critères

Bonjour Chalet53
En sélectionnant en AI (m) je souhaite qu'il me recopie les noms qui correspond de la base en A2 et en B1 je choisi le mot faim il me met en b2 le mot "faim qui correspond a "m" de A1
j'ai commencé un fichier le premier filtre fonctionne mais pas le deuxième
Cdt
Picronte

 

[picronte]

Re : tri automatique avec deux critères

Bonjour le fil,
Je relance ma demande, je me suis peut-être mal expliqué. je souhaiterai que dans la feiul7 quand je sélection une lettre P,M;l,k,j,h,y,v,i,o de la cellule A1 (en exemple j'ai sélectionné la lettre P) il me reprend les données de la base colonne AE (Noms qui correspond a la lettre p de la colonne BD et me les mettent en feuil7 a partir de A2 puis quand je sélection en B1de le feuil7 un mot ( espoir) je voudrais qu'il me met en B2 les réponses de la colonne AW de la base qui correspond a la lettre p et ainsi de suite
Merci
Picronte

 

[picronte]

Re : tri automatique avec deux critères

Bonjour le fil
Je vois que le post a été vu plusieurs fois sans réponse.
Pouvez- vous me dire si cela est possible ou peut-être par une autre solution

Merci
Picronte

 

[picronte]

Re : tri automatique avec deux critères

bonsoir le fil,
je réitère ma demande en espérant avoir une réponse
merci
picronte

 

[job75]

Re : tri automatique avec deux critères

Bonjour picronte, le forum,

Voyez le fichier joint avec cette macro dans le code de la feuille "Feuil7" :

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [A1:B1]) Is Nothing Then Exit Sub
Dim h As Long, col As Variant
Application.ScreenUpdating = False
Rows("2:" & Rows.Count).Delete 'RAZ
With Feuil1 'CodeName de la feuille "BASE"
  h = .Range("AE" & Rows.Count).End(xlUp).Row - 7
  If h < 1 Then Exit Sub 'sécurité
  .[AE8].Resize(h).Copy [A2] 'pour copier aussi les formats
  col = Application.Match([B1], [Liste2], 0)
  If IsNumeric(col) Then [B2].Resize(h) = [Liste2].Cells(2, col).Resize(h).Value
  [AA2].Resize(h) = .[BD8].Resize(h).Value
End With
[AB2].Resize(h).FormulaR1C1 = "=LN(AND(RC[-1]=R1C1,RC2=R1C2))"
[AB2].Resize(h) = [AB2].Resize(h).Value 'suppression des formules
[A2:AB2].Resize(h).Sort [AB2], xlAscending, Header:=xlNo 'tri pour accélérer la suppression
On Error Resume Next 's'il n'y a pas de valeurs d'erreur
[AB2].Resize(h).SpecialCells(xlCellTypeConstants, 16).EntireRow.Delete
[AA:AB].ClearContents
End Sub

Nota : vous aurez compris que la fonction LN permet d'obtenir des valeurs d'erreur...

A+

 

[job75]

Re : tri automatique avec deux critères

Message annulé...

 

[job75]

Re : tri automatique avec deux critères

Re,

Dans la liste de validation en B1 il y a "Amour" et "amour"...

Il faut donc que la casse soit respectée pour la recherche dans cette liste :

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [A1:B1]) Is Nothing Then Exit Sub
Dim h As Long, c As Range
Application.ScreenUpdating = False
Rows("2:" & Rows.Count).Delete 'RAZ
With Feuil1 'CodeName de la feuille "BASE"
  h = .Range("AE" & Rows.Count).End(xlUp).Row - 7
  If h < 1 Then Exit Sub 'sécurité
  .[AE8].Resize(h).Copy [A2] 'pour copier aussi les formats
  For Each c In [Liste2]
    If c = [B1] Then Exit For 'la casse est respectée
  Next
  If Not c Is Nothing Then [B2].Resize(h) = c(2).Resize(h).Value
  [AA2].Resize(h) = .[BD8].Resize(h).Value
End With
[AB2].Resize(h).FormulaR1C1 = "=LN(AND(RC[-1]=R1C1,RC2=R1C2))"
[AB2].Resize(h) = [AB2].Resize(h).Value 'suppression des formules
[A2:AB2].Resize(h).Sort [AB2], xlAscending, Header:=xlNo 'tri pour accélérer la suppression
On Error Resume Next 's'il n'y a pas de valeurs d'erreur
[AB2].Resize(h).SpecialCells(xlCellTypeConstants, 16).EntireRow.Delete
[AA:AB].ClearContents
End Sub

Fichier (2).

A+

 

[job75]

Re : tri automatique avec deux critères

Re,

Pour peaufiner, on peut donner le choix, en B1, entre AND (ET) et OR (OU) :

[AB2].Resize(h).FormulaR1C1 = "=LN(" & [B1] & "(RC[-1]=R1C1,RC3=R1C3))"

Fichier (3).

A+

 

[picronte]

Re : tri automatique avec deux critères

Bonjour le fil
Merci Job75
c'est cela que je recherchais
Picronte