recherche par nom de colonne

[domduf33]

Bonsoir à tous.🙂

Comment peut-on renvoyer la valeur d'une colonne à recherchant son "nom".
J'ai un fichier de plusieurs onglets. Sur chacun de ces onglets, j'ai des données en colonnes dont les entêtes sont toujours les mêmes mais pas forcément à la même place. Ainsi ma colonne dont l'entête se nomme "alt-home" peut, indifféremment, selon les onglets se trouver à la colonne D ou F ou B...
Mon souci, est que j'ai une feuille récapitulatif sur laquelle, je fait la somme (une cellule différente par onglet) de ma colonne dont l'entête se nomme "alt-home".
voir exemple de mon fichier.
Je souhaiterais, pour l'onglet récapitulatif, dans le calcul de la somme pouvoir remplacer automatiquement A:A ou B:B.... par une recherche automatique du style :
pour la cellule A2 : recherche dans l'onglet "445066" la colonne dont l'entête se nomme "Atl-home" et fait la somme de cette colonne.

J'ai essayé plusieurs choses mais je n'y arrive pas. Savez-vous s'il est possible de faire cela sans passer par VBA car je n'y connait rien en VBA.

par avance merci
Cordialement
Dominique

 

[JCGL]

Re : recherche par nom de colonne

Bonjour à tous,

En B2 de 'recap' :

=SOMME(INDIRECT(A2&"!A:A"))

Après avoir supprimé le texte total

A+ à tous

 

[job75]

Re : recherche par nom de colonne

Bonsoir domduf33, bienvenue sur XLD,

Essayez en B2 cette formule, à tirer vers le bas :

=SOMME(DECALER(INDIRECT(DROITE(A2;6)&"!A:A");;EQUIV("alt-home";INDIRECT(DROITE(A2;6)&"!1:1");0)-1))

Rebonsoir JC 🙂

A+

 

[Jocelyn]

Re : recherche par nom de colonne

Bonjour le Forum,
Bonjour domduf33,

un essai :

=SOMME(INDIRECT("'"&B2&"'!"&CAR(64+EQUIV("alt-home";INDIRECT("'"&B2&"'!1:1");0))&":"&CAR(64+EQUIV("alt-home";INDIRECT("'"&B2&"'!1:1");0))))

voir fichier joint attention séparer total du numéro d'onglet ce sera plus simple bien que l'on puisse le faire sans la séparation

Jocelyn

Oup's Bonjour JCGL 🙂,Job75 🙂, desolé pour la collision

 

[hoerwind]

Re : recherche par nom de colonne

Bonjour, salut les autres,

Autre possibilité en recap!B2 :

=SOMME(DECALER(INDIRECT(DROITE(A2;6)*1&"!A1");;EQUIV("alt-home";INDIRECT(DROITE(A2;6)*1&"!A1:C1");0)-1;7))

formule à copier vers le bas

 

[JCGL]

Re : recherche par nom de colonne

Bonjour à tous,
Re Job 🙂,
Salut Jocelyn 🙂,

Un essai avec SOMMEPROD() mais j'ai du supprimer(é) les 'descriptifs' qui sont en texte :

=SOMMEPROD((INDIRECT($A2&"!$A$1:$C$1")=B$1)*INDIRECT($A2&"!A2:C6"))

A++ les 🙂
A+ à tous

 

[domduf33]

Re : recherche par nom de colonne

Bonsoir à tous. 🙂

Désolé de ne pas avoir répondu plus tôt, mais j'étais en déplacement pour le travail. 😱

Merci à tous d'avoir répondu à ma question. Pour l'instant, je n'ai essayé que la méhtode de Jocelyn qui fonctionne à merveille. Merci beaucoup.
Je ne comprend absolument pas la formule mais elle fonctionne très bien.
Il va vraiment falloir que je travail sur les fonctions indirect et equiv.
En tout cas merci à tous

a+
Dominique