recherche v avec deux conditions

[dominique35]

Bonjour.

Voila je ne trouve pas, la solution n'est pas loin pourtant!
Sur le fichier joint.
Sur la feuille 2 trois colonnes :
A: Nom de société.
B: Nom.
C: Fait.
Sur la feuille 1 j'ai la recherche.
A : Nom de société.
B : Nom.
C : le résulta de la recherche (emplacement de la formule)

je souhaite que quand sur la feuille 1 je remplie un nom de société en A2 et un nom en B2, avoir en C3 soit FAIT si le nom de la société et le nom de la personne son présent dans la feuille 2 sur une ligne de 2 à 5000.
J'ai essayé la formule suivante :
=SI(ESTNA(RECHERCHEV(A2;Feuil2!A2:C5000;3;FAUX));"A SIGNER";RECHERCHEV(A2;Feuil2!A2:C5000;3;FAUX))
Mais ça bloque.


Merci pour votre aide.
Cordialement Dominique.

 

[BOISGONTIER]

Re : recherche v avec deux conditions

Bonjour,


Voir pj

=INDEX(Signature;EQUIV(1;(Nom=B2)*(Société=A2);0))
Valider avec maj+ctrl+entrée

Recherche 2 critères

jb

 

[dominique35]

Re : recherche v avec deux conditions

Bonjour Boisgontier.

Je te remercie, mais j'ai un problème car quand le nom et la société ne sont pas dans la liste j'ai NA à la place de "A SIGNER"

 

[BOISGONTIER]

Re : recherche v avec deux conditions

=SI(ESTNA(EQUIV(1;(Nom=B2)*(Société=A2);0));"A signer";INDEX(Signature;EQUIV(1;(Nom=B2)*(Société=A2);0)))
Valider avec maj+ctrl+entrée

=SI(A2="";"";SI(B2="";"A signer";INDEX(Signature;EQUIV(1;(Nom=B2)*(Société=A2);0))))

JB

 

[dominique35]

Re : recherche v avec deux conditions

Bonjour.

J'ai suivie tes conseils mais le problème, j'ai l’impression que ça bloque sur la 2ème ligne de feuille 2.
Si je met autre chose que le contenue de de cette ligne, j'ai à chaque fois à signer alors que la société et le nom sont dans la liste.
Par-contre si je vais dans la feuille 2 est que je fait un copier et un coller dans la feuille 1 du nom de la société et du nom ça fonctionne?

 

[BOISGONTIER]

Re : recherche v avec deux conditions

Bonjour,

Il y a des espaces dans les noms de Feuil2
Il faut supprimer les espaces ou mettre cette formule

=SI(ESTNA(EQUIV(1;(SUPPRESPACE(Nom)=B2)*(SUPPRESPACE(Société)=A2);0));"A signer";INDEX(Signature;EQUIV(1;(SUPPRESPACE(Nom)=B2)*(SUPPRESPACE(Société)= A2);0)))
Valider avec maj+ctrl+entrée

ou

=SI(A2="";"";SI(B2="";"A signer";INDEX(Signature;EQUIV(1;(SUPPRESPACE(Nom)=B2)*(SUPPRESPACE(Société)= A2);0))))

JB

 

[dominique35]

Re : recherche v avec deux conditions

Bonjour Boisgontier.

Je tiens à te remercier de l'aide que tu m'a apporté. Ça fonctionne parfaitement.

Cordialement Dominique.