rassembler les données en supprimant les cellules vides

[papajer]

Bonjour,

j'aimerais rassembler les données d'une partie d'une ligne qui contient des cellules de texte et des cellules vides dans une autre partie de cette ligne mais sans les cellules vides. En collant les cellules de textes les unes aux autres dans le même ordre mais sans les cellules vides.
J'espère me faire comprendre.

Je joins un fichier exemple qui contient "ce que j'ai" en feuille 1 et "ce que je veux obtenir" en feuille 2.

Je ne sais pas si c'est possible de faire cela. J'ai essayé des combinaisons avec index, equiv, recherche mais sans succès.
Merci de votre aide.

 

[Modeste]

Re : rassembler les données en supprimant les cellules vides

Bonsoir papajer et bienvenue,

Commençons par la version simple (sinon, ce seront des formules matricielles, sans doute) 😱

sélectionne G1:W4
appuye sur F5
clique sur le bouton cellule
coche "Cellules vides" puis OK
clic droit sur une de ces cellules vides > Supprimer...
sélectionner "Décaler les cellules vers la gauche"

... est-ce que ça te suffirait?

Edit: salut Tibo, mapomme, 00, ravi de vous croiser!

 

[mapomme]

Re : rassembler les données en supprimant les cellules vides

Bonsoir papajer

Voir fichier joint en xls (sur la feuille 2).

Pour excel 2007 & 2010, la formule en A1 peut-être remplacée par la formule ci-dessous puis tirée à droite puis vers le bas.

=SIERREUR(INDEX($A1:$W1;PETITE.VALEUR(SI($G1:$W1<>"";COLONNE($G1:$W1));COLONNE()));"")

Toutes les formules sont matricielles.
(Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique. Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier)

Edit: Bonsoir Tibo, ta formule me plaît bien car elle évite de passer par une gestion d'erreur.
Bonsoir Modeste : en 'one shot' méthode très élégante !

 

[Tibo]

Re : rassembler les données en supprimant les cellules vides

Bonsoir Papajer, salut Modeste,

Bien vu Modeste pour ta méthode, je n'y avais jamais pensé.

Sinon, le recours à une matricielle est nécessaire.

En A1 :

=SI(COLONNES($A:A)>NBVAL($G1:$W1);"";INDIRECT(ADRESSE(LIGNE();PETITE.VALEUR(SI($G1:$W1<>"";($G1:$W1<>"")*COLONNE($G1:$W1));COLONNES($A:A)))))

Formule matricielle à valider par CTRL + MAJ + ENTREE

à recopier vers le bas et vers la droite

@+

Edit : Salut Mapomme, belle matricielle plus efficace 🙂

@+

 

[papajer]

Re : rassembler les données en supprimant les cellules vides

Bon,
je suis calmé.
Merci beaucoup.

Cela fonctionne parfaitement, maintenant le plus dur va être de comprendre comment fonctionne cette formule.
Déjà je ne comprends pas la formule PETITE.VALEUR et elle est présente dans vos 2 réponses.

En tout cas merci beaucoup.
J'ai beaucoup d'autres questions de mise en forme comme celle-ci mais je posterai plus tard car même si cette mise en forme là va me faire gagner un temps précieux, ce n'est pas la priorité...

Merci encore une fois.

 

[R@chid]

Re : rassembler les données en supprimant les cellules vides

Salut,
en A1:

=SIERREUR(INDEX($G1:$W1;PETITE.VALEUR(SI($G1:$W1<>"";COLONNE($G1:$W1)-6);COLONNES($A:A)));"")

@ valider par Ctrl+Maj+Entrée
@ recopier vers le bas et vers la droite
@ +
@ Rachid