XL 2010 Télécharger données autres classeurs dans un fichier excel en vba

Créer une discussion
Répondre
  • Initiateur de la discussion Initiateur de la discussion BBDan
  • Date de début Date de début

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
B

BBDan

XLDnaute Nouveau
Bonjour,
J'ai un dossier nommé "Factures" dans lequel j'enregistre toutes mes factures clients.
Dans chaque facture, j'ai nommé des cellules spécifiques contenant des données que j'aimerais exploiter.
Je voudrais qu'Excel aille me chercher les données des cellules nommées dans chaque facture de ce dossier et me les rentre automatiquement dans mon fichier RECAP FACTURES en les triant par chantier.
Il faudrait qu'il crée une nouvelle ligne dès qu'une nouvelle facture est créée.
J'ai créé un bouton "Actualiser" pour effectuer cette macro mais j'avoue que je débute en macro et ne sais pas vraiment comment m'y prendre.
Je mets en pièce jointe un exemple de facture et mon tableau récap.
J'ai commencé une macro, mais j'ai besoin d'aide.
Merci d'avance.
 

Pièces jointes

Solution
job75
Cela dit VBA a prévu le coup, il suffit de remplacer l'apostrophe par... 2 apostrophes :
VB: 
    If fichier <> ThisWorkbook.Name Then
        fichier = Replace(fichier, "'", "''")
        form = "'" & chemin & "[" & fichier & "]FACTURE'!"
Testez les fichiers joints.
Trier par date Trier par votes
Bonsoir BBDan,

Téléchargez les fichiers joints dans le même dossier et exécutez cette macro :
VB: 
Sub Actualiser()
Dim chemin$, fichier$, a, b(), lig&, form$, i%
chemin = ThisWorkbook.Path & "\" 'dossier à adapter
fichier = Dir(chemin & "*.xls*")
a = Array("DATE", "N°FACT", "N°SITU", "CHANTIER", "LOT", "BASEHT", "AVT_1", "AVT_2", "AVT_3", "AVT_4", "AVT_5", "AVT_6", "AVT_7", "TOTALMARCHE", "FACTHT")
ReDim b(1 To 15)
lig = 3 '1ère ligne de restitution
Application.ScreenUpdating = False
On Error Resume Next
While fichier <> ""
    form = "'" & chemin & "[" & fichier & "]FACTURE'!"
    For i = 1 To 15
        b(i) = ExecuteExcel4Macro(form & a(i - 1))
        If Err Or IsError(b(i)) Then Err = 0: GoTo 1
    Next
    Cells(lig, 1).Resize(, 15) = b 'restitution sur 15 colonnes
    lig = lig + 1
1   fichier = Dir 'fichier suivant
Wend
Rows(lig & ":" & Rows.Count).Delete 'RAZ en dessous
Columns.AutoFit 'ajustement largeurs
End Sub
Les fichiers sources sont copiés tout en restant fermés.

Je m'occuperai de la colonne P quand vous nous direz ce qu'il faut y mettre 🙄

PS : le nom "N°SITU" n'existait pas, je l'ai créé et j'ai recréé aussi "AVT_1"..."AVT_7".

A+
 

Pièces jointes

Dernière édition:
Vote positif 1 Vote négatif
Waouh ! Chapeau Job75 ! Je suis ébahie devant tant de savoir.
Je vous remercie infiniment d'avoir passé du temps sur ce projet.
Ingénieux la mise en forme personnalisée pour N°SITU !
La macro fonctionne super bien pour la facture en PJ de mon 1er post, mais par exemple pour celle en pièce jointe, cela ne fonctionne pas.

En effet, chaque facture est différente : il y a des constantes comme DATE, N°FACT, CHANTIER, LOT, FACTHT
Mais il y a aussi des variables, comme pour les avenants (dans certaines factures, il n'y en a pas et dans d'autres il peut y en avoir une vingtaine), le N°SITU peut apparaître sur certaines factures et pas sur d'autres.
Je voudrais qu'Excel remplisse le tableau en fonction des cellules nommées qu'il trouve dans chaque facture.

Faut-il que le classeur RECAP FACTURE soit dans le même dossier que mes factures ?

Pour ce qui est de la colonne P, il faudrait qu'Excel calcule la différence entre le MONTANT TOTAL MARCHE HT et le MONTANT FACTURE HT.

Serait-il possible également d'automatiser le calcul du MONTANT TOTAL MARCHE HT en faisant la somme depuis MONTANT BASE HT jusqu'au dernier AVT ?

Je suis impatiente de découvrir vos conseils et vos solutions.
Encore un grand MERCI !
 

Pièces jointes

Vote positif 0 Vote négatif
Voyez ce fichier (2), je pense que cette macro fait ce que vous souhaitez :
VB: 
Sub Actualiser()
Dim chemin$, fichier$, a, b(), lig&, form$, i%
chemin = ThisWorkbook.Path & "\" 'dossier à adapter
fichier = Dir(chemin & "*.xls*")
a = Array("DATE", "N°FACT", "N°SITU", "CHANTIER", "LOT", "BASEHT", "AVT_1", "AVT_2", "AVT_3", "AVT_4", "AVT_5", "AVT_6", "AVT_7", "TOTALMARCHE", "FACTHT")
ReDim b(1 To 16)
lig = 3 '1ère ligne de restitution
Application.ScreenUpdating = False
While fichier <> ""
    If fichier <> ThisWorkbook.Name Then
        form = "'" & chemin & "[" & fichier & "]FACTURE'!"
        For i = 1 To 15
            b(i) = ExecuteExcel4Macro(form & a(i - 1))
            If IsError(b(i)) Then b(i) = Empty
            If i > 5 Then If Not IsNumeric(b(i)) Then b(i) = Empty 'sécurité
        Next
        If IsEmpty(b(14)) Then b(14) = b(6) + b(7) + b(8) + b(9) + b(10) + b(11) + b(12) + b(13)
        If b(14) = 0 Then b(14) = Empty
        If b(14) <> b(15) Then b(16) = b(14) - b(15) 'colonne N - colonne O
        If Application.CountA(b) Then
            Cells(lig, 1).Resize(, 16) = b 'restitution sur 16 colonnes
            lig = lig + 1
        End If
    End If
    fichier = Dir 'fichier suivant
Wend
On Error Resume Next
Rows(lig & ":" & Rows.Count).Delete 'RAZ en dessous
Columns.AutoFit 'ajustement largeurs
End Sub
En colonne P on obtient la différence entre la colonne N et la colonne O comme demandé mais cela me paraît bizarre, il faudrait à mon avis retrancher la somme de toutes les factures précédentes et ça ce n'est pas facile.

Comme déjà dit tous les fichiers doivent être placés dans le même dossier.
 

Pièces jointes

Dernière édition:
Vote positif 1 Vote négatif
Super ! Merci beaucoup Job75. C'est vraiment génial !
Pour ce qui est de la différence, j'ai inséré une colonne "Cumul facturé", nommé la cellule dans la facture et adapté la macro à 17 colonnes au lieu des 16.
Je suis ravie de votre aide et vous remercie infiniment.
 
Vote positif 0 Vote négatif
Bonjour,
J'ai voulu adapter la macro de Job75 à mon nouveau tableau, mais la macro bug.
Pourriez-vous m'aider svp ? Mon tableau ne comprend plus que 10 colonnes et la dernière colonne doit être la somme des colonnes 8 et 9.
Voici la macro :
Sub Actualiser()
Dim chemin$, fichier$, a, b(), lig&, form$, i%
chemin = ThisWorkbook.Path & "\" 'dossier à adapter
fichier = Dir(chemin & "*.xls*")
a = Array("DATE", "N°FACT", "N°SITU", "CLIENT", "CHANTIER", "LOT", "ENGT", "TTCAVTRG", "RGTTC")
ReDim b(1 To 10)
lig = 3 '1ère ligne de restitution
Application.ScreenUpdating = False
While fichier <> ""
If fichier <> ThisWorkbook.Name Then
form = "'" & chemin & "[" & fichier & "]FACTURE'!"
For i = 1 To 10
b(i) = ExecuteExcel4Macro(form & a(i - 1))
If IsError(b(i)) Then b(i) = Empty
If i > 8 Then If Not IsNumeric(b(i)) Then b(i) = Empty 'sécurité
Next
If b(8) = 0 Then b(8) = Empty
If b(8) <> b(9) Then b(10) = b(8) + b(9) 'colonne H + colonne I
If Application.CountA(b) Then
Cells(lig, 1).Resize(, 10) = b 'restitution sur 10 colonnes
lig = lig + 1
End If
End If
fichier = Dir 'fichier suivant
Wend
On Error Resume Next
Rows(lig & ":" & Rows.Count).Delete 'RAZ en dessous
Columns.AutoFit 'ajustement largeurs
End Sub
 

Pièces jointes

Vote positif 0 Vote négatif
Le fichier en retour, les seules modifications de la macro ont porté sur :
VB: 
        For i = 1 To 9
            b(i) = ExecuteExcel4Macro(form & a(i - 1))
            If IsError(b(i)) Then b(i) = Empty
            If b(i) = 0 Then b(i) = Empty
            If i > 7 Then If Not IsNumeric(b(i)) Then b(i) = Empty 'sécurité
        Next
        b(10) = b(8) + b(9) 'colonne H + colonne I
        If b(10) = 0 Then b(10) = Empty
 

Pièces jointes

Vote positif 1 Vote négatif
Je viens de me rendre compte que Application.CountA(b) renvoie toujours 10 même quand la ligne est vide.

Il faut donc compter les cellules non vides, utilisez le fichier joint avec :
VB: 
Sub Actualiser()
Dim chemin$, fichier$, a, b(), lig&, form$, s%, i%
chemin = ThisWorkbook.Path & "\" 'dossier à adapter
fichier = Dir(chemin & "*.xls*")
a = Array("DATE", "N°FACT", "N°SITU", "CLIENT", "CHANTIER", "LOT", "ENGT", "TTCAVTRG", "RGTTC")
ReDim b(1 To 10)
lig = 3 '1ère ligne de restitution
Application.ScreenUpdating = False
While fichier <> ""
    If fichier <> ThisWorkbook.Name Then
        form = "'" & chemin & "[" & fichier & "]FACTURE'!"
        s = 0
        For i = 1 To 9
            b(i) = ExecuteExcel4Macro(form & a(i - 1))
            If IsError(b(i)) Then b(i) = Empty
            If b(i) = 0 Then b(i) = Empty
            If i > 7 Then If Not IsNumeric(b(i)) Then b(i) = Empty 'sécurité
            If Not IsEmpty(b(i)) Then s = s + 1 'compte les valeurs non vides
        Next
        b(10) = b(8) + b(9) 'colonne H + colonne I
        If b(10) = 0 Then b(10) = Empty
        If s Then
            Cells(lig, 1).Resize(, 10) = b 'restitution sur 10 colonnes
            lig = lig + 1
        End If
    End If
    fichier = Dir 'fichier suivant
Wend
On Error Resume Next
Rows(lig & ":" & Rows.Count).Delete 'RAZ en dessous
Columns.AutoFit 'ajustement largeurs
End Sub
 

Pièces jointes

Vote positif 0 Vote négatif
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

good57
  • Question Question
Microsoft 365 Récupération de données dans d'autres fichier
Réponses
1
Affichages
67
good57
good57
H
  • Question Question
Power Query Récupérer des données multiples dans un dossier
Réponses
9
Affichages
122
hijackfr
H
J
  • Question Question
Microsoft 365 Copie des onglets dans un fichier séparé depuis une liste en VBA
Réponses
3
Affichages
53
job75
job75
X
  • Question Question
XL 2021 Transformation de données sur une ligne en plusieurs lignes
Réponses
9
Affichages
171
xavieralvaro
X
P
  • Question Question
XL 2016 VBA Appliquer un filtre sur mes données importées
Réponses
4
Affichages
111
sousou
sousou
P
  • Question Question
XL 2019 Macro VBA appliquer un filtre lors d'une importation de données
Réponses
1
Affichages
92
fanch55
fanch55
M
  • Résolu(e)
XL 2013 Macross supprimant les données de cellule en dehors d'une période définie dans deux autres cellules
Réponses
9
Affichages
580
MarineU
M
E
  • Question Question
Microsoft 365 Problème de conversion des mois en périodes dans Excel avec VBA
Réponses
2
Affichages
602
RyuAutodidacte
RyuAutodidacte
V
  • Question Question
XL 2021 Implémenter tableau avec des fichiers mis dans un dossier
Réponses
2
Affichages
368
merinos-BernardEtang
merinos-BernardEtang
Chaton77
  • Résolu(e)
Microsoft 365 Vba : Transférer des données d'un tableau dans un autre fichier
Réponses
7
Affichages
487
Chaton77
Chaton77
Oscar21
  • Question Question
XL 2019 Importer des classeurs à la suite dans un tableau existant
2
Réponses
15
Affichages
2 K
Hasco
Hasco
J
  • Question Question
Microsoft 365 macro qui ouvre des fichiers excel de type "analyze in excel" généré par power bi et met à jour un filtre "mois" sur plusieurs tcd
Réponses
0
Affichages
140
JJ69
J
A
  • Question Question
XL 2021 Macro copier dans un fichier Excel sur Sharepoint
Réponses
1
Affichages
294
vgendron
vgendron
A
  • Question Question
XL 2021 Automatiser la génération de documents Word à partir d’Excel avec VBA
Réponses
12
Affichages
297
ali591
A
M
Excel et Co-edition dans un fichier sharepoint.
Réponses
0
Affichages
80
Mcgirard13
M
S
  • Question Question
Microsoft 365 VBA Requette SQL sur un autre fichier excel
Réponses
13
Affichages
470
dysorthographie
dysorthographie
D
  • Question Question
XL 2010 suppression de lignes dans un fichier EXCEL via une routine en VBA
Réponses
2
Affichages
611
mapomme
mapomme
A
  • Question Question
XL 2019 Copier une plage dans un fichier fermé en VBA
2
Réponses
21
Affichages
2 K
Amilo
A
L
  • Question Question
Autres Copier des données d’un fichier sans l’ouvrir juste en le sélectionnant via un UserForm
Réponses
6
Affichages
729
Liner77
L
L
  • Question Question
Microsoft 365 vba Outlook traiter un fichier excel lors de sa reception
Réponses
0
Affichages
562
lesoldat9
L
Retour