[RESOLU] Plusieurs formule VBA

Sub FormatDatesTaleaux()
    
    'Tableau1
    Call FormatTexteEnDate(Range("tableau1[Date de création]"))
    Call FormatTexteEnDate(Range("tableau1[Date de derniere modification]"))
    
    'Tableau2
    Call FormatTexteEnDate(Range("tableau2[Date de création]"))
    Call FormatTexteEnDate(Range("tableau2[Date de derniere modification]"))

End Sub

Sub FormatTexteEnDate(Colonne As Range)
    Dim i As Long
    Dim TabColonne() As Variant
    
    TabColonne = Colonne.Value
    For i = 1 To UBound(TabColonne, 1)
        If IsDate(TabColonne(i, 1)) Then TabColonne(i, 1) = CDate(TabColonne(i, 1))
    Next i
    Colonne.Value = TabColonne
    Colonne.NumberFormatLocal = "jj/mm/aaaa hh:mm"
End Sub

Sub SupprimeLignesTableau2()
    Dim i As Long
    Dim NbLignesSupprimées As Long
    Dim Aujourdhui As Date
    Const NbJoursSupprime = 7
   
    Aujourdhui = Now
    NbLignesSupprimées = 0
    i = 1
   
    Do While i <= Range("Tableau2").Rows.Count
        If IsDate(Range("Tableau2[Date de derniere modification]").Cells(i)) Then
            If DateDiff("d", Range("Tableau2[Date de derniere modification]").Cells(i), Aujourdhui) > NbJoursSupprime Then
                Range("Tableau2").Rows(i).Delete
                NbLignesSupprimées = NbLignesSupprimées + 1
                i = i - 1
            End If
        End If
        i = i + 1
    Loop
   
    MsgBox NbLignesSupprimées & " ligne(s) supprimée(s)."
End Sub