syntaxe VBA plage de cellule avec variable

Sub verif2()
    Dim i As Long

    'Recherche de la ligne et tri dans chaque feuille
    With Sheets("HR")
        For i = 2 To 300
            If .Cells(i, "c") = .Cells(i, "f") And .Cells(i, "d") = .Cells(i, "g") And .Cells(i, "e") = .Cells(i, "h") Then
                .Cells(i, "m") = .Cells(i, "i")
            End If
        Next i
    End With

End Sub

Sub verif2()
Dim i&, j&, egal As Boolean
   'Recherche de la ligne et tri dans chaque feuille
   With Sheets("HR")
      For i = 2 To 300
         egal = True
         For j = 0 To 2
            egal = egal And (.Cells(i, "c").Offset(, j) = .Cells(i, "f").Offset(, j))
         Next j
         If egal Then .Cells(i, "m") = .Cells(i, "i")
      Next i
   End With
End Sub

Sub verif2()
  With Sheets("HR")
    .Range("m2").FormulaArray = _
        "=IF(AND(RC[-10]:RC[-8]=RC[-7]:RC[-5]),IF(RC[-4]="""","""",RC[-4]),"""")"
    .Range("m2").AutoFill Destination:=Range("m2:m300"), Type:=xlFillDefault
    .Range("m2:m300") = .Range("m2:m300").Value
  End With
End Sub

Sub verif2()
Dim P1 As Range, P2 As Range, P3 As Range, P4 As Range
Dim t1, t2, t3, t4, ncol%, i&, j%
With Sheets("HR")
Set P1 = .[C2:E300]: Set P2 = .[F2:H300]: Set P3 = .[I2:I300]: Set P4 = .[M2:M300]
End With
P4 = "" 'facultatif, si l'on veut réinitialiser la plage
t1 = P1: t2 = P2: t3 = P3: t4 = P4 'matrices, plus rapides
ncol = UBound(t1, 2)
For i = 1 To UBound(t1)
  For j = 1 To ncol
    If t1(i, j) <> t2(i, j) Then GoTo 1
  Next
  t4(i, 1) = t3(i, 1)
1 Next
P4 = t4 'restitution
End Sub

Sub UnPetitChiconNonAutofilet()
With Sheets("HR").Range("m2:m300")
.FormulaArray = _
"=IF(AND(RC[-10]:RC[-8]=RC[-7]:RC[-5]),IF(RC[-4]="""","""",RC[-4]),"""")"
.Value = .Value
End With
End Sub

Sub UnPetitChiconNonAutofilet()
With Sheets("HR").Range("m2:m300")
.FormulaArray = _
"=IF((C2:C300=F2:F300)*(D2:D300=G2:G300)*(E2:E300=H2:H300),IF(I2:I300="""","""",I2:I300),"""")"
.Value = .Value
End With
End Sub