Rang selon 2 critères

[gourdin]

Bonsoir,

Bien qu'il existe nombreuses discussions sur le sujet, je n'ai pas réussi à trouver la formule (non matricielle) pour mon tableau simplifié en pièce jointe.

Merci de votre aide

 

[mdo100]

Re : Rang selon 2 critères

Bonsoir gourdin,

Est-ce que ceci peut vous convenir?

 

[gourdin]

Re : Rang selon 2 critères

Bonsoir mdo

Les formules fonctionnent avec mon exemple mais ne conviendront pas à mon fichier original car il y a trop de cas différents (donc trop de si à prendre en compte)

Merci quand même

 

[gourdin]

Re : Rang selon 2 critères

J'ai trouvé une formule (SOMMEPROD(($B$4:$B$14=B5)*(C5>$C$4:$C$14))+1) mais qui me pose problème car elle prend en compte les cellules vides (cf nouveau fichier joint)

 

[Hieu]

Re : Rang selon 2 critères

Salut Gourdin,

Dans le meme style que mdo100, mais en évitant "l'emboitement" de "si" :

D4=(B4="ABRICOT")*RANG(C4;$C$4:$C$14;1) + (B4="POIRE")*RANG(C4;$C$4:$C$14;1) +(B4="POMME")*RANG(C4;$C$4:$C$14;1)

Ou sinon, réaliser autant de colonne que de critère de fruit.

++

 

[mapomme]

Re : Rang selon 2 critères

Bonjour gourdin,

Un essai en apportant à votre dernière formule une condition et un terme correctif.

=SI(C4="";"";SOMMEPROD((Fruits=B4)*(C4>Poids))+1-SOMMEPROD((Fruits=B4)*(Poids="")))

Fruits et Poids sont deux noms dynamiques:
.

• Fruits => =DECALER(Feuil1!$B$4;0;0;NBVAL(Feuil1!$B$4:$B$50000);1)
• Poids => =DECALER(Fruits;0;1)

nota: sommeprod est une fonction matricielle

 

[CISCO]

Re : Rang selon 2 critères

Bonjour

Bonjour gourdin,


nota: sommeprod est une fonction matricielle

qui n'a pas besoin d'être validée avec les trois touches ctrl+maj+entrer.

@ plus

 

[CISCO]

Re : Rang selon 2 critères

Bonjour

Une autre possibilité en pièce jointe, avec une formule matricielle "camouflée" :

La formule utilisée est

=FREQUENCE(SI(B4=B$4:B$14;C$4:C$14);C4)

, à valider avec Ctrl+maj+entrer.

Pour ne pas avoir à la valider en matriciel, on définit dans le gestionnaire de noms fruitunique = SI(Feuil1!B4=Feuil1!B$4:B$14;Feuil1!C$4:C$14), ce qui donne finalement la formule

=FREQUENCE(fruitunique;C4)

qui n'a pas besoin d'être validée en matriciel.

@ plus

 

[gourdin]

Re : Rang selon 2 critères

Ok bien enregistrée au sujet de la fonction matricielle (je pensais que fonction matricielle était nécessairement validée avec les 3 touches)

 

[gourdin]

Re : Rang selon 2 critères

De mon coté, j'ai trouvé également une possibilité avec la formule suivante en D4 :

=SI(C4<>"";SOMMEPROD(($B$4:$B$14=B4)*(NON(ESTVIDE($C$4:$C$14))*(C4>$C$4:$C$14)))+1;"")