[Résolu]-Créer une macro qui remplace la fonction SI pour remplir une cellule.

CortX · 5 Février 2016

Bonjour;

Je rempli un tableau comptable et j'ai une colonne catégorie ou je renseigne le typer d'opération.
Pour automatiser, j'ai utiliser la fonction SI afin de repérer du texte et en fonction de ce texte, mettre une catégorie.
Malheureusement, on est limité au niveau du nombre d'arguments possible à enchainer et ça ne me suffit pas.

Est-ce qu'il est possible de faire ce genre de chose avec une macro ou pas ?
Que la macro lise la Cellule B? et remplisse C? en fonction de ce qui s'y trouve, ce qui me permettrait de passer outre le problème du nombre trop grand d'argument.

Je vous donne la formule que j'utilise pour vous donner une idée de ce dont je parle.

Code:

=SI(NB.SI(B3;"*articipation frais*");"Participation frais";SI(NB.SI(B3;"*apayer*");"Frais apayer";SI(NB.SI(B3;"*Adhésion*");"Adhésion";SI(NB.SI(B3;"*Atelier*");"Atelier";SI(NB.SI(B3;"*potage*");"Atelier";SI(NB.SI(B3;"*Assur*");"Assurance";SI(NB.SI(B3;"*Don*");"Don";SI(NB.SI(B3;"*Avance*");"Avance";SI(NB.SI(B3;"*compte*");"Frais bancaire";SI(NB.SI(B3;"*Loyer*");"Loyer"; "NA"))))))))))

Sur le net on trouve des information sur le SI, mais pas sur que faire quand le nombre d'argument SI est dépassé.
Je m'en remete donc à vous si vous pouvez m'aider la dessus.

Merci d'avance.
CortX

Papou-net · 5 Février 2016

Re : Créer une macro qui remplace la fonction SI pour remplir une cellule.

Bonsoir CortX,

Bien sûr que c'est faisable avec une macro, et sans limitation d'arguments.

Mais pour te répondre plus précisément en collant à ton application, un petit fichier exemple serait très utile.

A +

Cordialement.

CortX · 5 Février 2016

Re : Créer une macro qui remplace la fonction SI pour remplir une cellule.

Bonjour;

Voici le fichier, j'ai retiré les informations sensibles mais l'architecture de la feuille est présente.
https://drive.google.com/file/d/0B7d4gyZQid6_U0pYZE9ocmY5eW8/view?usp=sharing

Je souhaite remplir la colonne "C" en fonction de ce qui se trouve dans le colonne "B"

Edit, je viens de me rendre compte que le classeur a été mal enregistré et ne m'a pas gardé mes macros déjà présente de copie et de tri de ABCDE vers GHIJK. J'ai enregistré en XLSX au lieu de XLSM
Je vais devoir les refaire mais en vous en formalisez pas, ça ne concernait pas ma demande.

mapomme · 5 Février 2016

Re : Créer une macro qui remplace la fonction SI pour remplir une cellule.

Bonsoir CortX, Papou-net ,

Un essai sans VBA avec une formule matricielle à valider par la combinaison des touches Ctrl+Maj+Entrée qui n'est pas limitée en imbrication de SI().

Une feuille Data a été ajoutée sur laquelle on liste les textes à rechercher en colonne A et la catégorie correspondante en colonne B.

Un nom dynamique QuelTxt a été créé avec comme définition:

Code:

=DECALER(Data!$A$1;1;0;NBVAL(Data!$A:$A)-1;1)

La formule matricielle en cellule C3 est à recopier dans les autres cellules des colonnes C et I.

Code:

=SIERREUR(INDEX(DECALER(QuelTxt;0;1);PETITE.VALEUR(SI(NB.SI(B3;"*" & QuelTxt & "*")<>0;LIGNE(QuelTxt));1)-1);NA())

nb: si plusieurs catégories peuvent correspondre, c'est la première qui est retournée (en compliquant la formule, on pourrait afficher un texte d'avertissement pour ce cas)

CortX · 5 Février 2016

Re : Créer une macro qui remplace la fonction SI pour remplir une cellule.

Bonjour;

Comment est-ce que je fais pour réintégrer ça dans ma feuille de travail ?
J'ai rajouter le nom dans le gestionnaire de nom, j'ai ajouter la formule en lieu et place dans la colonne C mais ça me sort à chaque fois #N/A
Une idée ?

Edit:
J'ai pigé le: A valider par Ctrl+Shift+Entrée.
Je pensais que c'était comme une macro pour lancer l'update de la feuille mais non c'est la formule à valider comme ça pour qu'elle soit prise en compte en tant que matrice.

[Résolu]-Créer une macro qui remplace la fonction SI pour remplir une cellule.

CortX

XLDnaute Nouveau

Papou-net

XLDnaute Barbatruc

CortX

XLDnaute Nouveau

mapomme

XLDnaute Barbatruc

Pièces jointes

CortX

XLDnaute Nouveau

Discussions similaires