Microsoft 365 Supprimer une ligne en fonction de la valeur d'une cellule

Coralie01120 · 9 Février 2021

Bonjour,

Je débute en VBA et je ne trouve pas le code VBA qui pourrait me convenir sur ce forum. Je joins le fichier pour mieux comprendre.

Je cherche à supprimer une ligne entière quand le contenu de la colonne B est égal à « 05 Total ». Cela peut aussi être « 01 Total » ou encore « 12 Total » … En fait dès que le mot Total est dans une cellule de la colonne B j’aimerai supprimer la ligne mais je ne trouve pas comment faire.

Je souhaite également, toujours via une macro renseigner les onglets site_A, site_B et site_C avec le contenu pour chaque site (les données avec « A » et « A Total » dans la colonne C de l’onglet Sheet1 dans l’onglet site_A).

job75 · 9 Février 2021

Bonsoir Coralie01120, sylvanu, soan,

Coralie01120 à dit:
En fonction de la lettre (du site) j’aimerais alimenter 3 onglets différents. . L’affichage est est même, mais en supprimant la colonne B du site.

Dans Thisworkbook avec le filtre avancé :

VB:

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If UCase(Left(Sh.Name, 5)) <> "SITE_" Then Exit Sub
Dim critere$, derlig&
critere = Mid(Sh.Name, 6)
Application.ScreenUpdating = False
If Sh.FilterMode Then Sh.ShowAllData 'si la feuille est filtrée
Sh.Rows("6:" & Sh.Rows.Count).Delete
With Sheets("Sheet1")
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    derlig = .Cells(.Rows.Count, 3).End(xlUp).Row
    .[K7] = "=C7=""" & critere & """"
    .Range("A6:I" &...

sylvanu · 9 Février 2021

Bonsoir Coralie,
Un essai en PJ , pour la première partie, avec cette macro :

VB:

Sub Supprime()
    Application.ScreenUpdating = False
    DL = Range("B65500").End(xlUp).Row
    For L = DL To 1 Step -1
        If Cells(L, "B") Like "*Total*" Then
            Cells(L, 1).EntireRow.Delete
        End If
    Next L
End Sub

Pour le second point, est ce que Site correspond à Plant de la Sheet1 ( colonne B ) ?

Coralie01120 · 9 Février 2021

sylvanu à dit:
Bonsoir Coralie,
Un essai en PJ , pour la première partie, avec cette macro :

VB:

Sub Supprime() Application.ScreenUpdating = False DL = Range("B65500").End(xlUp).Row For L = DL To 1 Step -1 If Cells(L, "B") Like "*Total*" Then Cells(L, 1).EntireRow.Delete End If Next L End Sub

Pour le second point, est ce que Site correspond à Plant de la Sheet1 ( colonne B ) ?

Bonjour Sylvanu,

Super ça fonctionne pour le 1er point. Je n’avais pas pensé aux astérisques...

Oui c’est ça ! En fait dans Sheet1 la colonne B contient soit A, B ou C. En fonction de la lettre (du site) j’aimerais alimenter 3 onglets différents. L’affichage est est même, mais en supprimant la colonne B du site.

soan · 9 Février 2021

Bonjour @Coralie01120, sylvanu,

euh, pour ta 2ème demande, sur les 3 feuilles de destination "SITE_A", "SITE_B", "SITE_C", il me semble que tu as oublié la colonne « Plant », entre les 2 colonnes "Week" et "Day" !

(à moins que vraiment tu ne la veuilles plus ? peut-être que tu es devenue allergique à la chlorophylle ? )

soan

sylvanu · 9 Février 2021

Re bonsoir,
En PJ un essai.
Pour faire simple je recopie les 9 colonnes. Dans les feuilles SITES_X la colonne C est masquée.

job75 · 9 Février 2021

Bonsoir Coralie01120, sylvanu, soan,

Coralie01120 à dit:
En fonction de la lettre (du site) j’aimerais alimenter 3 onglets différents. . L’affichage est est même, mais en supprimant la colonne B du site.

Dans Thisworkbook avec le filtre avancé :

VB:

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If UCase(Left(Sh.Name, 5)) <> "SITE_" Then Exit Sub
Dim critere$, derlig&
critere = Mid(Sh.Name, 6)
Application.ScreenUpdating = False
If Sh.FilterMode Then Sh.ShowAllData 'si la feuille est filtrée
Sh.Rows("6:" & Sh.Rows.Count).Delete
With Sheets("Sheet1")
    If .FilterMode Then .ShowAllData 'si la feuille est filtrée
    derlig = .Cells(.Rows.Count, 3).End(xlUp).Row
    .[K7] = "=C7=""" & critere & """"
    .Range("A6:I" & derlig).AdvancedFilter xlFilterCopy, .[K6:K7], Sh.[A6:I6] 'filtre avancé
    .[K7] = ""
End With
derlig = Sh.Cells(Sh.Rows.Count, 3).End(xlUp).Row
Sh.Range("C6:C" & derlig).Delete xlToLeft
Range("A6:H" & derlig).Borders(xlEdgeBottom).Weight = xlMedium 'bordure du bas
With Sh.UsedRange: End With 'actualise les barres de défilement
End Sub

La macro se déclenche quand on active une feuille.

A+

Coralie01120 · 18 Février 2021

Bonjour,

Merci pour vos solutions. C'est exactement ce que je voulais.

Bonne journée,

Microsoft 365 Supprimer une ligne en fonction de la valeur d'une cellule

Coralie01120

XLDnaute Occasionnel

Pièces jointes

job75

sylvanu

XLDnaute Barbatruc

Pièces jointes

Coralie01120

XLDnaute Occasionnel

soan

XLDnaute Barbatruc

sylvanu

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

Coralie01120

XLDnaute Occasionnel

Discussions similaires