Supprimer lignes vides de valeurs

[Garamante]

Bonsoir !!!

Je voudrais supprimer toutes les lignes de ma feuille qui ne possèdent pas de contenu sachant qu'elles possèdent toutes de même des formules.
Pour le dire d'une autre façon ;o) supprimer toutes les lignes sans valeurs (sans tenir compte des formules qu'elles contiennent) ;o)

Je ne sais pas si je me suis bien exprimé ;o)))


En tout cas merci d'avance !!!

 

[CBernardT]

Bonsoir Garamante

Une macro qui j'espère répondra as ton soucis ?

Sub SupLignesVides()
Dim Mat As Variant
Dim j As Long
Mat = ActiveSheet.UsedRange
For j = 1 To UBound(Mat)
Mat = ActiveSheet.UsedRange
If j > UBound(Mat) Then Exit Sub
If Application.Count(Cells(j, 1).EntireRow) = 0 Then
Cells(j, 1).EntireRow.Delete
j = j - 1
End If
Next j
End Sub

Cordialement

CBernardT

 

[Garamante]

Ben en fait non ;o(, je ne sais pas pourquoi d'ailleurs; cela me supprime juste ma premiere ligne contenant du texte mais toutes les autres contenant des formules restent en place ...

 

[Garamante]

Sub CLEAN()
Sheets("Feuil1").Columns(1).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub


cette dernière fonctionne dans le principe mais comment l'adapter pour qu'elle supprime uniquement les cellules vide de valeur (mais pas de formules ) ????

 

[myDearFriend]

Bonsoir Garamante, CBernardT.


Tu peux essayer la procédure suivante :

Sub SupprLignes()
Dim L As Long, L1 As Long
Dim Plage As Range, R As Range
Dim C As Integer
   'Désactive le calcul automatique de la feuille et l'affichage
   C = Application.Calculation
   Application.Calculation = xlCalculationManual
   Application.ScreenUpdating = False
   'Borne le traitement
   Set Plage = ActiveSheet.UsedRange
   L1 = Plage.Cells(1, 1).Row
   'Pour chaque ligne utilisée
   For L = Plage.Rows.Count + L1 - 1 To L1 Step -1
      Set R = Rows(L)
      If R.Cells.Count - Application.CountBlank(R) = 0 Then
         R.Delete
      End If
   Next L
   'Réactive le mode de calcul de la feuille et l'affichage
   Application.Calculation = C
   Application.ScreenUpdating = True
End Sub


Cordialement.

Didier_mDF

 

[Garamante]

Merci beaucoup !!!!!