selectionner toutes les cellules contenant un mot précis

[jacks39]

Bonjour à tous,

Ya t'il possibilité (via excel classique ou sub vba) de sélectionner dans une plage de cellules données toutes les cellules contenant un texte/valeur précis ???

Merci d'avance pour vos réponses..

Jacks39

 

[PMO2]

Re : selectionner toutes les cellules contenant un mot précis

Bonjour,

Essayez le code suivant à copier dans un module standard

Sub RechercheSelect()
Dim R As Range
Dim C As Range
Dim var
If TypeName(Selection) <> "Range" Then
  MsgBox "Veuillez sélectionner une plage de cellules"
  Exit Sub
End If
var = Application.InputBox(prompt:="Mot à rechercher")
If var = False Then Exit Sub
If IsNumeric(var) Then var = CDbl(var)
For Each C In Selection
  If C = var Then
    If R Is Nothing Then
      Set R = C
    Else
      Set R = Application.Union(R, C)
    End If
  End If
Next C
If Not R Is Nothing Then
  R.Select
Else
  MsgBox "Aucune occurence de " & var & " n'a été trouvée"
End If
End Sub

 

[jacks39]

Re : selectionner toutes les cellules contenant un mot précis

Merci 1000 fois PMO2 !!!

C'est exactement ce que je cherchais....

Ce que j'aimerais être aussi fort... Aurais tu quelques conseilles à me donner pour avoir un bon niveau stp ?

La pratique j'imagine, mais ou trouver de quoi pratiquer ?

MERCI ENCORE