XL 2010 Tableau / faireclignoter des cellules si vide

[GADENSEB]

Bonjour,
Je viens vers vous car je commence à traiter les tableaux automatique et je ne suis pas trés à l'aise

Je souhaiterais faire clignoter des cellules tant qu'elle ne sont pas remplies pour Les colonnes F J N et P.

Pour les tableaux auto. il vaut mieux passer par une mfc ou unemacro ?

Merci

Bonne journée

 

[PMO2]

Bonjour,
On oublie le clignotement qui va utiliser trop de ressources.
La piste que je propose est de colorer les cellules vides concernées du tableau (ListObject).
Voir la pièce jointe.

1) Copiez le code suivant dans un module standard

Sub CellsVides(Cible As Range)
Dim LO As ListObject
Dim Plage As Range
Dim C As Range
Dim i&
Dim k&
Dim COLS As Variant
'--- Les colonnes où il faut agir ---
COLS = Array(6, 10, 14, 16)
'--- Identifcation du ListObject (Tableau) ---
On Error GoTo Erreur
Set LO = ActiveSheet.ListObjects(1)
On Error GoTo 0
'--- La plage du ListObject ---
Set Plage = LO.Range
'--- On sort si la cellule qui a changé n'appartient pas à la plage du ListObject ---
If Application.Intersect(Cible, Plage) Is Nothing Then Exit Sub
'--- Efface toute couleur du ListObject ---
Plage.Interior.Pattern = xlNone
'--- Colorise les cellules vides concernées ---
For k& = LBound(COLS) To UBound(COLS)
  For i& = Plage.Row To Plage.Rows.Count + Plage.Row - 1
    Set C = ActiveSheet.Cells(i&, Plage.Column + COLS(k&) - 1)
    If C = "" Then C.Interior.Color = vbCyan
  Next i&
Next k&
Exit Sub
'---
Erreur:
End Sub

2) Copiez le code suivant dans la fenêtre de code de la feuille concernée

Private Sub Worksheet_Change(ByVal Target As Range)
Call CellsVides(Target)
End Sub

 

[JHA]

Bonjour à tous,

Par MFC couleur rouge sans clignotement

JHA

 

[GADENSEB]

Hello tous les deux
Lesdeux solutions sont au top
Merci !!!
bon début de semaine