SOMME.SI ou équivalent avec énumération des critères

[Aloha]

Bonjour,

Admettons que j'ai une colonne comportant des critères et une autre avec les valeurs correspondantes.

Avec SOMME.SI je peux additionner toutes les valeurs répondant à un critère déterminé, et un seul.

Comment faire si je veux additionner les valeurs correspondant à plusieurs critères.

Ce que je trouverais bien pratique, c'est une formule du genre

=SOMME.SI(A2:A20;3,4,5;B2:B20) pour additionner toutes les valeurs correspondant aux critères 3,4,5, c'.-à-d, avec l'énumération des critères. Malheureusement SOMME.SI ne tolère qu'un seul critère à la fois.

Comment faire?

Je joins un exemple.

Merci d'avance pour toute aide

Aloha

 

[JHA]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour Aloha, le forum,
Une solution avec sommeprod
=SOMMEPROD((($A$3:$A$19=3)+($A$3:$A$19=4)+($A$3:$A$19=5))*($B$3:$B$19))
ou somme.si
=SOMME.SI($A$3:$A$19;3;$B$3:$B$19)+SOMME.SI($A$3:$A$19;4;$B$3:$B$19)+SOMME.SI($A$3:$A$19;5;$B$3:$B$19)

JHA

 

[Aloha]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour JHA,

Merci pour ton message.

Les solutions que tu me proposes, je les connais; l'un de leurs désavantages: si l'on a un certain nombre de critères, cela fait des formules fastidieuses.

Et je me rappelle avoir vu une formule avec énumération, mais je ne me rappelle ni la fonction employée, ni le contexte.

Je pense que ce serait alors une formule matricielle (mais j'emploie ce mot avec prudence, parce que je ne sais pas à 100% quand une formule est matricielle).

Bonne journée

Aloha

 

[JHA]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour Aloha, le forum,

Ci joint un autre exemple somme.si() avec plage nommée et matricielle.
il te suffit de changer les données de la plage.
Pour mon compte, je préfère sommeprod().
{=SOMME.SI($A$3:$A$19;essai;$B$3:$B$19)}

JHA

Ps: Une combination des deux te donne le résultat dans une cellule.

=SOMMEPROD(SOMME.SI($A$3:$A$19;essai;$B$3:$B$19))
essai étant la plage nommée pour ta recherche.

JHA

 

[Aloha]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour "JHA",

Ta solution me plaît. Mais on ne peut pas se passer d'une plage contenant les critères? Car, si les critères restent toujours les mêmes, et qu'il ne faut pas d'intervention de l'utilisateur, elle est superflue, sauf si la formule ne saurait s'en passer!

Bonne journée

Aloha

 

[BOISGONTIER]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour,

=SOMMEPROD(B3:B19*(A3:A19={3.4.5}))


=SOMMEPROD(B3:B19*(A3:A19>=3)*(A3:A19<=5))

JB
Formation Excel VBA JB

 

[JHA]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour Aloha, Jacques Boisgontier, le forum,

Je pensais faire des recherches sur des critères non figés (ni sur le nombre de critères, ni sur l'intitulé.
Comme tu ne veux pas de changement de critère, suit la première formule de Mr Boisgontier qui réalise cela très bien.
Merçi à lui.

JHA

 

[Aloha]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour "Boisgantier",

c'est exactement cela que je m'imaginais.

Si cette formule fonctionne c'est super.

Merci à tous les intervenants.

Aloha

 

[Holystorm]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour à tous,

A propos du sommeprod, je n'ai pas l'impression que la formule fonctionne avec plusieurs plages de sélection sur une même colonne.
Et dans ce cas, quelle formule pourrait faire l'affaire..?

Holy

 

[jeanpierre]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour Holystorm et Bienvenue sur XLD, Aloha, JHA, JB (et ses solutions fabuleuses),

Peut-être en nous mettant un fichier exemple de ta problématique et la solution attendue...???

Ton seul texte ne peut satisfaire à une réponse.

Bon après-midi.

Jean-Pierre

 

[Aloha]

Re : SOMME.SI ou équivalent avec énumération des critères

Bonjour,

Je constate que le séparateur entre les parenthèses dans une formule SOMMEPROD peut être le classique *, ou le ;, et même le +, que je viens de découvrir ici.

Quelle est la différence?

Bonne journée

Aloha