recherche valeur puis extraire ligne

[pasglop]

bonjours

je pense que cette question à déja du être posé mais je ne trouve pas de réponse dans recherche ou bien je la formule mal.

j'ai un tableau de 1500 lignes
avec des valeurs dans les colonne A-B-C-D-E-F

se que je voudrais bien pouvoir faire c'est :
-rechercher dans la colonne F une valeur se raprochant le plus d'un chiffre déterminé exemple 50

et extraire la ligne dans la quelle se trouve ce chiffre
exemple : il y a 49 dans la cellule "F958"
je voudrai que A1=A958 B1=B958 C1=C958 D1=D958 E1=E958

pour trouver le chiffre le plus rapprochant dans la colonne j'utilise en ce moment
=F1+SI(ABS(PETITE.VALEUR(F1:F1500;NB.SI(F1:F1500;"<=" &F1))-F1)>PETITE.VALEUR(F1:F1500;NB.SI(F1:F1500;"<"&F1)+1)-F1;PETITE.VALEUR(F1:F1500;NB.SI(F1:F1500;"<"&F1)+1)-F1;PETITE.VALEUR(F1:F1500;NB.SI(F1:F1500;"<="&F1))-F1)
se qui marche tres bien,
mais pour extraire la ligne .. je ne trouve pas

merci de me donner un petit coup de main

A++
yves

 

[juju_69]

Re : recherche valeur puis extraire ligne

Hello,

Ta formule ne fonctionne pas chez moi. En supposant qu'elle renvoie bien la valeur se rapprochant, c'est à dire 49, tu peux écrire cela pour connaitre ton N° de ligne :=EQUIV(F1;F2:F1500;1)+1

Où F1 = 49
F2:F1500 = ton tableau
et le +1 car mon tableau commence ligne 2 (donc à adapter)

@ +

Juju

 

[pasglop]

Re : recherche valeur puis extraire ligne

voila un exemple pour mieux comprendre sa vaut mieux qu'un long discour

merci d'avance

yves

 

[juju_69]

Re : recherche valeur puis extraire ligne

C'est carrément plus clair

Voici la formule à mettre en A1 : =INDIRECT("A"&EQUIV($F$3;$F$15:$F$1515;0)+14)
B1 : =INDIRECT("B"&EQUIV($F$3;$F$15:$F$1515;0)+14)
...

 

[pasglop]

Re : recherche valeur puis extraire ligne

merci beaucoup

sa fonctionne, pourrais tu m'expliquer comment sa marche ???
c'est toujours mieux de comprend que de simplement faire un copier collé ...

à quoi sert le +14 à la fin ??

merci
yves

 

[juju_69]

Re : recherche valeur puis extraire ligne

Bien sur avec plaisir, Alors si on décortique :
EQUIV($F$3;$F$15:$F$1515;0)
=> renvoie le N° de ligne du tableau(F15:F1515) ayant la valeur F3

Comme toi tu ne souhaites pas le N° de ligne du tableau mais le N° de ligne de la feuille Excel, j'ai ajouté +14 car le tableau commence à la ligne 15.

Ensuite cela donne donc : =INDIRECT("A"& N° de ligne)
Indirect permet de faire appel au résultat de la formule, c'est à dire =A17 (par exemple).

Voulou

 

[tototiti2008]

Re : recherche valeur puis extraire ligne

Bonjour à tous,

une autre proposition :

en A3 :

=INDEX($A$15:$F$20;EQUIV($F$3;$F$15:$F$20;0);COLONNE())

à recopier vers la droite

et une autre possibilité en F3

=SI(NB.SI(F15:F34;I4+MIN(ABS(F15:F34-$I$4)))=0;I4-MIN(ABS(F15:F34-$I$4));I4+MIN(ABS(F15:F34-$I$4)))

à valider avec Ctrl+Maj+Entrée

 

[capricorne68]

Re : recherche valeur puis extraire ligne

bonsoir le forum

tu peux aussi mettre cette formule en "a3" et le tirer vers la droite :

=INDEX(A15:A20;EQUIV($F$3;$F$15:$F$20;0))

bonne soirée

 

[Tibo]

Re : recherche valeur puis extraire ligne

Bonjour,

Une autre tentative pour trouver le plus près (Supérieur ou Inférieur) avec une formule matricielle en A3 :

=INDEX(A15:A20;EQUIV(MIN(ABS($F$15:$F$20-$I$4));
ABS($F$15:$F$20-$I$4);0))

Matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers la droite.

@+

 

[Gael]

Re : recherche valeur puis extraire ligne

Bonsoir à tous,

Ci-joint un exemple avec la formule de Tibo en F3 qui permet d'avoir la valeur approchée et la formule suivante en matricielle de A3 à E3:

=DECALER($A$14;EQUIV($F$3;$F$15:$F$20;0);;1;5)

Pour récupérer les valeurs de la ligne correspondante.

@+

Gael