Somme Prod sur plusieurs feuilles

[tyruso]

Bonjour, je n'arrive pas à faire un sommeprod avec 3 conditions sur plusieurs feuilles ou à partir d'une liste.

Merci de votre aide

PS: Onglet synthese sur le fichier joint.

 

[anthoYS]

Re : Somme Prod sur plusieurs feuilles

Bonjour,

CB c'est our carte bancaire.
Qu'est-ce qui se passe en C6 (synthèse)?
Pas evident de te suivre,

@ te relire.

 

[tyruso]

Re : Somme Prod sur plusieurs feuilles

En C6 laisse tomber ce sont des essais de formules.
En faite j'aimerais faire la somme des montants dans les onglets CB102 à CB 106 si les 3 conditions sont réunies: Date, Produits, Utilisateur

Merci

 

[anthoYS]

Re : Somme Prod sur plusieurs feuilles

Re,

Peut-être ainsi (agrégation de SOMMEPROD() et de SI() et de ET() eventuellement) :

une essai :

=SOMMEPROD(('CB102'!$A$3:$A$44=A4)*('CB102'!$H$3:$H$44=B4)*('CB102'!$B$3:$B$44=$C$3)*('CB102'!$E$3:$E$44))+SOMMEPROD(('CB103'!$A$3:$A$44=A4)*('CB103'!$H$3:$H$44=B4)*('CB103'!$B$3:$B$44=$C$3)*('CB103'!$E$3:$E$44))...

 

[tyruso]

Re : Somme Prod sur plusieurs feuilles

Le probleme c'est que pour l'instant il y a que 6 onglets mais par la suite il y en aura beaucoup plus donc t'as formule sera trop longues à ecrire

Merci

 

[anthoYS]

Re : Somme Prod sur plusieurs feuilles

Possible, je ne vois pas comment faire autrement...
Le mieux, c'est que chaque fois que tu rajoute un onglet (CBx), tu rajoute :

...+SOMMEPROD(('CBx'!$A$3:$A$44=A4)*('CBx'!$H$3:$H$44=B4)*('CBx'!$B$3:$B$44=$C$3)*('CBx'!$E$3:$E$44))

Autrement je ne vois pas. Il doit y avoir sans doute plus simple.
Désolé, là je coince. 😕

En 'RECAPCB' ça s'arrête à CB115. Donc, s'il n'y a que ça, c'est bon. Si le chiffre s'accroit et est indéterminée, c'est autre chose...

 

[tyruso]

Re : Somme Prod sur plusieurs feuilles

Ok Merci
Sinon il y a une formule qui permet de faire appel à une liste comme:
&CB&!$A$3:$A$44=A4
Mais celle ci j'arrive pas à la faire fonctionner

 

[anthoYS]

Re : Somme Prod sur plusieurs feuilles

Re,

Sinon il y a une formule qui permet de faire appel à une liste comme:
&CB&!$A$3:$A$44=A4

Désolé mais je ne vois pas. 😕

Esperons que tu trouve plus simple en effet, car si le nombre d'onglet à rajouter est indéterminée, il serait favorable de trouver une astuce qui actualiserais tes résultats à partir de la racine de l'ajout (sois CB).

 

[tyruso]

Re : Somme Prod sur plusieurs feuilles

Oui le nombre va s'accroitre, pour l'instant le tableau n'est pas finaliser

 

[tyruso]

Re : Somme Prod sur plusieurs feuilles

Merci qd meme pour ton aide, esperont que quelqu'un va trouver la solution car ca fait un moment que je planche sur la question

 

[BOISGONTIER]

Re : Somme Prod sur plusieurs feuilles

Bonjour,

Voir PJ

=SOMMEPROD((N(DECALER(INDIRECT("'"&"CB"&{102.103.104.105.106}&"'!e2");LIGNE($1:$43);0))
*((N(DECALER(INDIRECT("'"&"CB"&{102.103.104.105.106}&"'!a2");LIGNE($1:$43);0))=$A4))
*(T(DECALER(INDIRECT("'"&"CB"&{102.103.104.105.106}&"'!h2");LIGNE($1:$43);0))=$B4)
*(T(DECALER(INDIRECT("'"&"CB"&{102.103.104.105.106}&"'!b2");LIGNE($1:$43);0))=C$3))

ou

=SOMMEPROD((N(DECALER(INDIRECT("'"&"CB"&COLONNE($CX:$DB)&"'!e2");LIGNE($1:$43);0)))*
((N(DECALER(INDIRECT("'"&"CB"&COLONNE($CX:$DB)&"'!a2");LIGNE($1:$43);0))=$A4))*
(T(DECALER(INDIRECT("'"&"CB"&COLONNE($CX:$DB)&"'!h2");LIGNE($1:$43);0))=$B4)*
(T(DECALER(INDIRECT("'"&"CB"&COLONNE($CX:$DB)&"'!b2");LIGNE($1:$43);0))=C$3))

Formules Matricielles 3D

JB

 

[tyruso]

Re : Somme Prod sur plusieurs feuilles

Je vais essayer avec ceci. Merci encore