récupérer valeurs tableau sans #N/A

Bene25 · 31 Mars 2015

Bonsoir,

J'ai un tableau avec une dizaine d'onglet, chaque onglet correspond à type de données qui alimente un premiere onglet qui fait office de reporting (tableaux, graphiques etc....) Dans un de mes onglets j'ai des tableaux avec des valeurs #N/A qui sont issus d'une formule, je souhaiterais récupérer les données de ces tableaux sans les lignes ou cette valeurs apparait. j'ai essayé plusieurs méthodes rien y fait, un tcd ne répond pas à mes attentes. je vous joins un bout de fichier en PJ : un onglet valeurs à récupérer un autre tableau souhaité.

Auriez vous une solution?

d'avance merci

Victor21 · 31 Mars 2015

Re : récupérer valeurs tableau sans #N/A

Bonjour, Bene25.

Supprimez les NA à la source :
- SI(ESTNA(Valeur ou Formule);0;Valeur ou Formule)
- SIERREUR(Valeur ou Formule);0)

Utilisez une colonne supplémentaire, collez-y la formule =nb.si(E1:AE1;NA()), filtrez les 27 sur cette colonne et supprimez les lignes filtrées.

job75 · 1 Avril 2015

Re : récupérer valeurs tableau sans #N/A

Bonjour Bene25, Patrick, le forum,

Code à placer où vous voulez dans VBA :

Code:

Sub SupprimeErreurs()
Dim dest As Range, source As Range
Set dest = Feuil1.Rows(12) 'ligne à adapter
Set source = Feuil2.UsedRange 'à adapter
Application.ScreenUpdating = False
dest.Resize(Rows.Count - dest.Row + 1).Clear 'RAZ
With dest.Resize(source.Rows.Count)
  source.EntireRow.Copy .Cells 'pour copier les formats
  .Value = source.EntireRow.Value 'copie les valeurs
  On Error Resume Next 'si aucune valeur d'erreur
  .SpecialCells(xlCellTypeConstants, xlErrors).EntireRow.Delete
End With
dest.Parent.Columns.AutoFit 'ajustement largeur
End Sub

Bonne journée et A+

job75 · 1 Avril 2015

Re : récupérer valeurs tableau sans #N/A

Re,

Bien entendu si l'on veut traiter directement la feuille des erreurs c'est trivial :

Code:

Sub SupprimeErreurs1()
On Error Resume Next 'si aucune valeur d'erreur
With ActiveSheet.Cells
  .SpecialCells(xlCellTypeConstants, 16).EntireRow.Delete
  .SpecialCells(xlCellTypeFormulas, 16).EntireRow.Delete
End With
End Sub

Edit : et bien sûr on peut le faire sans macro :

- touche F5 => Cellules => Constantes => cocher "Erreurs"

- commande Supprimer => Ligne entière

- répéter ces opérations pour les formules.

A+

Bene25 · 1 Avril 2015

Re : récupérer valeurs tableau sans #N/A

Bonjour à tous

merci pour vos réponses!

@victor21 : j'ai testé votre formule, le problème c'est que je ne peux pas supprimer les #N/A à la source, parce que ces valeurs peuvent ne plus être en #N/A demain...

@job75: dsl je ne connais pas le vba, néanmoins voila ce que j'ai mis et en PJ le résultat que j'ai obtenu sur mon tableau original... pas vraiment le resultat espéré

Sub SupprimeErreurs()
Dim dest As Range, source As Range
Set dest = Feuil3.Rows(81) 'ligne à adapter
Set source = Feuil2.UsedRange(8,M) 'à adapter
Application.ScreenUpdating = False
dest.Resize(Rows.Count - dest.Row + 1).Clear 'RAZ
With dest.Resize(source.Rows.Count)
source.EntireRow.Copy .Cells 'pour copier les formats
.Value = source.EntireRow.Value 'copie les valeurs
On Error Resume Next 'si aucune valeur d'erreur
.SpecialCells(xlCellTypeConstants, xlErrors).EntireRow.Delete
End With
dest.Parent.Columns.AutoFit 'ajustement largeur
End Sub

Et le 2eme post rien compris....

et heu... j'ai aucune idée de ce qui peut coincer....

job75 · 1 Avril 2015

Re : récupérer valeurs tableau sans #N/A

Re,

Bene25 à dit:
@job75: dsl je ne connais pas le vba (...)

Alors pourquoi vous avez écrit Feuil2.UsedRange(8, M) qui ne signifie rien ???

Si vous voulez plus d'aide joignez votre fichier réel.

A+

Bene25 · 1 Avril 2015

Re : récupérer valeurs tableau sans #N/A

bonsoir,
En fait la seule qui change dans mon fichier d origine par rapport à celui posté. C'est que mes données sources se trouve sur la feuille 8 colonne M ligne 152 et que le résultat doit "arrivé " en feuille 4 colonne B ligne 82. Votre macro doit être elle recopier telle quelle dans le Vba?
Merci

job75 · 1 Avril 2015

Re : récupérer valeurs tableau sans #N/A

Re,

Si vous êtes sûr de ce que vous dites :

Code:

Sub SupprimeErreurs()
'Feuil4 et Feuil8 sont les CodeNames des feuilles
Dim dest As Range, source As Range
Set dest = Feuil4.Cells(82, "B") 'à adapter
With Feuil8 'feuille source, à adapter
  Set source = .Cells(152, "M") 'à adapter
  Set source = .Range(source, .Cells.SpecialCells(xlCellTypeLastCell))
End With
Application.ScreenUpdating = False
dest.Resize(Rows.Count - dest.Row + 1).EntireRow.Clear 'RAZ
With dest.Resize(source.Rows.Count, source.Columns.Count)
  source.Copy .Cells 'pour copier les formats
  .Value = source.Value 'copie les valeurs
  On Error Resume Next 'si aucune valeur d'erreur
  .SpecialCells(xlCellTypeConstants, xlErrors).EntireRow.Delete
End With
dest.Parent.Columns.AutoFit 'ajustement largeur
End Sub

Bien sûr je n'ai pas testé faute de fichier

Bonne fin de soirée.

Bene25 · 15 Avril 2015

Re : récupérer valeurs tableau sans #N/A

oups méa culpa, maxi culpa....je m’aperçois en que je ne vous ai pas remercier.... :-(

alors merci beaucoup avec beaucoup de retard

Victor21 · 15 Avril 2015

Re : récupérer valeurs tableau sans #N/A

Re,

Bene25 à dit:
@victor21 : j'ai testé votre formule, le problème c'est que je ne peux pas supprimer les #N/A à la source, parce que ces valeurs peuvent ne plus être en #N/A demain...

Il n'y aura donc pas à les supprimer...

récupérer valeurs tableau sans #N/A

Bene25

XLDnaute Nouveau

Pièces jointes

Victor21

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Bene25

XLDnaute Nouveau

Pièces jointes

job75

XLDnaute Barbatruc

Bene25

XLDnaute Nouveau

job75

XLDnaute Barbatruc

Bene25

XLDnaute Nouveau

Victor21

XLDnaute Barbatruc

Discussions similaires