Somme de valeurs en fonction de la date

Tibo

XLDnaute Barbatruc

• 2 Août 2006

• #2

Re : Somme de valeurs en fonction de la date

Salut Jx,

Essaye avec la fonction SOMMEPROD :

Tes données en colonne A et B

en D1 (par exemple) : janvier 2006
en E1 : SOMMEPROD((MOIS(A1:A7)=MOIS(D1))*B1:B7)

@+

 

Vote positif 0 Vote négatif

Jx7

XLDnaute Nouveau

• 2 Août 2006

• #3

Re : Somme de valeurs en fonction de la date

Trop fort!!! ^^

et une réponse super rapide en + 😛

J'ai mis un moment à comprendre mais j'ai compris 🙂

Par contre avec cette formule ca prend que le mois donc quand je vais arriver à 2007 il va m'additioner les valeurs de janvier 2006 avec celles de janvier 2007 :s

est ce qu'on peut ajouter la sélection de l'année dans ta formule magique? J'essaie mais en vain...

Merci en tout cas c'est tip top 😉

++

 

Vote positif 0 Vote négatif

Tibo

XLDnaute Barbatruc

• 2 Août 2006

• #4

Re : Somme de valeurs en fonction de la date

re,

Pour faire le distingo en tenant compte de l'année :

en E1 : =SOMMEPROD((ANNEE(A1:A7)=ANNEE(D1))*(MOIS(A1:A7)=MOIS(D1))*B1:B7)

Voilou

Bonne soirée

@+

 

Vote positif 0 Vote négatif

Jx7

XLDnaute Nouveau

• 2 Août 2006

• #5

Re : Somme de valeurs en fonction de la date

ARGH! J'avais presque trouvé!

En tout cas merci pour ton aide ;-)

tip top!!!!

 

Vote positif 0 Vote négatif

Foufoudora

XLDnaute Occasionnel

• 3 Août 2006

• #6

Re : Somme de valeurs en fonction de la date

Salut j'ai le même problème mais plusieurs lignes de saisies par jour.
j'aimerai avir la SOMMEPROD de chaque jour.

Ex:
01/01/2006 100
01/01/2006 250
03/01/2006 200
01/06/2006 20
01/06/2006 30
01/06/2006 40
etc

Merci d'avance

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 3 Août 2006

• #7

Re : Somme de valeurs en fonction de la date

Bonjour,

Dates sans doublons par Grande.Valeur()
et SommeProd ou Somme.Si

 

Pièces jointes

• SommeFoufoudora.zip

  4.6 KB · Affichages: 55

Vote positif 0 Vote négatif

Foufoudora

XLDnaute Occasionnel

• 3 Août 2006

• #8

Re : Somme de valeurs en fonction de la date

Meci beaucoup tu es un amour

peux-tu voir mon message de Intégration SOMMEPROD MACRO sur le forum

Merci d'avance

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 3 Août 2006

• #9

Re : Somme de valeurs en fonction de la date

Re,

J'ai vu ce message, oui.
Mais je n'y connais rien en macro

 

Vote positif 0 Vote négatif

Foufoudora

XLDnaute Occasionnel

• 3 Août 2006

• #10

Re : Somme de valeurs en fonction de la date

comme même un grand merci

Foufoudora

 

Vote positif 0 Vote négatif

Jx7

XLDnaute Nouveau

• 3 Août 2006

• #11

Re : Somme de valeurs en fonction de la date

Tibo à dit:

re,

Pour faire le distingo en tenant compte de l'année :

en E1 : =SOMMEPROD((ANNEE(A1:A7)=ANNEE(D1))*(MOIS(A1:A7)=MOIS(D1))*B1:B7)

Voilou

Bonne soirée

@+

Cliquez pour agrandir...

Je reviens à l'assaut avec un nouveau problème lié à cette formule:

colonne A: les dates
colonne B: les chiffres
colonne D: les mois (01/2006, 02/2006, 03/2006, etc...)
colonne E: la formule

Quand je tape les chiffres à la main dans la colonne B, ça marche impec. mais quand ces chiffres sont eux mêmes issus d'une formule, ma formule de la colonne E déconne 🙁 et m'affiche #VALEUR!

some idea?

edit: je viens de m'apercevoir que ça n'arrive que lorsqu'au moins une case de la colonne B est vide (c'est toujours le résultat d'une formule)

 

Dernière édition: 3 Août 2006

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 3 Août 2006

• #12

Re : Somme de valeurs en fonction de la date

Bonjour,

Fais un essai en remplaçant le dernier * par un point-virgule :
=SOMMEPROD((ANNEE(A$1:A$20)=ANNEE(D1))*(MOIS(A$1:A$20)=MOIS(D1));B$1:B$20)

 

Vote positif 0 Vote négatif

Jx7

XLDnaute Nouveau

• 3 Août 2006

• #13

Re : Somme de valeurs en fonction de la date

Monique à dit:

Bonjour,

Fais un essai en remplaçant le dernier * par un point-virgule :
=SOMMEPROD((ANNEE(A$1:A$20)=ANNEE(D1))*(MOIS(A$1:A$20)=MOIS(D1));B$1:B$20)

Cliquez pour agrandir...

PARFAIT! merci ^^

par contre j'ai un peu de mal à comprendre le déroulement du calcul et ça m'enerve...

++

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 3 Août 2006

• #14

Re : Somme de valeurs en fonction de la date

Re,

SommeProd fait la somme des produits, ligne par ligne

Tu prends les valeurs de ton 1er message, en A1:A7 et B1:B7
=SOMMEPROD((ANNEE(A$1:A$7)=ANNEE(D1))*(MOIS(A$1:A$7)=MOIS(D1));B$1:B$7)

Dans la barre de formule, tu sélectionnes la partie en bleu et tu appuies sur F9, ça donne :
=SOMMEPROD(({VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI})*(MOIS(A$1:A$7)=MOIS(D1));B$1:B$7)

Idem avec la partie en bleu, ça donne :
=SOMMEPROD(({VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI})*({VRAI;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX});B$1:B$7)

Idem avec la fin, ça donne :
=SOMMEPROD(({VRAI;VRAI;VRAI;VRAI;VRAI;VRAI;VRAI})*({VRAI;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX});{420;122;780;300;150;466;561})

Idem avec le nouveau début, ça donne :
=SOMMEPROD({1;1;0;0;0;0;0};{420;122;780;300;150;466;561})

VRAI équivaut à 1 et FAUX à 0
VRAI*VRAI = 1
VRAI*FAUX = 0
FAUX*FAUX = 0

=SOMMEPROD({1;1;0;0;0;0;0};{420;122;780;300;150;466;561})
équivaut à :
=SOMME(1*420;1*122;0*780;0*300;0*150;0*466;0*561)

Si on ne veut compter que le nombre de mois répondant au critère :
=SOMMEPROD((MOIS($A$1:$A$7)=MOIS(D1))*1)
=SOMMEPROD(({VRAI;VRAI;FAUX;FAUX;FAUX;FAUX;FAUX})*1)
=SOMME(({1;1;0;0;0;0;0})*1)

 

Vote positif 0 Vote négatif

nat54

XLDnaute Barbatruc

• 3 Août 2006

• #15

Re : Somme de valeurs en fonction de la date

WOW merci pour cette explication 🙂, j'ai ENFIN compris comment le SOMMEPROD fonctionne !

 

Vote positif 0 Vote négatif