XL 2013 Somme de plusieurs valeurs entre 2 dates avec plusieurs feuilles

débutantplus · 18 Mars 2022

Bonjour,
Cette discussion sera peut être une redite mais mes connaissances sont pauvres donc tout est nouveau pour les néophytes.
Je souhaiterais faire une somme de plusieurs valeurs entre 2 dates sur des valeurs contenu sur plusieurs feuilles
Je souhaiterais avoir une formule pour calculer : stock ordonnancement +stock SAP -stock commandes.
Ma formule est : =SOMME.SI.ENS('stock ordonnancement'!$B$3:$B$367;'stock ordonnancement'!$A$3:$A$367;">" & 'stock final a date'!A4;'stock final a date'!$A$4:$A$368;"<" & 'stock final a date'!A5)+SOMME.SI.ENS('stock sap '!$B$4:$B$368;'stock sap '!$A$4:$A$368;">" & 'stock final a date'!A4;'stock final a date'!$A$4:$A$368;"<" & 'stock final a date'!A5)-SOMME.SI.ENS('stock commandes'!$B$4:$B$368;'stock commandes'!$A$4:$A$368;">" & 'stock final a date'!A4;'stock final a date'!$A$4:$A$368;"<" & 'stock final a date'!A5)
Mais elle affiche 0 partout...
La feuille est "stock à date" et la formule est sur OPA98S
Merci du coup de main.
Bon weekend à tous

Hasco · 21 Mars 2022

Bonjour,

Ne cherchez pas midi à quatorze heures Plus c'est simple, mieux c'est.

Pour prendre en compte la valeur du calcul précédent (votre stock final du 1/1)
Pour le calcul du stock final au 2/2 est calculé sur la ligne précédente, à mon avis c'est là qu'il faut le récupérer pour l'ajouter au calcul de la ligne en cours (celle du 2/2)
Pour homogénéiser les formules et qu'en B3 de 'Stock final' il n'y a pas de valeur numérique à reprendre (d'ailleurs où est la valeur du mois précédent s'il y en a une ?), utilisez la fonction N(Valeur) qui va retourner la valeur numérique de la cellule ou 0 si Valeur est autre chose que numérique.
La formule complète de B4(à tirer vers le bas et la droite) de 'Stock final' devient ...

Hasco · 18 Mars 2022

Bonjour,

Vous connaissez des dates entre le 1/02/2022 et le 2/02/2022 ?

Ne serait-ce pas :

=SOMME.SI.ENS('stock ordonnancement'!$B$3:$B$367;'stock ordonnancement'!$A$3:$A$367;"="&$A4)+SOMME.SI.ENS('stock sap '!$B$4:$B$368;'stock sap '!$A$4:$A$368;"="&$A4)-SOMME.SI.ENS('stock commandes'!$B$4:$B$368;'stock commandes'!$A$4:$A$368;"="&$A4)

ou si vous n'avez qu'un critère de date :

=SOMME.SI('stock ordonnancement'!$A$3:$A$367;"="&$A4;'stock ordonnancement'!$B$3:$B$367)+SOMME.SI('stock sap '!$A$4:$A$368;"="&$A4;'stock sap '!$B$4:$B$368)-SOMME.SI('stock commandes'!$A$4:$A$368;"="&$A4;'stock commandes'!$B$4:$B$368)

Attention dans Somme.Si simple, la plage qui doit répondre au critère vient en premier, le critère lui même en second et la colonne a sommer en dernier.

Si vos colonnes sont dans le même ordre dans les feuilles concernées, alors enlevez les $ dollars devant la colonne à sommer et laisser les sur la colonne de critère, avant de tirer la formule vers la droite pour qu'elle s'adapte :

=SOMME.SI('stock ordonnancement'!$A$3:$A$367;"="&$A4;'stock ordonnancement'!B$3:B$367)+SOMME.SI('stock sap '!$A$4:$A$368;"="&$A4;'stock sap '!B$4:B$368)-SOMME.SI('stock commandes'!$A$4:$A$368;"="&$A4;'stock commandes'!B$4:B$368)

En regardant de plus près votre fichier.
En admettant :
1 - qu'au lieu de mettre des=Si.Erreur(....;"") vous mettiez des =Si.Erreur(....;0) avec un format personnalisé et adapté genre "Standard;Standard;;" pour ne pas afficher les 0
2 - que vous ayiez les mêmes noms de colonne au même endroit dans vos feuilles
3 - que les dates sur chaque feuille soit les mêmes
vous pourriez facilement avoir pour formule :

='stock ordonnancement'!B3+'stock sap '!B4-'stock commandes'!B4

que vous n'auriez qu'à tirer vers le bas et à droite.

Les Si.Erreurs sont bien utiles, seulement lorsqu'on a finalisé les calculs. Ils peuvent masquer des erreurs inattendues qui obligent à des pirouettes qu'on pourrait éviter en laissant les erreurs et traitant leur cause. (ce n'est que mon avis)

Cordialement

débutantplus · 21 Mars 2022

Bonjour Hasco,
Merci tout d'abord pour votre réponse très détaillée.
Au départ j'aurais souhaité avoir dans l'idée de votre formule (='stock ordonnancement'!B3+'stock sap '!B4-'stock commandes'!B4) qui permet de calculer le stock sur une date précise mais il faudrait ajouter pour que ce soit juste la valeur du stock du jour précédent. C'est pourquoi au départ je souhaitais trouver une formule me permettant de calculer la somme des valeurs entre deux dates.
Si j'utilise votre formule

=SOMME.SI.ENS('stock ordonnancement'!$B$3:$B$367;'stock ordonnancement'!$A$3:$A$367;"="&$A4)+SOMME.SI.ENS('stock sap '!$B$4:$B$368;'stock sap '!$A$4:$A$368;"="&$A4)-SOMME.SI.ENS('stock commandes'!$B$4:$B$368;'stock commandes'!$A$4:$A$368;"="&$A4)

et que j'ajoute la valeur du stock du jour antérieur le calcul est il juste ?

=SOMME.SI.ENS('stock ordonnancement'!$B$3:$B$367;'stock ordonnancement'!$A$3:$A$367;"="&$A4)+SOMME.SI.ENS('stock sap '!$B$4:$B$368;'stock sap '!$A$4:$A$368;"="&$A4)-SOMME.SI.ENS('stock commandes'!$B$4:$B$368;'stock commandes'!$A$4:$A$368;"="&$A4) +valeur du jour antérieur

Hasco · 21 Mars 2022

Bonjour,

Ne cherchez pas midi à quatorze heures Plus c'est simple, mieux c'est.

Pour prendre en compte la valeur du calcul précédent (votre stock final du 1/1)
Pour le calcul du stock final au 2/2 est calculé sur la ligne précédente, à mon avis c'est là qu'il faut le récupérer pour l'ajouter au calcul de la ligne en cours (celle du 2/2)
Pour homogénéiser les formules et qu'en B3 de 'Stock final' il n'y a pas de valeur numérique à reprendre (d'ailleurs où est la valeur du mois précédent s'il y en a une ?), utilisez la fonction N(Valeur) qui va retourner la valeur numérique de la cellule ou 0 si Valeur est autre chose que numérique.
La formule complète de B4(à tirer vers le bas et la droite) de 'Stock final' devient :

=N(B3)+'stock ordonnancement'!B3+'stock sap '!B4-'stock commandes'!B4

Avis personnel : ce serait bien de descendre votre tableau de 'stock ordonnancement' d'une ligne pour que les donnée commencent en ligne 4. C'est juste une question d'homogénéité des formules. Dans 6 mois ou 1 ans vous ne saurez peut-être plus pourquoi B3 pour une feuille et B4 pour les autres. Dans la formule, on comprendrait tout de suite que le 3 est la ligne précédente.

débutantplus à dit:
le calcul est il juste ?

C'est à vous de vérifier la justesse des calculs. Moi je me contente de vous donnez des méthodes en fonction de ce que vous nous dites. N'oubliez jamais qu'il s'agit de VOTRE travail, pas celui de quelqu'un d'autre.

Cordialement

XL 2013 Somme de plusieurs valeurs entre 2 dates avec plusieurs feuilles

débutantplus

XLDnaute Junior

Pièces jointes

Hasco

Hasco

XLDnaute Barbatruc

débutantplus

XLDnaute Junior

Hasco

XLDnaute Barbatruc

Discussions similaires