Microsoft 365 Transposé des nombres

[Electron24]

Bonjour le Forum,

Je ne comprends pas pourquoi excel ne me fait pas la sommes des valeurs transposées en colonnes.
En effet,

du 12 Avril au 17 avril j'ai recopié manuellement les données.

A partir du 18 avril j'ai utilisé la fonction TRANSPOSE en faisant :

Sélection de la plage C290 à C337 de la feuille données Verticale

Click Droit sur Copier

Sélection de la cellule C21 de la feuille Données Horizontale

Collage Spécial

Cocher Valeurs et formats des nombres

Cocher Transposé

Et la je n'ai plus le total des 48 colonnes que j'avais en copiant manuellement les données.

 

[Electron24]

@Electron24


Pourtant avec le fichier que j'ai mis au post #6 j'ai ceci avec Excel 2010

Regarde la pièce jointe 1217174
Les erreurs sont avec ce fichier ou un autre ???

Je regarde cela de plus près demain car mon fichier donne une erreur aussi avec la proposition de Jean Eric. Ça dois forcément venir de moi.

 

[Phil69970]

@Electron24

Tiens nous au courant 🤣

 

[Electron24]

@Electron24

Tiens nous au courant 🤣

Ok

 

[AtTheOne]

Bonne nuit les petits !
@Electron24 je te transmets une solution avec
Un tableau structuré "TS_Relevé" pour recueillir tes relevés de consommation dans la feuille "Données Verticales".
Une feuille "Tableau Jours-Heures" qui comporte 4 formules matricielle dynamiques pour générer ton tableau dit "horizontal"
Note que avec quelques modifications sur tes données brutes un tableau croisé dynamique ferait l'affaire.
Les formules
Les dates

=TRIER(UNIQUE(ENT(TS_Relevé[Date]));;-1)

Les totaux journaliers

=BYROW(Relevé#;LAMBDA(L;SOMME(L)))

Les horaires

=TRANSPOSE(UNIQUE(TS_Relevé[Date]-ENT(TS_Relevé[Date])))

Les relevés

=SIERREUR(CNUM(SUBSTITUE(SUBSTITUE(RECHERCHEX(A3#+C2#;TS_Relevé[Date];TS_Relevé[Consommation];"");" kWh";"");".";","));"-")

Voir le fichier joint

À bientôt

 

[AtTheOne]

Re bonjour,
Je sais la partie est finie mais je bricole sur mon téléphone, car sur le PC à ma disposition ici je n'ai que EXCEL 2021.
C'est pas coton !
Voici une version avec Un total mensuel pour un mois choisi.

Voir le fichier joint
À bientôt

 

[Electron24]

Bonjour à tous,

Alors comme promis je reviens vers vous.

Après le tuto sur Power Query, je pense opter pour cette solution, cela me semble beaucoup plus pratique que toutes ces formules ou j'y perd mon latin.
Donc merci à vous tous pour vos solutions enrichissantes.
Je vais donc mettre en pratique la solution de vgendron
Cordialement et bonne journée.

 

[Electron24]

Bonjour AtTheOne

En regardant ton travail de plus près, j'ai exactement la même erreur que Phil69970 c'est à dire une erreur #VALEUR sur toutes les lignes dés que j'ai voulu entrer les données de ce jour. Je me retrouve avec un tableau vide.
De plus, le tableau commence à 21:30 ce qui est ennuyeux pour la suite de mon travail.
Je ne comprends pas

 

[Phil69970]

@Electron24

Est ce que cela fonctionne avec le fichier fournit sans rien toucher d'autre donc sans rajouter des nouvelles journées ?

Je suis absent cet apres midi donc je verrais ce soir ta réponse

 

[AtTheOne]

re

De plus, le tableau commence à 21:30 ce qui est ennuyeux pour la suite de mon travail.

Fait attention, il y a des volets figés en $C$3, il faut faire défiler vers la gauche. 😉

j'ai exactement la même erreur que Phil69970 c'est à dire une erreur #VALEUR sur toutes les lignes dés que j'ai voulu entrer les données de ce jour.

Peux-tu me transmettre le fichier avec les saisies qui provoquent l'erreur ?
Sur mon tétéphone cela fonctionne !

Est-tu vraiment avec EXCEL365 ?
À bientôt

PS

Je vais donc mettre en pratique la solution de vgendron

Donc marque plutôt son post #5 comme solution retenue

 

[Electron24]

j'ai essayé de rajouter un jour et voici ce que cela donne
Je suis sur OFFICE 365

 

[Electron24]

Pour Phil69970, oui cela fonctionne sur le ficher sans rajout

 

[AtTheOne]

Re,
Le problème vient de l'absence du point dans la mesure ajoutée le 18/04 à 2:00
Je peux prendre une précaution pour le cas ou la valeur de la colonne est déjà une valeur numérique et nom une chaîne de caractère avec 1 point ...
À bientôt

 

[AtTheOne]

Re
Heu, ce n'est pas ça ! si je revalide la formule, le calcul se fait bien ! 🤔
À +

 

[mapomme]

Re,

Je ne comprends pas pourquoi vous n'utilisez pas de formules. Notamment celle du message #7 .
La formule (mais aussi toutes les autres formules) est aisément compréhensible et le tableau résultat est toujours à jour; pas besoin d'actualisation.

Formule du message #7 (en C11) :
=SIERREUR(1*SUBSTITUE(SUBSTITUE(RECHERCHEV($A11 + C$1;'Données Verticale'!$B$1:$C$99999;2;FAUX);" kWh";"");".";",");"")


Explication de la formule :

On commence par définir la date avec l'heure au sein du tableau résultat
$A11 + C$1

On recherche cette date et l'heure dans la colonne B et on renvoie la valeur de la colonne C par un simple RECHERCHEV
RECHERCHEV($A11 + C$1;'Données Verticale'!$B$1:$C$99999;2;FAUX)

La valeur retournée comprend une unité qu'on va éliminer avec SUBSTITUE :
SUBSTITUE(RECHERCHEV($A11 + C$1;'Données Verticale'!$B$1:$C$99999;2;FAUX);" kWh";"")

La valeur retournée comprend un point décimal qu'on va éliminer avec SUBSTITUE :
SUBSTITUE(SUBSTITUE(RECHERCHEV($A11 + C$1;'Données Verticale'!$B$1:$C$99999;2;FAUX);" kWh";"");".";",");""

On convertit le résultat en nombre avec une multiplication par 1
1*SUBSTITUE(SUBSTITUE(RECHERCHEV($A11 + C$1;'Données Verticale'!$B$1:$C$99999;2;FAUX);" kWh";"");".";",")

Et on a le résultat... Est-ce vraiment si compliqué ?

nota : si une date et une heure est absente de la source, alors la formule renvoie une erreur (car Recherchev ne trouve rien). Dans ce cas on affiche "" :
=SIERREUR(1*SUBSTITUE(SUBSTITUE(RECHERCHEV($A11 + C$1;'Données Verticale'!$B$1:$C$99999;2;FAUX);" kWh";"");".";",");"")

 

[Jean-Eric]

Bonjour,
Une mise à jour avec un détail mensuel (voir liste de validation).
Cdlt.