séparation des mots sur excel

[chermiti]

rebonjour à tous,

merci infiniment pour votre aide,
j'ai pas réussi à comprendre la formule pour pouvoir l'utiliser , donc s'il vous plait pouvez vous faire extraire le premier mot avant le premier tiret

 

[Efgé]

Re : séparation des mots sur excel

Bonjour chermiti et bienvenu sur le forum

Une proposition a mettre en B2 et à recopier vers le bas:

=STXT(A2;TROUVE("§";SUBSTITUE(A2;"-";"§";2))+1;NBCAR(A2))

Cordialement

 

[Modeste geedee]

Re : séparation des mots sur excel

Bonsour®
sous réserve qu'il y ai toujours 2 et seulement 2 "-" dans la colonne A ...

=STXT(SUBSTITUE(A2;"-";"|";1);TROUVE("-";SUBSTITUE(A2;"-";"|";1))+1;9^9)

😎
élémentaire !! mon cher Efgé...

 

[chermiti]

Re : séparation des mots sur excel

Bonjour chermiti et bienvenu sur le forum

Une proposition a mettre en B2 et à recopier vers le bas:

=STXT(A2;TROUVE("§";SUBSTITUE(A2;"-";"§";2))+1;NBCAR(A2))

Cordialement

merci pour votre aide mais ça pas marché, pouvez vous s'il vous plait m'inclure cette formule dans le fichier excel


je suis trés reconnaisant pour votre aide

 

[Efgé]

Re : séparation des mots sur excel

Re
Bonjour Modeste Geedee 🙂
Un classeur avec les deux propositions plus une variante avec Droite
Cordialement

 

[chermiti]

Re : séparation des mots sur excel

Bonsour®
sous réserve qu'il y ai toujours 2 et seulement 2 "-" dans la colonne A ...

=STXT(SUBSTITUE(A2;"-";"|";1);TROUVE("-";SUBSTITUE(A2;"-";"|";1))+1;9^9)

Regarde la pièce jointe 312711

😎
élémentaire !! mon cher Efgé...

merci pour votre aide mais ça pas marché, pouvez vous s'il vous plait m'inclure cette formule dans le fichier excel


je suis trés reconnaisant pour votre aide

 

[chermiti]

Re : séparation des mots sur excel

merci beaucoup cher ami, c'est la meilleur forum que j'ai visité

 

[Modeste geedee]

Re : séparation des mots sur excel

Bonsour®
peut-être ??? :

=MID(A2,FIND("§",SUBSTITUTE(A2,"-","§",2))+1,LEN(A2))

ou bien :

=MID(SUBSTITUTE(A2,"-","|",1),FIND("-",SUBSTITUTE(A2,"-","|",1))+1,9^9)

 

[Efgé]

Re : séparation des mots sur excel

Bonsour®
peut-être ??? :

=MID(A2,FIND("§",SUBSTITUTE(A2,"-","§",2))+1,LEN(A2))

J'étais en train d'y penser 😀

Cordialement

 

[Modeste geedee]

Re : séparation des mots sur excel

Bonsour®

J'étais en train d'y penser 😀

😉

Function lireF(target)
lireF = target.FormulaR1C1
End Function

 

[job75]

Re : séparation des mots sur excel

Bonjour chermiti, Efgé, Modeste geedee,

Une solution dans le fichier joint qui fonctionne quel que soit le nombre de tirets.

Formule matricielle en B2 :

=SI(ESTNUM(TROUVE("-";A2));STXT(A2;1+EQUIV(9^9;TROUVE("-";STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)));9^9);""&A2)

A valider par Ctrl+Maj+Entrée et tirer vers le bas.

A+

 

[chermiti]

Re : séparation des mots sur excel

Bonjour chermiti, Efgé, Modeste geedee,

Une solution dans le fichier joint qui fonctionne quel que soit le nombre de tirets.

Formule matricielle en B2 :

=SI(ESTNUM(TROUVE("-";A2));STXT(A2;1+EQUIV(9^9;TROUVE("-";STXT(A2;LIGNE(INDIRECT("1:"&NBCAR(A2)));1)));9^9);""&A2)

A valider par Ctrl+Maj+Entrée et tirer vers le bas.

A+

merci infiniment

 

[chermiti]

Re : séparation des mots sur excel

rebonjour à tous,

merci infiniment pour votre aide,
j'ai pas réussi à comprendre la formule pour pouvoir l'utiliser , donc s'il vous plait pouvez vous faire extraire le premier mot avant le premier tiret

 

[Modeste geedee]

Re : séparation des mots sur excel

Bonsour®

Une solution dans le fichier joint qui fonctionne quel que soit le nombre de tirets.
Formule matricielle

🙁 🙄 pour le fun et en tant que "Chirogourdiste" (i.e : sans matricielle because PR)
😉
rappel : la chaine après le dernier tiret

=STXT(A2;TROUVE("|";SUBSTITUE(A2;"-";"|";NBCAR(A2)-NBCAR(SUBSTITUE(A2;"-";""))))+1;9^9)

chermiti n'a pas précisé le cas ou il n'y a pas de tiret ??? (#VALEUR)

alternative renvoie chaine initiale :

=STXT("-"&A2;TROUVE("|";SUBSTITUE("-"&A2;"-";"|";NBCAR("-"&A2)-NBCAR(SUBSTITUE("-"&A2;"-";""))))+1;9^9)

 

[chermiti]

Re : séparation des mots sur excel

merci infiniment pour votre aide,
j'ai pas réussi à comprendre la formule pour pouvoir l'utiliser , donc s'il vous plait pouvez vous faire extraire le premier mot avant le premier tiret