Somme pourcentage + moyenne en VBA ?

[yves03]

Bonjour,

J'ai une colonne qui contient des pourcentages, et je voudrait en faire la somme et ensuite la moyenne et mettre le resultat dans un Textbox.
Sachant que mon nombre de ligne n'est pas toujours identique.
J'arrive bien a le faire par formule, mais pas en VBA
Si quelqu'un peut m'aider, c'est avec plaisir.
Merci d'avance

 

[Guest]

Re : Somme pourcentage + moyenne en VBA ?

Hello Yves,

Sans plus de précision sur ta demande,voici un exemple dont j'espère tu pourras tirer quelque chose:

Sub TestSommeMoyenne()
    Dim derLigne As Long 'Variable qui contiendra le dernier numéro de ligne
    Dim Plage As Range 'Variable référence à la plage à calculer
    Dim Somme As Variant, Moyenne As Variant 'Variables de resultats
 
    'Dans cet exemple les données à calculer sont dans plage "A2:A"Derligne
    With Sheets("Feuil1")
        'Calcul de la dernière ligne
        derLigne = .Range("A" & .Rows.Count).End(xlUp).Row
        'Si derLigne n'est pas 1 (ligne d'entête de colonne)
        If derLigne > 1 Then
            Set Plage = .Range("A2:A" & derLigne)
            Somme = Application.WorksheetFunction.Sum(Plage)
            Moyenne = Application.WorksheetFunction.Average(Plage)
        End If
    End With
    'Les resultats de formule de feuille de calcul appliquées dans VBA
    'Peuvent retourner une erreur. C'est pourquoi les variables contenant ces
    'Résultats doivent être déclarées [COLOR=red]As Variant[/COLOR]
    If Not IsError(Somme) And Not IsError(Moyenne) Then
        MsgBox Somme & vbTab & Moyenne
    End If
End Sub

A bientôt

 

[yves03]

Re : Somme pourcentage + moyenne en VBA ?

Merci encore Hasco.
C'est tout à fait ce que je voulais, j'ai simplement modifier pour afficher dans un Textbox au lieu d'un Msgbox et je n'ai garder que la variable Moyenne.
Merci beaucoup et bonne journée.