Retourner des numéros de lignes.

[JJ1]

Bonjour,
J'ai un tableau de nombres plagés A1:T2415.
J'ai des couplés colonnes U et V (ex: 1 2 )
Je voudrais, à partir de la colonne W, retourner tous les nméros de lignes où ces couplets sont présents, pour suivre les écarts.
Est ce possible par formule ou par macro (j'avais commencé avec un sommeprod mais je n'ai pas su continuer pour la colonne suivante )
merci de votre aide, je joins un bout de fichier.
Bon samedi

 

[JeanMarie]

Re : Retourner des numéros de lignes.

Bonjour JJ1

Une proposition

Formule à valider par Ctrl+Shift+Entrer, en ayant sélectioné la plage W1:AD1

=TRANSPOSE(PETITE.VALEUR(SI(FREQUENCE(SI(FREQUENCE(SI($A$1:$I$40=U1;LIGNE($1:$40));LIGNE($1:$40))*($A$1:$I$41=V1);LIGNE($1:$41));LIGNE($1:$40));LIGNE($1:$40));LIGNE($1:$8)))

En inversant ton orientation de ton tableau, tu peux supprimer dans la formule la fonction TRANSPOSE.

Nota: La formule n'a pas de gestion d'erreur, si le nombre de combinaisons des deux valeurs est inférieur à 8, la formule retournera en supplément la valeur #NOMBRE!.

@+Jean-Marie

 

[job75]

Re : Retourner des numéros de lignes.

Bonjour JJ1, JeanMarie,

Autre solution :

1) W1 étant sélectionnée, définir le nom p par la formule :

=ESTNUM(CHERCHE(" "&$U1&" * "&$V1&" ";" "&$A$1:$A$5000&"  "&$B$1:$B$5000&"  "&$C$1:$C$5000&"  "&$D$1:$D$5000&"  "&$E$1:$E$5000&"  "&$F$1:$F$5000&"  "&$G$1:$G$5000&"  "&$H$1:$H$5000&"  "&$I$1:$I$5000&" "))*LIGNE($A$1:$A$5000)

En effet il faut séparer les valeurs par des espaces (doublés).

2) Entrer en W1 la formule matricielle (valider pat CTRL+Maj+Entrer) :

=PETITE.VALEUR(SI(p>0;p;"");COLONNE()-22)

Puis tirer à droite et vers le bas. Les entrées prennent un certain temps...

A+

 

[JJ1]

Re : Retourner des numéros de lignes.

Bonjour Jean Marie, Job75, le Forum,
Sorry pour le retard à vous répondre et à vous remercier, les formules fonctionnent super.
Bonne journée