Transformer en négatif toutes les valeurs d'une colonne

[David590]

Bonjour à tous,

Et bien... tout est dans le titre 😀

J'ai besoin de transformer en négatif toutes les valeurs d'une colonne

Je connais cette solution : Range("B2") = -Range("B2")

qui consiste à le faire pour une cellule, mais comment faire pour l'appliquer à la colonne complète ?

 

[CHALET53]

Re : Transformer en négatif toutes les valeurs d'une colonne

bonjour
tu fais une boucle sur ta colonne du genre :
Sub essai()
For i = 1 To 3
Range("B" & i) = -Range("B" & i)
Next i
End Sub

en remplaçant 3 par dernière ligne de la colonne

a+

 

[DoubleZero]

Re : Transformer en négatif toutes les valeurs d'une colonne

Bonjour, David590, le Forum,

Comme ceci ?

Option Explicit
Sub Négatif()
Dim c As Range
    For Each c In Range(Range("b2"), Range("b2").End(xlDown))
        If IsNumeric(c) And c > 0 Then c.Value = c.Value * -1
    Next
End Sub

A bientôt 🙂

P. S. : Bonjour, CHALET53

 

[David590]

Re : Transformer en négatif toutes les valeurs d'une colonne

Bonjour CHALET53, DoubleZero,

C'est exactement ce que je voulais

Merci à vous

@+

 

[kjin]

Re : Transformer en négatif toutes les valeurs d'une colonne

Soirbon,
Sélectionne une cellule ou tu auras écris -1 puis copier/collage spécial/multiplication
A+
kjin

 

[Pierrot93]

Re : Transformer en négatif toutes les valeurs d'une colonne

Bonjour à tous

une autre approche qui évite la boucle :

With Range("K1")
    .Value = "-1"
    .Copy
    Range("A1", Range("A65536").End(xlUp)).PasteSpecial Paste:=xlPasteAll, Operation:=xlMultiply
    .ClearContents

bonne soirée
@+

Edition : bonjour Kjin.. Aarf pas raffraichi moi...

 

[job75]

Re : Transformer en négatif toutes les valeurs d'une colonne

Bonjour à tous,

Sans boucle et uniquement pour le fun :

Sub SigneMoins()
With Range("A1", [A65536].End(xlUp))
  ThisWorkbook.Names.Add "Table", .Value
  .Formula = "=IF(ISNUMBER(INDEX(Table,ROW())),-ABS(INDEX(Table,ROW())),IF(ISNA(INDEX(Table,ROW())),"""",INDEX(Table,ROW())))"
  .Value = .Value
End With
ThisWorkbook.Names("Table").Delete
End Sub

A+

 

[job75]

Re : Transformer en négatif toutes les valeurs d'une colonne

Re,

Avec une formule matricielle 😛 c'est plus rapide et encore plus fun :

Sub SigneMoins()
With Range("A1", [A65536].End(xlUp))
  ThisWorkbook.Names.Add "Table", .Value
  .FormulaArray = "=IF(ISNUMBER(Table),-ABS(Table),IF(ISNA(Table),"""",Table))"
  .Value = .Value
End With
ThisWorkbook.Names("Table").Delete
End Sub

A+

 

[David590]

Re : Transformer en négatif toutes les valeurs d'une colonne

Bonsoir tous le monde,

Je n'ai que l'embarras du choix

Merci à tous 😉

 

[David590]

Re : Transformer en négatif toutes les valeurs d'une colonne

Re,

Avec une formule matricielle 😛 c'est plus rapide et encore plus fun :

Sub SigneMoins()
With Range("A1", [A65536].End(xlUp))
  ThisWorkbook.Names.Add "Table", .Value
  .FormulaArray = "=IF(ISNUMBER(Table),-ABS(Table),IF(ISNA(Table),"""",Table))"
  .Value = .Value
End With
ThisWorkbook.Names("Table").Delete
End Sub

A+

Bonjour tout le monde,

Apparemment c'est ce code qui me conviendrait le mieux car rapide et surtout c'est le seul qui ne m'affiche pas de 0 si les cellules sont vide, le seul problème est qu'il ne fonctionne pas si le format de la colonne est en monétaire
J'ai d'ailleurs mis du temps pour savoir d'ou venait le problème puisqu'il fonctionnait sur mon classeur test mais pas sur mon classeur final)

Donc je vais faire un changement de format au début et à la fin du code, à moins que l'on puisse modifier quelque chose directement ?

 

[job75]

Re : Transformer en négatif toutes les valeurs d'une colonne

Bonjour David590,

Utilisez .Value2 au lieu de .Value :

Sub SigneMoins()
With Range("A1", [A65536].End(xlUp))
  ThisWorkbook.Names.Add "Table", .Value2
  .FormulaArray = "=IF(ISNUMBER(Table),-ABS(Table),IF(ISNA(Table),"""",Table))"
  .Value = .Value
End With
ThisWorkbook.Names("Table").Delete
End Sub

A+

 

[David590]

Re : Transformer en négatif toutes les valeurs d'une colonne

Super

Merci job75

A+