XL 2016 Rendre fonction concatener dynamique

[scoubidou35]

Bonjour à tous,

Je cherche à créer une cellule avec toutes les adresses mails pour faire des envois groupés.
J'ai réussi à obtenir un résultat en suivant les étapes comme indiqué dans le fichier joint.
Mais j'aimerai automatiser le résultat car d'un mois à l'autre il y a des suppressions et des ajouts d'adresses.
de plus pour activer la matrice sur CTRL + Flèche MAJ + Entrer est facile pour moi mais pour la personne qui sera amené à le faire est paralysé d'un bras donc impossible pour elle d'exécuter la tâche.

Je reste donc un moyen d'obtenir le même résultat soit avec une formule soit VBA que j'ai essayé avec la méthode d'enregistrement de macro pour avoir les étapes mais cela ne marche pas ou power query que j'ai également regardé mais je n'ai pas trouvé le moyen.

Merci

 

[mapomme]

Bonsoir @scoubidou35 ,

A partir de Excel 2016, on peut utiliser la formule : =JOINDRE.TEXTE(";";VRAI;liste_mail) ou bien =JOINDRE.TEXTE(";";;liste_mail)

 

[scoubidou35]

Bonsoir @scoubidou35 ,

A partir de Excel 2016, on peut utiliser la formule : =JOINDRE.TEXTE(";";VRAI;liste_mail) ou bien =JOINDRE.TEXTE(";";;liste_mail)

Bonsoir mapomme
je suis désolé mais je n'ai pas cette fonction sur ma version d'excel 2016

 

[scoubidou35]

J'ai trouvé ce code VBA

Function JOINDRE_TEXTE(r As Range, Char As String)
Dim Tbl
If r.Rows.Count = 1 Then Tbl = Application.Index(r.Value, 1, 0) Else Tbl = Application.Transpose(r)
JOINDRE_TEXTE = Join(Tbl, Char)
End Function

Ca marche.

 

[mapomme]

mais je n'ai pas cette fonction sur ma version d'excel 2016

Dans ce cas une fonction VBA agissant sur des plages multiples tout comme JOINDRE.TEXTE :

Function JoindreTexte(xSeparateur As String, xIgnorervide As Boolean, ParamArray xCellules()) As String
Dim xplage, xcell, r$
   If UBound(xCellules) < LBound(xCellules) Then Exit Function
   For Each xplage In xCellules
      For Each xcell In xplage
         If xcell = "" Then
            If Not xIgnorervide Then r = r & xSeparateur & xcell
         Else
            r = r & xSeparateur & xcell
         End If
      Next xcell
   Next xplage
   If r <> "" Then r = Mid(r, Len(xSeparateur) + 1)
   JoindreTexte = r
End Function