supprimer les doublons dans les lignes

[jad73]

bonjour le forum

peut-on supprimer les doublons ligne par ligne.par colonnes pas de probleme mais par ligne comment faire.j'ai joint un bout de fichier avec les deux premieres lignes en V2 et 3 sans doublons.
merci

 

[jad73]

Re : supprimer les doublons dans les lignes

bonjour carharodon-carcharias,le forum
j'ai du mal m'exprimer,moi ce que je cherche a faire c'est enlever les doublons de la ligne 2 puis ceux de la ligne 3 et ainsi de suite jusqu'a la ligne 1248 actuellement sans modifier les lignes(a part enlever les doublons bien sur)
ex:ligne 2:1 1 2 3 4 4 resultat 1 2 3 4,hors je n'ai trouvé aucun fichier qui fasse cela.
merci

 

[david84]

Re : supprimer les doublons dans les lignes

Bonsoir, salut CC🙂,
cette demande a déjà été traitée plus d'une fois.
Une possibilité parmi d'autres :

=SI(COLONNES($A:A)<=SOMME(1/NB.SI($A2:$T2;$A2:$T2));INDEX($A2:$T2;EQUIV(MIN(SI(NB.SI($U2:U2;$A2:$T2)=0;COLONNE($A2:$T2)));COLONNE($A2:$T2);0));"")

Formule à placer en V2, à valider en matriciel et à tirer vers le bas et la droite.
A+

 

[mth]

Re : supprimer les doublons dans les lignes

🙂 Bonsoir à tous, carcha, david 🙂

Un essai avec ce code, qui fonctionne mais qui a l'inconvénient de trier les lignes (pas réussi à faire autrement ...)

Sub Macro1()
Application.ScreenUpdating = False
Dim lig As Long, col As Long
With Sheets("Feuil1")
lig = .Cells(Rows.Count, 1).End(xlUp).Row
For i = 1 To lig
col = .Cells(i, Columns.Count).End(xlToLeft).Column
.Sort.SortFields.Clear
.Sort.SortFields.Add Key:=Range(Cells(i, 1), Cells(i, col)), _
SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
With .Sort
.SetRange Range(Cells(i, 1), Cells(i, col))
.Header = xlGuess
.MatchCase = False
.Orientation = xlLeftToRight
.SortMethod = xlPinYin
.Apply
End With
'*' d'après un code de Silkyroad
 
Set Origine = .Cells(i, 1)
Do
Set Suivant = Origine.Offset(0, 1)
If Suivant = Origine Then Origine.Delete xlToLeft
Set Origine = Suivant
Loop Until Origine = ""
Next i
End With
Application.ScreenUpdating = True
End Sub

Bonne soirée/nuit,

mth

 

[david84]

Re : supprimer les doublons dans les lignes

Re, bonjour mth🙂,
une proposition par VBA :

Sub trier()
Dim Plage As Range, a, c, Mondico As Object, i&
Set Plage = [A2].CurrentRegion
Set Mondico = CreateObject("Scripting.Dictionary")
    For i = 1 To Plage.Rows.Count
        a = Range(Cells(i + 1, 1), Cells(i + 1, Plage.Columns.Count)).Value
            For Each c In a
                Mondico(c) = c
            Next c
        Cells(i + 1, Plage.Columns.Count + 2).Resize(1, Mondico.Count) = Mondico.keys
        Mondico.RemoveAll
    Next i
End Sub

A+

 

[laetitia90]

Re : supprimer les doublons dans les lignes

bonjour tous 🙂🙂🙂🙂
ou encore sur 20colonnes

Sub es()
Dim t, x As Variant, m As Object, i As Long
For i = 2 To Cells(Rows.Count, 1).End(xlUp).Row
Set m = CreateObject("Scripting.Dictionary")
x = Range(Cells(i, 1), Cells(i, 20))
For Each t In x: m(t) = t: Next t
Range(Cells(i, 1), Cells(i, 20)) = ""
Cells(i, 1).Resize(1, m.Count) = m.keys
Set m = Nothing
Next i
End Sub