Somme prod

[BRUNO62]

Bonjour à tous,

J'ai besoin d'aide.
Je cherche à comptabiliser la somme des références identiques qui se trouvent dans la zone A1:H24
Merci, d'avance
Bonne journée
A+

 

[titiborregan5]

Re : Somme prod

Bonjour bruno, le forum,
Je ne sais pas si ça répond vraiment à ta demande, mais avec un somme.si ça marche...
pour la référence 1 en k2 tu mets:

=SOMME.SI(A$2:A$24;$J2;B$2:B$24)+SOMME.SI(C$2:C$24;$J2;D$2:D$24)+SOMME.SI(E$2:E$24;$J2;F$2:F$24)+SOMME.SI(G$2:G$24;$J2;H$2:H$24)

et tu tires jusqu'en k5...
En espérant que ça te convienne!

Bon courage

 

[excfl]

Re : Somme prod

Bonjour le forum,

=SOMMEPROD(($A$2:$A$24=J2)*($B$2:$B$24))+SOMMEPROD(($C$2:$C$24=J2)*($D$2:$D$24))+SOMMEPROD(($E$2:$E$24=J2)*($F$2:$F$24))+SOMMEPROD(($G$2:$G$24=J2)*($H$2:$H$24))

excfl

 

[BRUNO62]

Re : Somme prod

Bonjour titiborregan5 et excfl,
Merci, à vous.
Cela me convient.
Est qu'il existe une autre solution dans le cas ou la feuille regroupe une multitude de colonnes
Encore merci.
Bonne journée
A+

 

[titiborregan5]

Re : Somme prod

Peut-être faire une macro qui mettrait tout en forme de 2 colonnes (libellé / quantité) et ensuite un somme.si global ou un TCD???😕

 

[R@chid]

Re : Somme prod

Bonjour @ tous,
Plus courte, en K2 :

=SOMMEPROD((A$2:G$24=J2)*(B$2:H$24))

@ tirer vers le bas


@ + +

 

[BRUNO62]

Re : Somme prod

Bonjour Rachid,
Merci, à toi

Bonne journée à tous
A+

 

[Modeste geedee]

Re : Somme prod

Bonsour® R@chid

proposition séduisante mais ...
🙁 dans le cas présent :
si quantité = ref ????


😎

=SOMMEPROD((A$2:G$24=J2)*(A$1:G$1="Réf")*(B$2:H$24))

 

[R@chid]

Re : Somme prod

Bonjour @ tous,
Salut GD,
J'ai fait en sorte que les références réelles sont différentes des valeurs, sinon en K2,

=SOMME(SI((MOD(COLONNE(A$2:G$24);2)=1)*(A$2:G$24=J2);B$2:H$24))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

@ + +

 

[Modeste geedee]

Re : Somme prod

Bonsour® R@chid...
😉
sans validation matricielle :

=SOMMEPROD((A$2:G$24=J2)*(A$1:G$1="Réf")*(B$2:H$24))

 

[R@chid]

Re : Somme prod

Re,
😉
J'ai pensé à faire avec SOMMEPROD() et MOD() mais j'ai pas pensé à utiliser le critère "Rèf" il faut que je corrige la vue, mais sûrement le problème n'est pas dans mes yeux 🙂 .


@ + +

 

[Modeste geedee]

Re : Somme prod

Bonsour® le fil ...
fonctionne aussi si les références sont alphanumériques :

=SOMMEPROD((A$2:G$24=J2)*(A$1:G$1="Réf")*ESTNUM(B$2:H$24);B$2:H$24)