XL 2019 Remplacement de valeurs tres long avec grosse base de données

G

gbinforme

XLDnaute Impliqué

• 3 Juin 2024

• #2

carlos à dit:

Auriez vous une solution rapide sous vba pour remplacer les . en , et les nombre-texte en nombre.

Cliquez pour agrandir...

Bonjour,
La fonction "Remplacer" d'Excel est faite pour cela et fonctionne très bien pourquoi la réinventer ?

 

Vote positif 0 Vote négatif

C

carlos

XLDnaute Impliqué

Supporter XLD

• 3 Juin 2024

• #3

BonjourGBinforme,
J'ai deja fait cela mais ca rame quand meme
Private Sub CommandButton2_Click()
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
Remplacer
MAJTexteParNb
Application.ScreenUpdating = True
MsgBox "Calcul automatique des formules désactivé"
End Sub
Sub MAJTexteParNb()
Dim Rng As Range
Application.ScreenUpdating = False
Set Rng = ActiveSheet.UsedRange.SpecialCells(xlCellTypeConstants)
' Inscrie la valeur 1 dans une cellule après la plage utilisée
Cells(1, Rng.Columns.Count + 1).Value = 1
Cells(1, Rng.Columns.Count + 1).Copy
' Collage spécial valeur par multiplication
Rng.PasteSpecial xlPasteValues, xlPasteSpecialOperationMultiply

End Sub
Sub Remplacer()
Dim plage As Range
Application.ScreenUpdating = False
Set plage = Range(ActiveSheet.UsedRange.Address)

'pour chaque cellule de ma plage
For Each c In plage
'je remplace le . par une ,
c.Value = Replace(c.Value, ".", ",")
Next c
Application.ScreenUpdating = True
End Sub
,

 

Vote positif 0 Vote négatif

chris

XLDnaute Barbatruc

• 3 Juin 2024

• #4

Bonjour

Ton fichier à la base c'est un Excel ou un CSV ?

C'est sûr qu'une boucle n'est pas la meilleure approche

Les 60 colonnes contiennent des nombres ?

Il y a une ligne de titre ?

 

Vote positif 0 Vote négatif

G

gbinforme

XLDnaute Impliqué

• 3 Juin 2024

• #5

carlos à dit:

J'ai deja fait cela mais ca rame quand meme

Cliquez pour agrandir...

re
Tu ne penses pas que la fonction native d'Excel serait plus adaptée et performante ?

 

Vote positif 0 Vote négatif

chris

XLDnaute Barbatruc

• 3 Juin 2024

• #6

RE
Ma solution est instantanée mais sans réponse...

 

Vote positif 0 Vote négatif

C

carlos

XLDnaute Impliqué

Supporter XLD

• 3 Juin 2024

• #7

Bonjour Chris,
Désolé mais je n'ai pas pu te répondre aussitot.
C'est un fichier Excel.
Les colonnes contiennent des nombres, du texte, des Nombre en format texte.
Oui il y a 2 lignes de titre.
Merci

 

Dernière édition: 3 Juin 2024

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 3 Juin 2024

• #8

Bonjour à tous,

Exécutez ce code :

VB:

Dim i
For i = 0 To 9
    Cells.Replace i, i, xlPart
Next

A+

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 3 Juin 2024

• #9

J'ai testé sur un tableau 25000 x 60 contenant des nombres aléatoires avec le point comme séparateur.

Le code précédent s'exécute chez moi en 5 minutes, ce n'est pas fameux.

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 3 Juin 2024

• #10

Avec cette macro l'exécution se fait en 35 secondes :

VB:

Sub Conversion()
Dim t, i
t = Timer
On Error Resume Next 'si aucune SpecialCell
For i = 0 To 9
    Cells.SpecialCells(xlCellTypeConstants, 2).Replace i, i, xlPart
Next
MsgBox Timer - t
End Sub

 

Vote positif 0 Vote négatif

Deadpool_CC

XLDnaute Accro

• 3 Juin 2024

• #11

Salut à tous ... de passage rapide après une longue absence

Et pourquoi ne pas utiliser la fonction intégré
Remplacement de "." par "," dans 60col x 60 000 lignes = 12 secondes sur mon PC

VB:

    Range("A2:BI6040").Select
    Selection.Replace What:=".", Replacement:=",", LookAt:=xlPart, _
        SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
        ReplaceFormat:=False, FormulaVersion:=xlReplaceFormula2

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 3 Juin 2024

• #12

Bonjour Deadpool_CC,

Il peut y avoir des textes comme "1234" qu'il faut convertir en nombres.

A+

 

Vote positif 0 Vote négatif

C

carlos

XLDnaute Impliqué

Supporter XLD

• 3 Juin 2024

• #13

Bonjour, merci beaucoup pour vos propositions.
Je regarde cela au calme.
Merci encore

 

Vote positif 0 Vote négatif

chris

XLDnaute Barbatruc

• 3 Juin 2024

• #14

RE

PowerQuery charge 25000 lignes sur 60 colonnes de nombres avec un point quasi instantanément (moins de 2 secondes) mais un exemple de quelques lignes représentatives permettrait de vérifier la véritable nature du contenu.
On parle 3 types de données mais on ne sait si c'est mélangé dans une même colonne...

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 4 Juin 2024

• #15

Bonjour le forum,

Téléchargez le fichier déposé sur cjoint.com :

https://www.cjoint.com/c/NFehaWhtEP7

et lancez la macro :

VB:

Sub Conversion()
Dim t, ds$, tablo, ub%, i&, j%, x$
t = Timer
ds = Application.DecimalSeparator
With [A1:BH25000] 'à adapter
    tablo = .Formula 'au cas où il y aurait des formules
    ub = UBound(tablo, 2)
    For i = 1 To UBound(tablo)
        For j = 1 To ub
            x = Replace(tablo(i, j), ".", ds)
            If IsNumeric(x) Then tablo(i, j) = CDbl(x) 'conversion
    Next j, i
    .Value = tablo 'restitution
End With
MsgBox Timer - t
End Sub

Chez moi elle s'exécute en 2,6 secondes.

A+

 

Vote positif 0 Vote négatif

Solution