SOMME.SI.ENS sur colonnes de critères fixes mais avec possibilité de renseigner ou non

[nyxynyx]

Bonjour,

Je cherche une solution pour renvoyer en colonne N et O le résultat en fonction des critères 1, 2 et 3.
En mettant une " * " dans les critères où je veux tout prendre, le calcul ne reprend pas les cellules vides.
Existe-t-il une formule ou une syntaxe qui permettrait de tenir compte de toutes les cellules y compris les vides?
L'objectif étant de ne pas avoir à refaire la formule en fonction du nombre de critères que l'on souhaite afficher.

Merci de votre aide.

Bon weekend.

Linda

 

[sylvanu]

Bonjour nyxynyx,
Une méthode primaire mais efficace : Couvrir toutes les combinaisons :

En N8 :

=SI(ET(K8<>"*";L8<>"*");SOMME.SI.ENS(C:C;E:E;J8;F:F;K8;G:G;L8);
SI(ET(K8="*";L8<>"*");SOMME.SI.ENS(C:C;E:E;J8;G:G;L8);
SI(ET(K8<>"*";L8="*");SOMME.SI.ENS(C:C;E:E;J8;F:F;K8);
SI(ET(K8="*";L8="*");SOMME.SI.ENS(C:C;E:E;J8);""))))

 

[nyxynyx]

Bonjour Sylvanu,
Oui, en effet cela fonctionne, mais sur mon fichier réel, j'ai minimum 5 zones de critères différentes et chacune pouvant à la fois être renseignées ou non .
Mes cours de math sont un peu loin, cela voudrait dire qu'il faudrait couvrir 25 combinaisons non?

 

[sylvanu]

Re,
Exact, donc peu applicable. C'est un paramètre important, vous auriez du le préciser dès le départ.
Peut être une fonction perso. Je vais regarder.

 

[sylvanu]

Peut être une piste inspiré en fouillant un peu sur le web :
1- Le premier critère est obligatoire.
2- Pour les autres critères faire : Si Critère vide on reprend le premier critère, sinon on prend le critère donné.
Ca a l'air de marcher. A vérifier car difficile dans ce fichier incomplet.
( Quand pas de critère laisser vide )

En R8 :

=SOMME.SI.ENS(C:C;E:E;L8;
SI(M8="";E:E;F:F);SI(M8="";L8;M8);
SI(N8="";E:E;G:G);SI(N8="";L8;N8);
SI(O8="";E:E;H:H);SI(O8="";L8;O8);
SI(P8="";E:E;I:I);SI(P8="";L8;P8))

 

[nyxynyx]

Sylvanu,
HO... super, je ne savais pas qu'on pouvait utiliser cette formule comme ça.
Cela me convient parfaitement. J'adore!

Merci beaucoup.

Bonne fin de weekend.

Linda.