Reference a une cellule de la feuille précédente

[nicolas]

Bonjour , je débute avec excel est c'est une question qui doit vraiment pas être compliqué. je fais un programme de gestion de stock sur le mois. Chaque feuille de mon classeur represente un jour; je voudrais que le stock initial de la journée deux reprenne le stock final de la journée 1.
Bien sur je peux faire ='1'!b2 mais cela est fastidieux, comment faire référence à la feuille précedente.
Merci d'avance

 

[bbmarcus]

Re:Reference a une cellule de la feuille précédent

Bonjour Nicolas, bonjour à tous,

alors nicolas j'ai bien une prop' à te faire mais elle passe par vba...(j'ai pas trouvé avec excel même...je suis pas super perfectionné encore mais je me soigne 😉

Donc, je pense qu'en passant par un bouton commande dans lequel tu demande l'activation de la page précédente puis la copie d'une cellule vers une auter, ca devrait marcher...

J'ai pas le temps de te faire un exemple, mais ca se résume à ca:
ActiveSheet.Previous.Select
Range('A1').Select
Ensuite tu crée une petite macro pour copier/coller et tu reviens dans ta feuille initiale avec un ActiveSheet.Next

Je pense que de meilleurs utilisateurs pourront t'aider mieux que moi, mais ca t'aidera à te perfectionner.....

Si tu as un EX, met-le à dispo et on y jétera un oeil.

bon courage !

bbmarcus

 

[Temjeh]

Bonjour à tous
Bonjour nicolas & bbmarcus

Avec cette solution de bb (à copier dans la feuil)

Private Sub Worksheet_Activate()
Range('A1') = ActiveSheet.Previous.Range('A1')
End Sub

A++

Temjeh

 

[bbmarcus]

Re:Reference a une cellule de la feuille précédent

Bonjour temjeh, nicolas,

effectivement, soluce encore plus simple.......
J'en apprend encore grace à toi.

@+

bbmarcus

 

[Monique]

Bonjour,

Si tes noms d'onglets sont 1, 2, 3, etc

Nom de la feuille précédente :
=STXT(CELLULE('filename';A1);TROUVE(']';CELLULE('filename';A1))+1;32)-1

Contenu de la cellule B2 de la feuille précédente :
=INDIRECT('''&(STXT(CELLULE('filename';A1);TROUVE(']';CELLULE('filename';A1))+1;32)-1)&''!B2')

Somme de la plage B2:B100 de la feuille précédente :
=SOMME(INDIRECT('''&(STXT(CELLULE('filename';A1);TROUVE(']';CELLULE('filename';A1))+1;32)-1)&''!B2:B100'))

 

[nicolas]

Re:Reference a une cellule de la feuille précédent

merci à tous, mais je le copie ou dans la feuille?

j envoie le fichier, je voudrais que la cellule C52 de la feuille 2 prenne la valeur de la cellule F52 de la feuille 1 et ainsi de suite pour toute les feuilles et pour toute les valeurs.

MErci de votre aide

 

[Monique]

Re:Reference a une cellule de la feuille précédent

Re,

Cette formule, collée dans toutes les cellules C52 de toutes tes feuilles (sauf la 1ère)
=INDIRECT('''&(STXT(CELLULE('filename';A1);TROUVE(']';CELLULE('filename';A1))+1;32)-1)&''!F52')
te donnera la valeur de la cellule F52 de la feuille précédente

 

[nicolas]

Re:Reference a une cellule de la feuille précédent

merci beaucoup monique c'est genial

 

[Choops]

Re : Reference a une cellule de la feuille précédente

Bonjour tout le monde,

Est-il possible d'utiliser pour le nom de la cellule la fonction LIGNE() de manière à ce que la formule se mette à jour quand on insère des lignes ?

Un peu dans le genre de:

=INDIRECT("Sem"&(STXT(CELLULE("filename";N26);TROUVE("]";CELLULE("filename";N26))+4;2)-1)&"!"&(LIGNE()))

Mais ça ne fonctionne pas.

Merci!

 

[Choops]

Re : Reference a une cellule de la feuille précédente

Aucune idée à ce sujet ?

 

[Monique]

Re : Reference a une cellule de la feuille précédente

Bonjour,

Oui, mais en mettant aussi la lettre de la colonne

Si tu insères des lignes, tu en insères dans toutes les feuilles
=INDIRECT("Sem"&(STXT(CELLULE("filename";N26);TROUVE("]";CELLULE("filename";N26))+4;2)-1)&"!F"&LIGNE())

Si tu insères des lignes et des colonnes :
=INDIRECT("Sem"&(STXT(CELLULE("filename";N26);TROUVE("]";CELLULE("filename";N26))+4;2)-1)&"!"&ADRESSE(LIGNE();COLONNE()))

Si besoin, avec LIGNE()-2 ou autre s'il y a un décalage au départ

 

[Choops]

Re : Reference a une cellule de la feuille précédente

Merci Monique 🙂