XL 2016 Supprimer dernier caractère de cellule.

[Etoto]

Bonjour,

Est ce que quelqu'un pourrais créer une fonction grâce au VBA qui supprime automatiquement le dernier caractère d'une cellule ?

Merci d'avance

 

[soan]

Bonjour Etoto,

en A1 : "élèves" ; en B1 : =SI(A1="";"";GAUCHE(A1;NBCAR(A1)-1)) ➯ "élève"

pour la fonction VBA, je te fais ça dans un moment.

soan

 

[sylvanu]

Bonjour Etoto, Soan,
Sans plus d'info, un essai.
Dans cette PJ, si on entre une chaine dans la colonne A alors le dernier caractère est supprimé.

Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, Range("A1:A100")) Is Nothing Then
        Application.EnableEvents = False
        Target = Left(Target.Value, Len(Target.Value) - 1)
        Application.EnableEvents = True
    End If
End Sub

 

[Dudu2]

Bonjour @Etoto, @soan, @sylvanu,
S'il s'agit bien d'une écriture de sens horizontal dextroverse, dans la formule, ne faudrait-il pas remplacer DROITE par GAUCHE ?

 

[soan]

@Etoto (salut sylvanu et Dudu2)

voici le fichier.

Option Explicit

Function SDC(chn$) As String
  Dim n As Byte: n = Len(chn)
  If n > 0 Then SDC = Left$(chn, n - 1)
End Function

SDC = Sans le Dernier Caractère

soan

 

[Etoto]

Effectivement je crois que c'est plus simple d'utiliser une DROITE ou GAUCHE avec un SI aussi. J'y avais pas pensé merci.

 

[Etoto]

@Etoto (salut sylvanu)

voici le fichier.

Option Explicit

Function SDC(chn$) As String
  Dim n As Byte: n = Len(chn)
  If n > 0 Then SDC = Left$(chn, n - 1)
End Function

SDC = Sans le Dernier Caractère

soan

Merci tu es rapide.

Merci à tous

 

[Dudu2]

Je vais faire le mêle-tout qui intervient même dans les sujets où il ne contribue pas sauf pour mettre du sel sur les égratignures. Mais quand même...

Effectivement je coirs que c'est plus simple d'utiliser une DROITE ou GAUCHE avec un SI aussi. J'y avais pas pensé merci.

@Etoto, on ne sait pas ce que tu veux faire précisément.
- Est-ce que c'est pour valoriser UNE AUTRE cellule à partir d'une cellule source à tronquer
(Auquel cas c'est @soan qui remporte la coupe avec 2 buts)
- Est-ce que c'est pour valoriser LA MÊME cellule à tronquer de la saisie qui y a été faite
(Auquel cas c'est @sylvanu qui a le dernier mot Jean-Pierre)
La rédaction de ta question laisse plutôt penser à la 2ème option.
Et la solution confirme que c'est la 1ère

 

[Etoto]

Je vais te dire pourquoi, sur le forum dans la section VBA, il y'a la possibilité d'utiliser la fonction PREMLETTRE mais elle laisse un "." à la fin et je voulais m'en débarrasser, c'est chose faite avec la fonction SDC de @soan. Et comme tu l'as surement remarqué, moi et les macros, je suis pourris, les seuls choses que je sais faire en macro c'est créer des fonctions qui calculent la TVA ou la fonction CARRE.

 

[Dudu2]

Ok, cette fonction de @Staple1600 est subtile avec l'utilisation d'un script pour les expressions régulières.
Tu veux des '.' comme séparateur des lettres sauf la dernière donc.

 

[Etoto]

Ok, cette fonction de @Staple1600 est subtile avec l'utilisation d'un script pour les expressions régulières.
Tu veux des '.' comme séparateur des lettres sauf la dernière donc.

Exactement

 

[sylvanu]

Re,
Expliqué comme ça c'est plus simple.
Pourquoi ne pas modifier la macro de Staple pour supprimer le dernier caractère :

Function PREMLETTRE(S$, Optional casse As VbStrConv) As String
Dim mc As Object, m As Object
With CreateObject("vbscript.regexp")
    .Global = True
    .Pattern = "\b\w"
    If .test(S) = True Then
        Set mc = .Execute(S)
        For Each m In mc
            PREMLETTRE = StrConv(PREMLETTRE & m, casse) & "."
            Next m
        End If
        PREMLETTRE = Left(PREMLETTRE, Len(PREMLETTRE) - 1)
End With
End Function

 

[Dudu2]

Dans ce cas tu pourrais supprimer ce dernier '.' directement dans la fonction de @Staple1600 !
Edit: Voila @sylvanu l'a fait ! Peut-être tester Len(PREMLETTRE) > 0
Je l'ai dit, je suis là uniquement pour critiquer

 

[Dudu2]

Ok, je bosse un peu quand même, entre 2 siestes et 3 critiques
C'est moins élégant qu'un "RegExp" mais je ne sais pas comment coder les lettres accentuées en expression régulière ("ÀÁÂÃÄÅÇÈÉÊËÌÍÎÏÑÒÓÔÕÖÙÚÛÜÝŸàáâãäåçèéêëìíîïñòóôõöùúûüýÿ")

Donc à défaut j'ai fait cette fonction qui corrige les remarques de @Magic_Doctor dans PREMLETTRE.

'---------------------------------------
'Fonction qui rend l'acronyme d'un texte
'---------------------------------------
Function Acronyme(Cellule As Range) As String
    Dim C As String, S As String
    Dim i As Integer
    Dim Bool As Boolean
    
    S = CStr(Cellule.Value)
    
    For i = 1 To Len(S)
        C = Mid(S, i, 1)
        'Ce test identifie toutes les lettres, accentuées ou pas !
        If StrComp(Ucase(C), LCase(C), 0) <> 0 Then
            If Not Bool Then Acronyme = Acronyme & Ucase(C) & "."
            Bool = True
        Else
            Bool = False
        End If
    Next i
End Function

 

[Magic_Doctor]

Bonjour Dudu2,

Ta fonction marche très bien. Pourquoi ne pas la glisser dans la banque de fonctions ?
Moi, en tout cas, je l'ai gardée. Sait-on jamais...

Bonne fin de journée.