remplacer les . par des ,

[Pol]

Bonjour à tous,

Je souhaite remplacer les . par des , dans une colonne active avec une macro.

Quel est le code VBA correpondant (sans passer par recherche/remplacer) ?

Merci bcp.

 

[Pierrot93]

Re : remplacer les . par des ,

Bonjour,

si tes données proviennent d'une importation, sans doute préférable de passer par la conversion, Données => Outils de données => Convertir... L'enregistreur devrait te donner la syntaxe.

bon après midi
@+

 

[Pol]

Re : remplacer les . par des ,

Justement, j'ai un problème avec l'enregistreur,

Lorsque je fais la manip "manuelle" ça marche et quand je fais la manip par macro ça ne marche plus, je ne comprends pas ce qui se passe.

je te donne mon fichier.

 

[Pierrot93]

Re : remplacer les . par des ,

Re,

essaye avec ceci :

Option Explicit
Sub test()
With Columns("A:A")
    .TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, Other:=True, OtherChar:="T", FieldInfo:=Array(Array(1, 1), Array(2, 9), Array(3, 9))
    .TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, Other:=True, OtherChar:="H", FieldInfo:=Array(Array(1, 1), Array(2, 9))
    .TextToColumns Destination:=Range("A1"), DecimalSeparator:=","
End With
End Sub

 

[Pol]

Re : remplacer les . par des ,

Bonjour Pierrot,

j'ai exécuté ta macro, elle présente le même problème, les . ne sont pas remplacés par des ,

Aurais-tu une autre idée ?

 

[Pierrot93]

Re : remplacer les . par des ,

Bonjour,

bah... fonctionne chez moi sous 2003 avec le fichier que tu as fourni...

bon après midi
@+

 

[Modeste geedee]

Re : remplacer les . par des ,

Bonsour®

Justement, j'ai un problème avec l'enregistreur,

Lorsque je fais la manip "manuelle" ça marche et quand je fais la manip par macro ça ne marche plus, je ne comprends pas ce qui se passe.

je te donne mon fichier.

🙄
aprés l'import :

Sub Macro1()
    Columns("A:A").Select
    Selection.Replace What:=".", Replacement:=",", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False
'
    With Range("B2")
    .FormulaR1C1 = "=1*LEFT(RC[-1],FIND("","",RC[-1])+2)"
    .AutoFill Destination:=Range("B2:B294")
    End With
    
    With Range("C2")
    .FormulaR1C1 = "=MID(RC[-2],FIND("","",RC[-2])+3,3)"
   .AutoFill Destination:=Range("C2:C294")
    End With
    
    [A1].Select
    End Sub

 

[laetitia90]

Re : remplacer les . par des ,

bonjour Pol ,Modeste geedee , l'ami Pierrot🙂
une autre macro qui le fait aussi

Sub essai()
Dim x As Variant, r As Long, c As Long
 Application.ScreenUpdating = False
 x = Range("a1", Cells(Rows.Count, "c").End(xlUp))
 For r = 1 To UBound(x, 1)
 For c = 1 To UBound(x, 2)
 x(r, c) = Replace(x(r, c), ".", ",")
 Next c: Next r
 Range("a1", Cells(Rows.Count, "c").End(xlUp)) = x
End Sub

 

[CBernardT]

Re : remplacer les . par des ,

Bonjour à tous,


Une macro qui devrait aller :

Sub Test()
Dim Derlig As Integer, Tablo, i As Integer, k As Byte, Extraction As String

With Sheets("Feuil1")
Derlig = .Range("A100000").End(xlUp).Row
Tablo = .Range(.Cells(2, 1), .Cells(Derlig, 1))
For i = 1 To UBound(Tablo, 1)
Extraction = ""
For k = 1 To Len(Tablo(i, 1))
If IsNumeric(Mid(Tablo(i, 1), k, 1)) Then
Extraction = Extraction & Mid(Tablo(i, 1), k, 1)
ElseIf Mid(Tablo(i, 1), k, 1) = "." Or Mid(Tablo(i, 1), k, 1) = "," Then
Extraction = Extraction & ","
ElseIf Mid(Tablo(i, 1), k, 1) = "T" Or Mid(Tablo(i, 1), k, 1) = "H" Then
Exit For
End If
Next k
On Error Resume Next
If IsNumeric(CDbl(Extraction)) Then
Tablo(i, 1) = CDbl(Extraction)
Else
Tablo(i, 1) = ""
End If
On Error GoTo 0
Next i
.Range("A2").Resize(UBound(Tablo, 1), UBound(Tablo, 2)) = Tablo
End With
End Sub