Somme sans compter les doublons et en fonction d'un critere

[jvlabas]

Bonjour à tous,

je bute sur un problème depuis quelque temps : j'ai un tableau excel qui comporte plusieurs colonnes.
Je souhaiterai faire la somme des valeurs d'une colonne, sans compter plusieurs fois les mêmes occurrences.
Avec un petit exemple, ce sera sans doute plus clair :

A B C
Projet1 POL 1000
Projet2 POL 250
Projet1 POL 1000
Projet3 PAM 500
Projet2 POL 250
...

Je souhaiterai faire la somme de la colonne C pour les POL (respectivement les PAM), sans compter plusieurs fois les mêmes occurrences "Projet x".
Donc en résultat, cela donnerait :
Somme de la colonne C pour les POL = 1250
Somme de la colonne C pour les PAM = 500


Merci d'avance aux âmes charitables qui essaieront de m'aider

j

 

[R@chid]

Re : Somme sans compter les doublons et en fonction d'un critere

Bonjour et Bienvenu sur XLD,

Avec un petit exemple, ce sera sans doute plus clair

Surement, mais si tu joins un fichier execl,
Voir PJ, si ca te convient
Amicalement

 

[jvlabas]

Re : Somme sans compter les doublons et en fonction d'un critere

Tout d'abord merci de cette réponse rapide.
La solution proposée (qui correspond au besoin!) demande de créer une colonne supplémentaire, ce qui est un peu compliqué dans le fichier que je maintiens : je rapatrie mes données à partir d'un autre fichier Excel par macro.
Donc au temps pour moi, j'aurai du préciser qu'il ne fallait pas que j'ajoute de colonne supplémentaire.
Je pense pouvoir régler mon problème par VBA, mais je souhaitais une "solution élégante", directement sous Excel.
Penses-tu avoir une solution qui ne demanderait pas d'ajouter de colonne ?
Merci d'avance

 

[jvlabas]

Re : Somme sans compter les doublons et en fonction d'un critere

En fait, j'ai peut-être trouvé la solution sur le site (c'était dans les liens discussions similaires).
Du coup je vais essayer et je reviens vers le forum pour dire si ça fonctionne :
https://www.excel-downloads.com/thr...ere-et-sans-doublon-sur-un-2e-critere.135495/

 

[R@chid]

Re : Somme sans compter les doublons et en fonction d'un critere

Re,
Voir si ça te convient???
sinon je reviendrai ce soir chercher si on peut faire plus simple...
Bonne Journée

 

[david84]

Re : Somme sans compter les doublons et en fonction d'un critere

Bonsoir tout le monde,
cf. fichier.
A+
Edit : pour la 2ème formule, peut-être que

=SOMME(SI(FREQUENCE(SI(B$1:B$5=E2;EQUIV(A$1:A$5;A$1:A$5;0));LIGNE(A$1:A$5))>0;C$1:C$5))

suffit (c'est à toi de voir).

 

[homepyrof53]

Re : Somme sans compter les doublons et en fonction d'un critere

Bonsoir,

Voici une méthode par macro

Bonne soirée

 

[jvlabas]

Re : Somme sans compter les doublons et en fonction d'un critere

Bonjour,

Vraiment un grand merci. J'ai finalement utilisé une formule du type :

=SOMME(SI((FREQUENCE(SI((D1:D6=F2);EQUIV(A1:A6;A1:A6;0));LIGNE(A1:A6))>0)*1;C1:C6))

Je me suis un peu galéré à transposer dans mon fichier et surtout j'ai du rajouter un ENT car les données n'étaient par défaut des chiffres !

Par contre, est-ce que vous savez comment rajouter un critère supplémentaire sur une 4ème colonne.
J'ai essayé de rajouter des ET et des SOMMEPROD mais sans succès..En gros critère DM sur la colonne B (voir fichier joint).
Merci d'avance à ceux qui pourront m'éclairer et encore une fois merci à ceux qui m'ont déjà aidé !

 

[david84]

Re : Somme sans compter les doublons et en fonction d'un critere

Re
à tester (validation matricielle par Ctrl, Maj et entrée) :

=SOMME(SI((FREQUENCE(SI((D1:D6=F2)*(B1:B6=G2);EQUIV(A1:A6;A1:A6;0));LIGNE(A1:A6))>0)*1;C1:C6))

A+

 

[jvlabas]

Re : Somme sans compter les doublons et en fonction d'un critere

Super merci.
Et une idée pour chercher une chaine de caractère plutot que "DM" ?

 

[david84]

Re : Somme sans compter les doublons et en fonction d'un critere

Re
remplace la cellule en question indiquée dans la formule par la chaîne de caractère ou rentre la chaîne de caractère voulue à la place de "DM".
A+

 

[jvlabas]

Re : Somme sans compter les doublons et en fonction d'un critere

Je me suis trompé : je voulais dire qu'au lieu de chercher "Ma chaine", chercher ce qui commence par "Ma c" par exmple, pour aussi trouver "Ma chaine2"

 

[david84]

Re : Somme sans compter les doublons et en fonction d'un critere

Re
désolé mais je commence à avoir du mal à te suivre...plutôt que de rajouter les conditions une par une, fais un exemple explicite sur un fichier exemple avec l'ensemble des conditions à traiter et note manuellement le résultat attendu.
Ce sera plus simple et l'on gagnera du temps.
A+

 

[R@chid]

Re : Somme sans compter les doublons et en fonction d'un critere

Bonsoir @ tous,
Si j'ai bien compris,

=SOMME(SI(FREQUENCE(SI((D1:D6=F2)*(GAUCHE(B1:B6;2)=G2);EQUIV(A1:A6;A1:A6;0));LIGNE(INDIRECT("1:"&LIGNES(A1:A6))))>0;C1:C6))

Voir PJ....

 

[jvlabas]

Re : Somme sans compter les doublons et en fonction d'un critere

Après quelques soucis d'adaptation, ça fonctionne nickel ! La dernière formule était la bonne !
Merci à tous les deux pour votre aide rapide sur le sujet !!!!
C'est vraiment sympa que vous consacriez du temps aux problèmes des autres !
Encore merci !