Somme après application d'un filtre

[Gil_Se]

Bonjour à tous.
J'ai cherché et je n'ai pas trouvé:
Comment calculer le nombre de cellules des colonnes contenant un "C" après application d'un filtre ?
Le fichier joint sera beaucoup plus explicite.
Merci.
Gil

 

[Tibo]

Re : Somme après application d'un filtre

Bonjour,

Regarde ce fil où le problème posé était similaire au tien :

https://www.excel-downloads.com/threads/sous-total-selon-critere-sur-liste-filtree.128967/

@+

 

[Gil_Se]

Re : Somme après application d'un filtre

Bonjour Tibo et merci.
Le fil que tu l'as transmis correspond à des sommes de chiffres et moi je recherche une somme d'un certain caractère.
Gil

 

[david84]

Re : Somme après application d'un filtre

Bonjour à Gil Se, Tibo,
à placer en F9 et à tirer vers la droite :
=SOMMEPROD((F$13:F$31="C")*SOUS.TOTAL(3;DECALER(F13;LIGNE(F13:F31)-LIGNE(F13); )))
A+

 

[Gil_Se]

Re : Somme après application d'un filtre

Bonjour et merci David.
Que dois-je rajouter dans la formule pour que le résultat soit égale à 0 si aucun filtre n'est appliqué ou (Tous)?
Gil

 

[david84]

Re : Somme après application d'un filtre

Re;
à tester :
=SI(SOUS.TOTAL(3;$A$13:$A$31)=15;0;SOMMEPROD((F$13:F$31="C")*SOUS.TOTAL(3;DECALER(F13;LIGNE(F13:F31)-LIGNE(F13); ))))
Affiche 0 si aucun filtre n'est appliqué (tu ne peux enlever tous les filtres).
A+
NB : enlever l'espace après le dernier ";" dans la formule).

Edit :encore mieux
=SI(SOUS.TOTAL(3;$A$13:$A$31)=NBVAL($A$13:$A$31);0;SOMMEPROD((F$13:F$31="C")*SOUS.TOTAL(3;DECALER(F13;LIGNE(F13:F31)-LIGNE(F13); ))))

 

[Gil_Se]

Re : Somme après application d'un filtre

Re.
Ces formules fonctionnent parfaitement et en plus j'arrive presque à les comprendre.
Merci David.
Gil

 

[JCGL]

Re : Somme après application d'un filtre

Bonjour à tous,

Un essai avec la formule donnée sur le fil proposé par Tibo :

=SI(SOUS.TOTAL(3;service)=NBVAL(service);0;SOMMEPROD(((SOUS.TOTAL(3;DECALER(E13;LIGNE($E$13:$E$31)-LIGNE(E13);))*(E13:E31="C")))))

A+ à tous

Édition : Ajout fichier, je trouve des différences par rapport à la formule de David

Edition2 : Je mettais la formule avec F... dans la colonne E... Les résultats sont identiques...