Résolu critere somme si

[zumba]

Bonjour , j'ai un tableau avec plusieurs colonnes , dans la colonne B j'ai la date , du 01-janv au 31-dec,dans la C des valeurs .
Je souhaite faire un total des valeurs par mois . Je pensais donc utiliser " somme si" avec (la plage , le critère, et somme plage ).
Pour que cela fonctionne il faut seulement reprendre le mot "janv" ou "fev" ... comme valeur pour le paramètre critère.j'ai essayé plusieurs méthodes sans succes pour l'instant : "??/janv" "mmmm" "......
Avez-vous une solution à me proposer .Merci

 

[Compte Supprimé 979]

Re : critere somme si

Bonjour Zumba 😉

Ahhh si tout pouvait être simple ... mais non 😱

Si tu veux faire le total par mois, il va falloir utiliser un produit matriciel 😱

=SOMMEPROD((MOIS(B2:B500)=1)*(C2:C500))

Cette formule pour le mois de Janvier

Il suffit de remplacer ensuite le "=1" par "=2" pour février et ainsi de suite

A+

 

[R@chid]

Re : critere somme si

Bonjour @ tous,
Salut Bruno,
@ Zumba : le fichier exemple est toujours plus claire.
Tu peux mettre cette formule en D1 :

=SOMME(SI(MOIS(PlageDates)=LIGNE();PlageValeurs))

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas jusqu'a D12
elle te renvoie la somme de janvier, fervrier, mars, ...
Amicalement

 

[zumba]

Re : critere somme si

ta solution est intéressante BrunoM45, mais elle ne convient pas en totalité .
En effet la présentation des jours mois n'est pas continue , ex : entre le 31 janv et le 1 fev j' ai des cellules vides , par contre en face de ces cellules donc en C j'ai des valeurs , et ces valeurs se trouvent du coup comptabilisées dans le total de janv => problème


Au départ j'étais dans la recherche d'une solution qui masquait une partie de la chaine de caractère , le 01 du 01-janv , de façon à ne conserver que le "janv"

 

[Compte Supprimé 979]

Re : critere somme si

Re,

Au départ j'étais dans la recherche d'une solution qui masquait une partie de la chaine de caractère , le 01 du 01-janv , de façon à ne conserver que le "janv"​

Cela ne changera rien, à mon avis, car si j'ai bien compris tu veux jouer sur le format des cellules date
Mais dans la cellule le numéro de série de la date est toujours là !

Si tu veux que l'on puisse t'aider d'avantage, merci de joindre un fichier

A+​

 

[hbenalia]

Re : critere somme si

Bonjour à tous,

Pour éviter de comptabiliser les cellules vides, la formule de BrunoM45 deviendra:

=SOMMEPROD((MOIS($B$2:$B$500)=1)*($B$2:$B$500<>"")*($C$2:$C$500))

Cordialement

 

[zumba]

Re : critere somme si

Merci à tous , j'ai testé avec succès la formule proposée par hbenalia .

Mais le problème se corse un peu en effet dans la colonne B (du calendrier) en plus des cellules vides, j' ai aussi du texte et dans ce cas j'ai un retour " erreur valeur" : logique ....
La question: comment procéder pour que de ces cellules ne perturbent plus le résultat ,(cellules qui se limitent pour l'instant à un ou deux mots )

 

[CISCO]

Re : critere somme si

Bonsoir

Le plus simple, zumba, serait que tu mettes un petit fichier en pièce jointe.

@ plus

 

[hbenalia]

Re : critere somme si

Bonjour à tous,

La formule matricielle suivante résoudra le problème des cellules vides ou contenant du texte...

=SOMMEPROD(SI(ESTNUM($B$2:$B$500);(MOIS($B$2:$B$500)=1)*($C$2:$C$500)))

A Valider par : CTRL+MAJ+ENTREE

Cordialement

 

[zumba]

Re : critere somme si

Exemple ci-joint

 

[R@chid]

Re : critere somme si

Bonsoir,
voir PJ.
Amicalement

 

[hbenalia]

Re : critere somme si

Bonjour à tous,

Dans le fichier attaché, l'application de la formule matricielle citée précédemment...

Cordialement

 

[R@chid]

Re : critere somme si

Bonjour @ tous,
@ hbenalia :
je ne sais pas pourquoi la SOMMEPROD(), on peut economiser 4 tapes sur le clavier en mettant SOMME().
Amicalement

 

[hbenalia]

Re : critere somme si

Bonjour à tous, bonjour Rachid

L'utilisation de SOMMEPROD dans ce genre de problème n'est pas obligatoire, c'est par habitude que j'utilise cette fonction... L'intérêt d'une formule ce n'est pas le nombre de caractères qu'elle contient mais de ce qu'elle peut faire, d'ailleurs la formule similaire à ta fonction matricielle

=SOMME(SI(MOIS($B7:$B$25)=COLONNES($E:E);$C$7:$C$25))

en utilisant la fonction SOMMEPROD est la formule matricielle:

=SOMMEPROD((MOIS($B$7:$B$25)=COLONNE(A1))*($C$7:$C$25))

avec deux caractères de plus (2 tapes en plus) qui sont remplacées par la validation de ta formule par CTRL+MAJ+ENTREE, et donc le nombre de tapes dans les formules est le même (en ajoutant la tape de la touche ENTREE à ma formule)...
Et tu remarques que ces deux formules ne répondent pas à la demande de "zumba" (elles donnent toutes deux une erreur), qui consiste à faire les calculs avec des cellules vides ou contenant du texte...

Pour cela j'ai proposé la formule matricielle suivante (A valider par Ctrl+Maj+Entree):

=SOMMEPROD(SI(ESTNUM($B$1:$B$1000);(MOIS($B$1:$B$1000)=COLONNE(A1))*($C$1:$C$1000)))

et ta formule matricielle, avec ces nouvelles conditions, doit être ramenée à la forme suivante (suggestion):

=SOMME(SI(ESTNUM($B$1:$B$1000);SI(MOIS($B1:$B$1000)=COLONNES($E:E);$C$1:$C$1000)))

A valider aussi par Ctrl+Maj+Entree

NB: Un avantage à utiliser la formule avec SOMME même si la "Somme_Plage" (la plage à sommer) contiendrait des textes, tandis que la formule avec SOMMEPROD donnerait une erreur...

Cordialement

 

[R@chid]

Re : critere somme si

Bonjour @ tous,
@ hbenalia : Avec tout mon respect, ce que je veux savoir est :

L'utilisation de SOMMEPROD dans ce genre de problème n'est pas obligatoire, c'est par habitude que j'utilise cette fonction

Amicalement