SUMPRODUCT : formule à améliorer...

[marido]

Bonjour,

Je cherche à additionner toutes les colonnes intitulées "Prix" d'un tableau (soit
F / I et L dans l'exemple joint) si et seulement si il y a un X en collone B

Je pensais utiliser la commande SUMPRODUCT (que j'ai découvert sur le forum) mais ... il me manque visiblement de la pratique

Quelqu'un peut-il me conseiller ?

Vous remerciant

MD

 

[Modeste]

Re : SUMPRODUCT : formule à améliorer...

Bonsoir Marido,

Une solution avec SOMME.SI:

=SOMME.SI(B5:B18;"x";F5:F18)+SOMME.SI(B5:B18;"x";I5:I18)+SOMME.SI(B5:B18;"x";L5:L18)

Dans tous les cas, il vaudrait mieux mettre des '0' dans les colonnes prix, plutôt que des '-'

Modeste

 

[Raja]

Re : SUMPRODUCT : formule à améliorer...

Bonsoir Salut à tous,

Enlève les tirets dans la plage et remplace par zéros ou efface-les et utilise la formule corrigée suivante :

=SOMMEPROD(($B$5:$B$18="X")*(D4:L4="Prix")*(D5:L18))

 

[ROGER2327]

Re : SUMPRODUCT : formule à améliorer...

Bonsoir à tous

Une variante matricielle (donc à valider par Ctrl + Maj + Entrée) qui accepte les tirets :

[COLOR="DarkSlateGray"]=SOMME((B5:B18="X")*SUBSTITUE(F5:F18;"-";0);(B5:B18="X")*SUBSTITUE(I5:I18;"-";0);(B5:B18="X")*SUBSTITUE(L5:L18;"-";0))[/COLOR]

ROGER2327

 

[BOISGONTIER]

Re : SUMPRODUCT : formule à améliorer...

Bonsoir,

=SOMME(SOMME.SI(B5:B18;"x";INDIRECT({"f5:f18";"i5:i18";"l5:l18"})))

ou

=SOMME(SOMME.SI(B5:B18;"x";DECALER(F5:F18;;{0.3.6})))

JB

 

[Monique]

Re : SUMPRODUCT : formule à améliorer...

Bonjour,

Dans la formule du fichier de Marido :
L4 à la place de L18
; à la place de *

=SOMMEPROD((B5:B18="X")*(D4:L4="Prix");D5:L18)

 

[marido]

Re : SUMPRODUCT : formule à améliorer...

Merci à tous, j'ai le choix !!! je vais essayer de comprendre vos différentes solutions
Monique, tu as corrigé ma formule et j'ai compris mon erreur

MD

 

[Modeste]

Re : SUMPRODUCT : formule à améliorer...

re-bonsoir,

Merci à tous, j'ai le choix !!!

Tu as raison, Marido: on dirait un conte de Noël, avec les Rois Mages et leurs présents. Je vais faire comme toi: les garder, les regarder ... et essayer de les réutiliser quand l'occasion se présentera.

Joyeux Noël en avance! 😛

Modeste