XL 2019 Recherche valeur dans un tableau et décale

[sum01]

Bonjour,
Dans un tableau dynamique en fonction des mises à jour, je cherche à trouver la ligne correspondante à une valeur spécifique "VA" et sa valeur correpondante dans la colonne adjacente. J'ai deux formules qui fonctionnent pour la première valeur trouvée en O3 et P3 mais je coince pour rechercher les suivantes. Je ne parviens pas à imbriquer la formule DECALER.

Merci d'avance et bon week-end

 

[sylvanu]

Bonjour Sum,
Une tentative en PJ avec une autre approche :

Ligne :
=SIERREUR(INDEX(LIGNE($K$2:$K$13);PETITE.VALEUR(SI($K$2:$K$13=$H$2;LIGNE(INDIRECT("1:"&LIGNES($L$2:$L$13))));LIGNES($3:3)));"")
Quoi :
=SIERREUR(INDEX($L$2:$L$13;PETITE.VALEUR(SI($K$2:$K$13=$H$2;LIGNE(INDIRECT("1:"&LIGNES($L$2:$L$13))));LIGNES($3:3)));"")

Formules matricielles à valider par Alt+Ctrl+Entrée

 

[sum01]

Bonjour Sum,
Une tentative en PJ avec une autre approche :

Ligne :
=SIERREUR(INDEX(LIGNE($K$2:$K$13);PETITE.VALEUR(SI($K$2:$K$13=$H$2;LIGNE(INDIRECT("1:"&LIGNES($L$2:$L$13))));LIGNES($3:3)));"")
Quoi :
=SIERREUR(INDEX($L$2:$L$13;PETITE.VALEUR(SI($K$2:$K$13=$H$2;LIGNE(INDIRECT("1:"&LIGNES($L$2:$L$13))));LIGNES($3:3)));"")

Formules matricielles à valider par Alt+Ctrl+Entrée

Bonjour Sylvanu,
deux petites merveilles de formules qui fonctionnent à la perfection ! Merci bcp pour votre aide !
Bon week end

 

[Hasco]

Bonjour,

Une solution avec AGREGAT ^pour excel >= 2010 (en jaune dans le fichier)

=SIERREUR(AGREGAT(15;6;LIGNE($K$2:$K$13)/($K$2:$K$13=$H$2);LIGNE()-2);"")

Sans Agregat en bleu dans le fichier :

=SIERREUR(PETITE.VALEUR(SI($K$3:$K$13=$H$2;LIGNE($K$3:$K$13));LIGNE(1:1));"")

Les versions < 365 devront valider la première par CTRL+MAJ+ENTREE puis tirer vers le bas.

Et une solution pour excel 365 (en vert dans le fichier)

=FILTRE(L3:L13;K3:K13=H2)

Cordialement

 

[sylvanu]

Re,
@SUM, c'est la solution à mettre en vert, pas votre commentaire.
Ca simplifie la vie aux futurs lecteurs.

 

[sylvanu]

Révisez les consignes de David.
Pour le cas où : https://excel-downloads.com/threads/prefixe-resolu-et-marquer-comme-solution.20029836/

Les personnes posant des questions dans le forum souhaitent souvent pouvoir indiquer que les fils qu'ils ont initiés ont trouvé une réponse qui leur convient.

Donc mettre en exergue sa propre conclusion n'avance pas le futur lecteur.