XL 2010 Sélectionner une cellule d'une plage

[Magic_Doctor]

Bonsoir,

J'ai une plage de cellules : [C25,I25,C30,I30]
Je voudrais sélectionner, par exemple, la 3ème cellule.
J'ai tenté ceci sans succès :
[C25,I25,C30,I30].Item(3).Select

Comment s'y prendre ?

Merci d'avance pour toute réponse.

 

[mapomme]

Bonsoir Magic_Doctor,

avec ceci ?: Range(Split([C25,I25,C30,I30].Address, ",")(2)).Select

Ne fonctionne qu'avec des cellules individuelles au sein de [,,,]. Si vous avez une ou des plages au sein de [,,,], la notion de Nième élément ne signifie plus rien ; une plage pouvant être parcourant de plusieurs manières (par lignes ou par colonnes).

 

[mapomme]

Re,

Mon excel 2010 semble parcourir les plages par ligne par ligne (mais je ne mettrai pas main au feu). Dans ce cas, et avec règle (non confirmée ?) , on pourrait utiliser la petite macro du fichier joint:

Sub test1()
Dim xcell As Range, n&, Nieme&

   Nieme = Int(Application.InputBox("Entrez un rang de cellule SVP", Type:=1))
   For Each xcell In [a1:d2,a7:b16,f4,e7,b4,d9].Cells
      n = n + 1
      If n = Nieme Then
         xcell.Select
         Exit Sub
      End If
   Next xcell
End Sub

 

[Magic_Doctor]

Bonsoir mapomme,

Merci, ça marche très bien !

 

[Magic_Doctor]

Re,

Pas rafraîchi...

Votre macro est aussi intéressante (je la conserve sous le coude) mais pas pour ce que je voulais. Votre précédent post y répondait parfaitement.

Bonne fin de soirée "là-bas". Il doit y avoir encore 5 heures de décalage.

 

[belkacem_64]

voila une autre solution
Supposons que la table contient des cellules : C25:I30

Sub test2()

Dim Rng As Range
Set Rng = Range("C25:I30")
iRow = InputBox("Entrez le numéro de Row SVP", "rows")
iCol = InputBox("Entrez le numéro de Column SVP", "Column")
Range(Rng.Address).Cells(Val(iRow), Val(iCol)).Select


End Sub

 

[Yurperqod]

Bonjour le forum

Ecrit comme cela, on obtient C27 comme 3ième cellule

Sub Macro1()
MsgBox [C25,I25,C30,I30].Address
'ligne pour test
MsgBox [C25,I25,C30,I30].Areas.Count
'3ième cellule= C27
'lignes pour tests
MsgBox [C25,I25,C30,I30].Areas(1).Item(3).Address
MsgBox [C25,I25,C30,I30].Areas(2).Item(3).Address
End Sub

 

[Magic_Doctor]

Bonsoir,

Merci belkacem_64 & Yurperqod pour vos réponses.
Jusqu'à présent, la solution qui satisfait le mieux à ce que je voulais est celle du post #2 de mapomme.

Je poursuis ce fil en posant la question suivante :
toujours avec la même plage de cellule, comment sélectionner toutes les cellules de la plage, sauf celle qui correspond au paramétrage.
Dans la solution de mapomme :
Range(Split([C25,I25,C30,I30].Address, ",")(2)).Select
c'est la 3ème cellule qui est sélectionnée.
Comment faire pour que ce soit maintenant l'inverse, autrement dit que les cellules "C25", "I25" & "I30" soient sélectionnées ?

 

[Yurperqod]

Bonjour le forum

Avec ce que j'ai compris

Sub Macro2()
Dim P As Range
Set P = [C25,I25,C30,I30]
'test
MsgBox Union(P.Item(1, 1), P.Item(1, 7), P.Item(6, 7)).Address
Union(P.Item(1, 1), P.Item(1, 7), P.Item(6, 7)).Select
'test adresse des cellules de la selection
MsgBox Selection.Address
End Sub

 

[job75]

Bonjour à tous,

Comment faire pour que ce soit maintenant l'inverse, autrement dit que les cellules "C25", "I25" & "I30" soient sélectionnées ?

Dim exclu&, a, i&, s As Range
exclu = 3 'modifiable
a = Split([C25,I25,C30,I30].Address, ",")
For i = 0 To UBound(a)
  If i <> exclu - 1 Then Set s = Union(IIf(s Is Nothing, Range(a(i)), s), Range(a(i)))
Next
s.Select

A+

 

[job75]

Re,

Il faut savoir que quand on détermine une plage multiple par Range(texte) le nombre de caractères de texte est limité (à 255 ou 256) [Edit] 255 je viens de vérifier.

Si donc le nombre de caractères n'est pas trop élevé on peut utiliser :

Dim exclu&, a, i&, t$
exclu = 3 'modifiable
a = Split([C25,I25,C30,I30].Address, ",")
For i = 0 To UBound(a)
  If i <> exclu - 1 Then t = t & "," & a(i)
Next
Range(Mid(t, 2)).Select

A+

 

[Magic_Doctor]

Bonjour Yurperqod, job, le forum,

Merci pour vos réponses.
job, ta routine marche très bien pour ce que je voudrais faire,
Ce ne seront que des valeurs numériques. Avec 255 caractères autorisés... il y a de la marge !

Bonne journée.

 

[job75]

Re,

Ce ne seront que des valeurs numériques. Avec 255 caractères autorisés... il y a de la marge !

Je vois que tu n'as pas compris mon dernier post.

Je parlais bien sûr de la chaîne des références de la plage comme "C25,I25,C30,I30" qui peut facilement dépasser 255 s'il y a beaucoup de cellules...

A+

 

[Magic_Doctor]

Re,

Effectivement, tu as raison, j'ai confondu.