Regrouper deux macros en une

[libellule85]

Bonjour le forum,

Voilà, actuellement j'utilise 2 macros (ci-dessous) : pour Mettre et Enlever une image.
N'est-il pas possible de regrouper ces 2 actions dans la même macro ?

Sub ImageVisible(ByVal control As IRibbonControl)
ActiveSheet.Shapes("Image 4").Visible = True
End Sub

Sub ImageInvisible(ByVal control As IRibbonControl)
ActiveSheet.Shapes("Image 4").Visible = False
End Sub

D'avance merci pour votre aide

 

[Dull]

Re : Regrouper deux macros en une

Salut libellule85, le Forum

A tester

Sub ImageVisibleInvisible(ByVal control As IRibbonControl)
ActiveSheet.Shapes("Image 4").Visible = IIf(ActiveSheet.Shapes("Image 4").Visible = True, False, True)
End Sub

Bonne Journée

 

[libellule85]

Bonjour Dull,

Merci beaucoup pour ta réponse, celà marche super bien.

Bonne journée

 

[Dranreb]

Re : [Résolu] Regrouper deux macros en une

Bonjour
Oui, ça marche, sans doute, mais ceci est plus élégant et plus ...logique :

Sub ImageVisibleInvisible(ByVal control As IRibbonControl)
With ActiveSheet.Shapes("Image 4"): .Visible = Not .Visible: End With
End Sub

Par ailleurs à quoi sert le paramètre control ? S'il designe le même objet :

Sub ImageVisibleInvisible(ByVal control As IRibbonControl)
control.Visible = Not control.Visible
End Sub

 

[libellule85]

Bonjour Dranreb,

Merci beaucoup pour ta réponse, c'est sympa

Bonne journée

 

[libellule85]

Re : Regrouper deux macros en une

Re bonjour le forum,

Je reprends mon fil, car j'aimerais regrouper également sur une même macro (si celà est possible ) la mise en forme d'une cellule dont vous trouverez les codes (macros réalisées avec l'enregistreur) ci-dessous :

Sub Effacer()
    Range("B10").Select
        Selection.Borders(xlDiagonalDown).LineStyle = xlNone
    Selection.Borders(xlDiagonalUp).LineStyle = xlNone
    With Selection.Borders(xlEdgeLeft)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    Selection.Borders(xlInsideVertical).LineStyle = xlNone
    Selection.Borders(xlInsideHorizontal).LineStyle = xlNone
    With Selection.Interior
        .Pattern = xlNone
        .TintAndShade = 0
        .PatternTintAndShade = 0
    End With
       Range("A5").Select
End Sub

Sub RemettreLundi()
    Range("B10").Select
         With Selection.Borders(xlDiagonalDown)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlMedium
    End With
    With Selection.Borders(xlDiagonalUp)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlMedium
    End With
    With Selection.Borders(xlEdgeLeft)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    With Selection.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
        .Weight = xlThin
    End With
    Selection.Borders(xlInsideVertical).LineStyle = xlNone
    Selection.Borders(xlInsideHorizontal).LineStyle = xlNone
    With Selection.Interior
        .Pattern = xlSolid
        .PatternColorIndex = xlAutomatic
        .ThemeColor = xlThemeColorDark1
        .TintAndShade = -0.14996795556505
        .PatternTintAndShade = 0
    End With
    Range("A5").Select
End Sub

Je vous joins également un fichier pour que vous voyez à quoi correspond ces codes.

D'avance je vous remercie beaucoup pour votre aide

 

[Paritec]

Re : Regrouper deux macros en une

Bonjour libellule85 le forum
voilà je pense ce que tu veux
a+
Papou🙂

Sub test()
    With Range("B10")
        If .Interior.ColorIndex = 15 Then
        .Clear
        Else
            Range("B7").Interior.ColorIndex = 15
            .Borders.LineStyle = 1
            .Borders(5).LineStyle = 1
            .Borders(6).LineStyle = 1
        End If
    End With
End Sub

 

[libellule85]

Re : Regrouper deux macros en une

Bonjour Paritec,

Merci pour ta réponse, mais ce n'est pas ce que je recherche.
Ce que j'aimerais c'est avoir sur la même macro la possibilité d'effacer et de remettre la mise en forme.
Par exemple la mise en forme (cellule barrée et fond gris) est dans la cellule B10 je veux qu'en cliquant sur le même bouton il n'y ai plus de mise en forme (plus de fond gris ni de barres à l'intérieur de la cellule) en B10.

 

[Paritec]

Re : Regrouper deux macros en une

Bonjour Libellule 85 le forum
excuses moi mais avant de dire que c'est pas cela il serait peut-être bon que tu saches te servir de la macro !!!!!
alors je vais te la mettre dans le fichier car manifestement tu ne sais pas
voilà dans le fichier, par contre si tu veux des traits en gras redis le
a+
Papou🙂

 

[Paritec]

Re : Regrouper deux macros en une

Re Libellule85 le forum
ton fichier avec deux versions en trait normal et en trait épais(j'ai pas fait le gras)
a+
papou🙂

 

[libellule85]

Re : Regrouper deux macros en une

re Paritec,

Merci beaucoup, je ne sais pas ce qui c'est passé ! Enfin bref, maintenant celà fonctionne.
Encore merci pour ton aide

 

[libellule85]

Re : Regrouper deux macros en une

re Paritec,

Excuses moi de t'embêter à nouveau, mais à l'effacement j'aimerais simplement garder le cadre : est ce possible ?
C'est promis après je ne t'embête plus !

 

[Compte Supprimé 979]

Re : Regrouper deux macros en une

Bonjour Libellule85

Essaye avec ceci

Sub test()
  With Range("B10")
    If .Interior.ColorIndex = 15 Then
      .Interior.ColorIndex = xlNone
      .Borders(5).LineStyle = xlNone
      .Borders(6).LineStyle = xlNone
    Else
      Range("B10").Interior.ColorIndex = 15
      .Borders.LineStyle = 1
      .Borders(5).LineStyle = 1
      .Borders(6).LineStyle = 1
    End If
  End With
End Sub

A+

 

[libellule85]

Re : Regrouper deux macros en une

Bonjour BrunoM45,

Un grand grand merci à toi, c'est exactement ce que je voulais.

Bon après midi