Somme en valeur absolue sur colonne contenant à la fois des nombres et du texte

[Mutafukaz]

Bonjour,

Je ne trouve pas de solution à mon besoin.

En fait je voudrais faire la somme en valeur absolue d'une colonne contenant à la fois des valeurs numériques et des valeurs textuelles.

Pour exemple, colonne A
-1
Exception
6
8
-10
Exception

La somme en valeur absolue de la colonne A devrait me donner 25.

Naturellement je taperais la formule suivante : SOMME.SI(A:A;ESTNUM(A:A)) mais cela ne fonctionne pas.

Que faire ?

Merci.

Julien.

 

[djidji59430]

Re : Somme en valeur absolue sur colonne contenant à la fois des nombres et du texte

Bonjour,


"Que faire ?"

La meme , mais en matricielle :

{=Somme(si(ESTNUM(A:A);A:A))}

(Shift + Crtl + Entrée) pour valider a la place de Entrée quand tu as fini de taper la formule.

Sauf que ta formule est fausse

Il faut :

{=Somme(si(ESTNUM(A:A);abs(A:A)))}

 

[Mutafukaz]

Re : Somme en valeur absolue sur colonne contenant à la fois des nombres et du texte

Merci beaucoup ça marche super.

Oui j'avais oublier la partie ABS.

Je me demande est-ce qu'il serait possible de faire quelque chose d'équivalent en utilisant la fonction sommeprod ? Il me semble qu'on ne peut pas utiliser de fonction logique avec la fonction sommeprod.

Encore merci pour la réponse.

Julien.

 

[djidji59430]

Re : Somme en valeur absolue sur colonne contenant à la fois des nombres et du texte

re

Yes, we can !

=SOMMEPROD(ESTNUM(A:A)*SIERREUR(ABS(A:A);0))

 

[job75]

Re : Somme en valeur absolue sur colonne contenant à la fois des nombres et du texte

Bonjour mutafukaz, djidji59430,

Travailler avec SOMMEPROD sur des plages illimitées prend beaucoup de temps.

Et sur les versions antérieures ce n'est pas possible.

Perso j'utiliserais plutôt :

=SOMME.SI(A:A;">0";A:A)-SOMME.SI(A:A;"<0";A:A)

Edit : chez moi (Excel 2013) la formule du post #4 nécessite la validation matricielle.

Ce qui enlève tout intérêt à SOMMEPROD, autant utiliser SOMME.

Salut cher R@chid 🙂

A+

 

[R@chid]

Re : Somme en valeur absolue sur colonne contenant à la fois des nombres et du texte

Bonjour @ tous,
@ djidji59430 :
on peut simplifier la tienne encore :

=SOMME(SIERREUR(ABS(A:A);))

@ valider par Ctrl+Shift+Enter


@ + +

 

[Mutafukaz]

Re : Somme en valeur absolue sur colonne contenant à la fois des nombres et du texte

Merci à tous pour votre aide.

Je trouve la réponse de job75 très élégante !