Supprimer des lignes dont cellules vides

[jean de chez claude]

Bonsoir le forum
Je souhaiterais incérer dans une macro une formule qui permette de supprimer les lignes dont les cellules au droit des colonnes D à V sont vides (voir fichier joint).
Encore un très grand merci pour le partage de vos connaissances.😕🙂

 

[Compte Supprimé 979]

Re : Supprimer des lignes dont cellules vides

Bonsoir JDCC

Voici le code à utiliser 😉

Sub SupLigCelVide()
  Dim DLig As Long, Lig As Long
  With Sheets("Sheet1")
    ' Récupérer le numéro de la dernièe ligne
    DLig = .Range("A" & Rows.Count).End(xlUp).Row
    ' Pour chaque ligne, de la fin ves le début
    For Lig = DLig To 6 Step -1
      ' Si la somme des colonnes = 0
      If Application.WorksheetFunction.Sum(.Range("D" & Lig & ":V" & Lig)) = 0 Then
        ' Alors on supprime la ligne
        Range("A" & Lig).EntireRow.Delete
      End If
    Next Lig
  End With
End Sub

A+

 

[mth]

Re : Supprimer des lignes dont cellules vides

Bonsoir,

Un essai avec ce code:

Sub Macro1()
Dim derlig As Long
Application.ScreenUpdating = False
With Sheets("Sheet1")
    derlig = .Cells(Rows.Count, 1).End(xlUp).Row
    .Range("W6:W" & derlig).FormulaR1C1 = "=IF(COUNTA(RC[-19]:RC[-1])=0,NA(),0)"
    On Error Resume Next
    .Columns("W:W").SpecialCells(xlCellTypeFormulas, 16).EntireRow.Delete
    On Error GoTo 0
    .Columns("W:W").ClearContents
End With
Application.ScreenUpdating = True
End Sub

Bonne soirée,

mth

Edit: Hello Bruno 🙂 🙂